SCONS

scons requires Python 3.7 or later to run; there should be no other dependencies or requirements, unless the experimental Ninja tool is used (requires the ninja package).

Changed in version 4.3.0: support for Python 3.5 is removed. The CPython project retired 3.5 in Sept 2020: m[blue]https://peps.python.org/pe-0478m[].

Changed in version 4.8.0: support for Python 3.6 is deprecated and will be removed in a future SCons release. The CPython project retired 3.6 in Sept 2021: m[blue]https://peps.python.org/pe-0494m[].

Changed in version 4.9.0: support for Python 3.6 is removed.

You set up an SCons build by writing a script that describes things to build (targets), and, if necessary, the rules to build those files (actions). SCons comes with a collection of Builder methods which supply premade Actions for building many common software components such as executable programs, object files and libraries, so that for many software projects, only the targets and input files (sources) need be specified in a call to a builder.

SCons operates at a level of abstraction above that of pure filenames. For example if you specify a shared library target named "foo", SCons keeps track of the actual operating system dependent filename (such as libfoo.so on a GNU/Linux system and foo.dll on Windows), and gives you a handle to refer to that target in other steps, so you don't have to use system-specific strings yourself. SCons can also scan automatically for dependency information, such as header files included by source code files (for example, #include preprocessor directives in C or C++ files), so these implicit dependencies do not have to be specified manually. SCons supports the ability to define new scanners to support additional input file types.

Information about files involved in the build, including a cryptographic hash of the contents of source files, is cached for later reuse. By default, this hash (the content signature) is used to decide if a file has changed since the last build, although other algorithms can be used by selecting an appropriate Decider function. Implicit dependency files are also part of out-of-date computation. The scanned implicit dependency information can optionally be cached and used to speed up future builds. A hash of each executed build action (the build signature) is also cached, so that changes to build instructions (changing flags, etc.) or to the build tools themselves (e.g. a compiler upgrade) can also trigger a rebuild.

SCons supports separated source and build directories (also called "out-of-tree builds") through the definition of variant directories Using a separated build directory helps keep the source directory clean of artifacts when doing searches, allows setting up differing builds ("variants") without conflicts, and allows resetting the build by just removing the build directory (note that SCons does have a "clean" mode as well). See the VariantDir description for more details.

When invoked, scons looks for a file describing the build configuration in the current directory and reads that in. The file is by default named SConstruct, although some variants of that, or a developer-chosen name, are also accepted (see the section called lqSConscript Filesrq). If found, the current directory is set as the project top directory. Certain command-line options specify alternate places to look for SConstruct (see -C, -D, -u and -U), which will set the project top directory to the path found. A path to the build configuration can also be specified with the -f option, which leaves the current directory as the project top directory.

The build configuration may be split into multiple files: the SConstruct file can specify additional configuration files by calling the SConscript function, and any file thus invoked may include further files in the same way. By convention, these subsidiary files are named SConscript, although any name may be used. As a result of this naming convention, the term SConscript files is used to refer generically to the complete set of configuration files for a project (including the SConstruct file), regardless of the actual file names or number of such files. A hierarchical build is not recursive - all of the SConscript files are processed in a single pass so that scons has a picture of the complete dependency tree when it begins considering what needs building. Each SConscript file is processed in a separate context so settings made in one script do not leak into another; information can however be shared explicitly between scripts.

Before reading the SConscript files, scons looks for a site directory - a directory named site_scons is searched for in various system directories and in the project top directory, or if the --site-dir option is given, checks only for that directory. Found site directories are prepended to the Python module search path (sys.path), thus allowing modules in such directories to be imported in the normal Python way in SConscript files. For each found site directory, (1) if it contains a file site_init.py that file is evaluated, and (2) if it contains a directory site_tools the path to that directory is prepended to the default toolpath. See the --site-dir and --no-site-dir options for details on default paths and controlling the site directories.

SConscript files are written in the Python programming language. For many tasks, the simple syntax can be understood from examples, so it is normally not necessary to be a Python programmer to use SCons effectively. SConscript files are executed in a context that makes the facilities described in this manual page directly available (that is, no need to import). Standard Python scripting capabilities such as flow control, data manipulation, and imported Python modules are available to use in more complicated build configurations. Other Python files can be made a part of the build system, but they do not automatically have the SCons context and need to import it if they need access (described later).

SCons reads and executes all of the included SConscript files before it begins building any targets. Progress messages show this behavior (the state change lines - those beginning with the scons: tag - may be suppressed using the -Q option):

$ scons foo.out
scons: Reading SConscript files ...
scons: done reading SConscript files.
scons: Building targets  ...
cp foo.in foo.out
scons: done building targets.
$

To assure reproducible builds, SCons uses a restricted execution environment for running external commands used to build targets, rather than propagating the full environment in effect at the time scons was called. This helps avoid problems like picking up accidental or malicious settings, temporary debug values that are no longer needed, or a developer having different settings than another (or than the CI pipeline). Environment variables needed for the proper operation of such commands must be set in the execution environment explicitly, either by assigning the desired values, or by picking those values individually or collectively out of environment variables exposed by the Python os.environ dictionary (as external program inputs they should be validated before use). The execution environment for a given construction environment is its $ENV value. A small number of environment variables are picked up automatically by scons itself (see the section called lqENVIRONMENTrq).

In particular, if a compiler or other external command needed to build a target file is not in scons' idea of a standard system location, it will not be found at runtime unless you explicitly add the location into the execution environment's PATH element. This is a particular consideration on Windows platforms, where it is common for a command to install into an app-specific location and depend on setting PATH in order for them to be found, which does not automatically work for SCons.

One example approach is to extract the entire PATH environment variable and set that into the execution environment:

import os
env = Environment(ENV={'PATH': os.environ['PATH']})

Similarly, if the commands use specific external environment variables that scons does not recognize, they can be propagated into the execution environment:

import os

env = Environment(
    ENV={
        'PATH': os.environ['PATH'],
        'MODULEPATH': os.environ['MODULEPATH'],
        'PKG_CONFIG_PATH': os.environ['PKG_CONFIG_PATH'],
    }
)

Or you can explicitly propagate the invoking user's complete external environment:

import os
env = Environment(ENV=os.environ.copy())

This comes at the expense of making your build dependent on the user's environment being set correctly, but it may be more convenient for some configurations. It should not cause problems if done in a build setup which tightly controls how the environment is set up before invoking scons, as in many continuous integration setups.

Note

The above fragments are intended to illustrate a concept. It is normally not a good idea to wipe out the entire default value of the execution environment (env["ENV"]), as it may carry important information for the execution of build commands.

scons is normally executed in a top-level directory containing an SConstruct file (the project top directory). When scons is invoked, the command line (including the contents of the SCONSFLAGS environment variable, if set) is processed. Command-line options (see the section called lqOPTIONSrq) are consumed. Any variable argument assignments are collected, and remaining arguments are taken as targets to build.

Values of variables to be passed to the SConscript files may be specified on the command line:

scons debug=1

These variables are available through the ARGUMENTS dictionary, and can be used in the SConscript files to modify the build in any way:

if ARGUMENTS.get("debug", ""):
    env = Environment(CCFLAGS="-g")
else:
    env = Environment()

The command-line variable arguments are also available in the ARGLIST list, indexed by their order on the command line. This allows you to process them in order rather than by name, if necessary. Each ARGLIST entry is a tuple consisting of the name and the value.

See the section called lqComman-Line Construction Variablesrq for more information.

scons can maintain a cache of target (derived) files that can be shared between multiple builds. When derived-file caching is enabled in an SConscript file, any target files built by scons will be copied to the cache. If an up-to-date target file is found in the cache, it will be retrieved from the cache instead of being rebuilt locally. Caching behavior may be disabled and controlled in other ways by the --cache-force, --cache-disable, --cache-readonly, and --cache-show command-line options. The --random option is useful to prevent multiple builds from trying to update the cache simultaneously.

By default, scons searches for known programming tools on various systems and initializes itself based on what is found. On Windows systems which identify as win32, scons searches in order for the Microsoft Visual C++ tools, the MinGW tool chain, the Intel compiler tools, the GCC tools, the LLVM/clang tools, and the PharLap ETS compiler. On Windows system which identify as cygwin (that is, if scons is invoked from a cygwin shell), the order changes to prefer the GCC toolchain over the MSVC tools. On OS/2 systems, scons searches in order for the OS/2 compiler, the GCC tool chain, and the Microsoft Visual C++ tools, On SGI IRIX, IBM AIX, Hewlett Packard HP-UX, and Oracle Solaris systems, scons searches for the native compiler tools (MIPSpro, Visual Age, aCC, and Forte tools respectively) and the GCC tool chain. On all other platforms, including POSIX (Linux and UNIX) and macOS platforms, scons searches in order for the GCC tool chain, the LLVM/clang tools, and the Intel compiler tools. The default tool selection can be pre-empted through the use of the tools argument to construction environment creation methods, explicitly calling the Tool loader, the through the setting of various setting of construction variables.  

Target Selection

SCons acts on the selected targets, whether the requested operation is build, no-exec or clean. Targets are selected as follows:

1. Targets specified on the command line. These may be files, directories, or phony targets defined using the Alias function. Directory targets are scanned by scons for any targets that may be found with a destination in or under that directory. The targets listed on the command line are made available in the COMMAND_LINE_TARGETS list.

2. If no targets are specified on the command line, scons will select those targets specified in the SConscript files via calls to the Default function. These are known as the default targets, and are made available in the DEFAULT_TARGETS list.

3. If no targets are selected by the previous steps, scons selects the current directory for scanning, unless command-line options which affect the directory for target scanning are present (-C, -D, -u, -U). Since targets thus selected were not the result of user instructions, this target list is not made available for direct inspection; use the --debug=explain option if they need to be examined.

4.

scons always adds to the selected targets any intermediate targets which are necessary to build the specified ones. For example, if constructing a shared library or dll from C source files, scons will also build the object files which will make up the library.

To ignore the default targets specified through calls to Default and instead build all target files in or below the current directory specify the current directory (.) as a command-line target:

scons .

To build all target files, including any files outside of the current directory, supply a command-line target of the root directory (on POSIX systems):

scons /

or the path name(s) of the volume(s) in which all the targets should be built (on Windows systems):

scons C: D:

A subset of a hierarchical tree may be built by remaining at the project top directory and specifying the subdirectory as the target to build:

scons src/subdir

or by changing directory and invoking scons with the -u option, which traverses up the directory hierarchy until it finds the SConstruct file, and then builds targets relatively to the current subdirectory (see also the related -D and -U options):

cd src/subdir
scons -u .

In all cases, more files may be built than are requested, as scons needs to make sure any dependent files are built.

Specifying "cleanup" targets in SConscript files is usually not necessary. The -c flag removes all selected targets:

scons -c .

to remove all target files in or under the current directory, or:

scons -c build export

to remove target files under build and export.

Additional files or directories to remove can be specified using the Clean function in the SConscript files. Conversely, targets that would normally be removed by the -c invocation can be retained by calling the NoClean function with those targets.

scons supports building multiple targets in parallel via a -j option that takes, as its argument, the number of simultaneous tasks that may be spawned:

scons -j 4

builds four targets in parallel, for example.  

OPTIONS

In general, scons supports the same command-line options as GNU Make and many of those supported by cons.

-b

Ignored for compatibility with non-GNU versions of Make

-c, --clean, --remove

Set clean mode. Clean up by removing the selected targets, well as any files or directories associated with a selected target through calls to the Clean function. Will not remove any targets which are marked for preservation through calls to the NoClean function.

While clean mode removes targets rather than building them, work which is done directly in Python code in SConscript files will still be carried out. If it is important to avoid some such work from taking place in clean mode, it should be protected. An SConscript file can determine which mode is active by querying GetOption, as in the call if GetOption("clean"):

--cache-debug=file

Write debug information about derived-file caching to the specified file. If file is a hyphen (-), the debug information is printed to the standard output. The printed messages describe what signature-file names are being looked for in, retrieved from, or written to the derived-file cache specified by CacheDir.

--cache-disable, --no-cache

Disable derived-file caching. scons will neither retrieve files from the cache nor copy files to the cache. This option can be used to temporarily disable the cache without modifying the build scripts.

--cache-force, --cache-populate

When using CacheDir, populate a derived-file cache by copying any already-existing, up-to-date derived files to the cache, in addition to files built by this invocation. This is useful to populate a new cache with all the current derived files, or to add to the cache any derived files recently built with caching disabled via the --cache-disable option.

--cache-readonly

Use the derived-file cache, if enabled, to retrieve files, but do not not update the cache with any files actually built during this invocation.

--cache-show

When using a derived-file cache, show the command that would have been executed to build the file (or the corresponding *COMSTR contents if set) even if the file is retrieved from cache. Without this option, scons shows a cache retrieval message if the file is fetched from cache. This allows producing consistent output for build logs, regardless of whether a target file was rebuilt or retrieved from the cache.

--config=mode

Control how the Configure call should use or generate the results of configuration tests. mode should be one of the following choices:

auto

SCons will use its normal dependency mechanisms to decide if a test must be rebuilt or not. This saves time by not running the same configuration tests every time you invoke scons, but will overlook changes in system header files or external commands (such as compilers) if you don't specify those dependencies explicitly. This is the default behavior.

force

If this mode is specified, all configuration tests will be re-run regardless of whether the cached results are out-of-date. This can be used to explicitly force the configuration tests to be updated in response to an otherwise unconfigured change in a system header file or compiler.

cache

If this mode is specified, no configuration tests will be rerun and all results will be taken from cache. scons will report an error if --config=cache is specified and a necessary test does not have any results in the cache.

-C directory, --directory=directory

Run as if scons was started in directory instead of the current working directory. That is, change directory before searching for the SConstruct, Sconstruct, sconstruct, SConstruct.py, Sconstruct.py or sconstruct.py file or doing anything else. When multiple -C options are given, each subsequent non-absolute -C directory is interpreted relative to the preceding one. See also options -u, -U and -D to change the SConstruct search behavior when this option is used.

-D

Works exactly the same way as the -u option except for the way default targets are handled. When this option is used and no targets are specified on the command line, all default targets are built, whether or not they are below the current directory.

--debug=type[,type...]

Debug the build process. type specifies the kind of debugging info to emit. Multiple types may be specified, separated by commas. The following types are recognized:

action-timestamps

Prints additional time profiling information. For each command, shows the absolute start and end times. This may be useful in debugging parallel builds. Implies the --debug=time option.

New in version 3.1.

count

Print how many objects are created of the various classes used internally by SCons before and after reading the SConscript files and before and after building targets. This is not supported when SCons is executed with the Python -O (optimized) option or when the SCons modules have been compiled with optimization (that is, when executing from *.pyo files).

duplicate

Print a line for each unlink/relink (or copy) of a file in a variant directory from its source file. Includes debugging info for unlinking stale variant directory files, as well as unlinking old targets before building them.

explain

Print an explanation of why scons is deciding to (re-)build the targets it selects for building.

findlibs

Instruct the scanner that searches for libraries to print a message about each potential library name it is searching for, and about the actual libraries it finds.

includes

Print the include tree after each top-level target is built. This is generally used to find out what files are included by the sources of a given derived file:

$ scons --debug=includes foo.o

json

Write info to a JSON file for any of the following debug options if they are enabled: memory, count, time, action-timestamps

The default output file is scons_stats.json

The file name/path can be modified by using DebugOptions for example DebugOptions(json='path/to/file.json')

$ scons --debug=memory,json foo.o

memoizer

Prints a summary of hits and misses using the Memoizer, an internal subsystem that counts how often SCons uses cached values in memory instead of recomputing them each time they're needed.

memory

Prints how much memory SCons uses before and after reading the SConscript files and before and after building targets.

objects

Prints a list of the various objects of the various classes used internally by SCons.

pdb

Run scons under control of the pdb Python debugger.

$ scons --debug=pdb
> /usr/lib/python3.11/site-packages/SCons/Script/Main.py(869)_main()
-> options = parser.values
(Pdb)

Note
pdb will stop at the beginning of the scons main routine on startup. The search path (sys.path) at that point will include the location of the running scons, but not of the project itself. If you need to set breakpoints in your project files, you will either need to add to the path, or use absolute pathnames when referring to project files. A .pdbrc file in the project root can be used to add the current directory to the search path to avoid having to enter it by hand, along these lines:

sys.path.append('.')

Due to the implementation of the pdb module, the break, tbreak and clear commands only understand references to filenames which have a .py extension. (although the suffix itself can be omitted), except if you use an absolute path. As a special exception to that rule, the names SConstruct and SConscript are recognized without needing the .py extension.

Changed in version 4.6.0: The names SConstruct and SConscript are now recognized without requiring .py suffix.

Changed in version 4.8.0: The name SCsub is now recognized without requiring .py suffix.

prepare

Print a line each time any target (internal or external) is prepared for building. scons prints this for each target it considers, even if that target is up-to-date (see also --debug=explain). This can help debug problems with targets that aren't being built; it shows whether scons is at least considering them or not.

presub

Print the raw command line used to build each target before the construction environment variables are substituted. Also shows which targets are being built by this command. Output looks something like this:

$ scons --debug=presub
Building myprog.o with action(s):
  $SHCC $SHCFLAGS $SHCCFLAGS $CPPFLAGS $_CPPINCFLAGS -c -o $TARGET $SOURCES
...

stacktrace

Prints an internal Python stack trace when encountering an otherwise unexplained error.

time

Prints various time profiling information:

* The time spent executing each individual build command

* The total build time (time SCons ran from beginning to end)

* The total time spent reading and executing SConscript files

* The total time SCons itself spent running (that is, not counting reading and executing SConscript files)

* The total time spent executing all build commands

* The elapsed wall-clock time spent executing those build commands

* The time spent processing each file passed to the SConscript function

(When scons is executed without the -j option, the elapsed wall-clock time will typically be slightly longer than the total time spent executing all the build commands, due to the SCons processing that takes place in between executing each command. When scons is executed with the -j option, and your build configuration allows good parallelization, the elapsed wall-clock time should be significantly smaller than the total time spent executing all the build commands, since multiple build commands and intervening SCons processing should take place in parallel.)

sconscript

Enables output indicating entering and exiting each SConscript file.

--diskcheck=type

Enable specific checks for whether or not there is a file on disk where the SCons configuration expects a directory (or vice versa) when searching for source and include files. type can be an available diskcheck type or the special tokens all or none. A comma-separated string can be used to select multiple checks. The default setting is all.

Current available checks are:

match

to check that files and directories on disk match SCons' expected configuration.

Disabling some or all of these checks can provide a performance boost for large configurations, or when the configuration will check for files and/or directories across networked or shared file systems, at the slight increased risk of an incorrect build or of not handling errors gracefully.

--duplicate=ORDER

There are three ways to duplicate files in a build tree: hard links, soft (symbolic) links and copies. The default policy is to prefer hard links to soft links to copies. You can specify a different policy with this option. ORDER must be one of hard-soft-copy (the default), soft-hard-copy, hard-copy, soft-copy or copy. SCons will attempt to duplicate files using the mechanisms in the specified order.

--enable-virtualenv

Import virtualenv-related variables to SCons.

--experimental=feature

Enable experimental features and/or tools. feature can be an available feature name or the special tokens all or none. A comma-separated string can be used to select multiple features. The default setting is none.

Current available features are: ninja (New in version 4.2), legacy_sched (New in version 4.6.0).

Caution
No Support offered for any features or tools enabled by this flag.

New in version 4.2 (experimental).

-f file, --file=file, --makefile=file, --sconstruct=file

Use file as the initial SConscript file. Multiple -f options may be specified, in which case scons will read all of the specified files.

-h, --help

Print a local help message for this project, if one is defined in the SConscript files (see the Help function), plus a line that refers to the standard SCons help message. If no local help message is defined, prints the standard SCons help message (as for the -H option) plus help for any local options defined through AddOption. Exits after displaying the appropriate message.

Note that use of this option requires SCons to process the SConscript files, so syntax errors may cause the help message not to be displayed.

--hash-chunksize=KILOBYTES

Set the block size used when computing content signatures to KILOBYTES. This value determines the size of the chunks which are read in at once when computing signature hashes. Files below that size are fully stored in memory before performing the signature computation while bigger files are read in block-by-block. A huge block-size leads to high memory consumption while a very small block-size slows down the build considerably.

The default value is to use a chunk size of 64 kilobytes, which should be appropriate for most uses.

New in version 4.1.

--hash-format=ALGORITHM

Set the hashing algorithm used by SCons to ALGORITHM. This value determines the hashing algorithm used in generating content signatures, build signatures and CacheDir keys.

The supported list of values are: md5, sha1 and sha256. However, the Python interpreter used to run scons must have the corresponding support available in the hashlib module to use the specified algorithm.

If this option is omitted, the first supported hash format found is selected. Typically, this is MD5, however, on a FIPS-compliant system using a version of Python older than 3.9, SHA1 or SHA256 is chosen as the default. Python 3.9 and onwards clients always default to MD5, even in FIPS mode.

Specifying this option changes the name of the SConsign database. The default database is .sconsign.dblite. In the presence of this option, ALGORITHM is included in the name to indicate the difference, even if the argument is md5. For example, --hash-format=sha256 uses a SConsign database named .sconsign_sha256.dblite.

New in version 4.1.

-H, --help-options

Print the standard help message about SCons command-line options and exit.

-i, --ignore-errors

Ignore all errors from commands executed to rebuild files.

-I directory, --include-dir=directory

Specifies a directory to search for imported Python modules. If several -I options are used, the directories are searched in the order specified.

--ignore-virtualenv

Suppress importing virtualenv-related variables to SCons.

--implicit-cache

Cache implicit dependencies. This causes scons to use the implicit (scanned) dependencies from the last time it was run instead of scanning the files for implicit dependencies. This can significantly speed up SCons, but with the following limitations:

scons will not detect changes to implicit dependency search paths (e.g. $CPPPATH, $LIBPATH) that would ordinarily cause different versions of same-named files to be used.

scons will miss changes in the implicit dependencies in cases where a new implicit dependency is added earlier in the implicit dependency search path (e.g. $CPPPATH, $LIBPATH) than a current implicit dependency with the same name.

--implicit-deps-changed

Forces SCons to ignore the cached implicit dependencies. This causes the implicit dependencies to be rescanned and recached. This implies --implicit-cache.

--implicit-deps-unchanged

Force SCons to ignore changes in the implicit dependencies. This causes cached implicit dependencies to always be used. This implies --implicit-cache.

--install-sandbox=sandbox_path

When using the Install builders, prepend sandbox_path to the installation paths such that all installed files will be placed under that directory. This option is unavailable if one of Install, InstallAs or InstallVersionedLib is not used in the SConscript files.

--interactive

Starts SCons in interactive mode. The SConscript files are read once and a scons>>> prompt is printed. Targets may now be rebuilt by typing commands at interactive prompt without having to re-read the SConscript files and re-initialize the dependency graph from scratch.

SCons interactive mode supports the following commands:

build [OPTIONS] [TARGETS] ...

Builds the specified TARGETS (and their dependencies) with the specified SCons command-line OPTIONS. b and scons are synonyms for build.

The following SCons command-line options affect the build command:

--cache-debug=FILE
--cache-disable, --no-cache
--cache-force, --cache-populate
--cache-readonly
--cache-show
--debug=TYPE
-i, --ignore-errors
-j N, --jobs=N
-k, --keep-going
-n, --no-exec, --just-print, --dry-run, --recon
-Q
-s, --silent, --quiet
--taskmastertrace=FILE
--tree=OPTIONS

Any other SCons command-line options that are specified do not cause errors but have no effect on the build command (mainly because they affect how the SConscript files are read, which only happens once at the beginning of interactive mode).

clean [OPTIONS] [TARGETS] ...

Cleans the specified TARGETS (and their dependencies) with the specified OPTIONS. c is a synonym. This command is itself a synonym for build --clean

exit

Exits SCons interactive mode. You can also exit by terminating input (Ctrl+D UNIX or Linux systems, (Ctrl+Z on Windows systems).

help [COMMAND]

Provides a help message about the commands available in SCons interactive mode. If COMMAND is specified, h and ? are synonyms.

shell [COMMANDLINE]

Executes the specified COMMANDLINE in a subshell. If no COMMANDLINE is specified, executes the interactive command interpreter specified in the SHELL environment variable (on UNIX and Linux systems) or the COMSPEC environment variable (on Windows systems). sh and ! are synonyms.

version

Prints SCons version information.

An empty line repeats the last typed command. Command-line editing can be used if the readline module is available.

$ scons --interactive
scons: Reading SConscript files ...
scons: done reading SConscript files.
scons>>> build -n prog
scons>>> exit

-j N, --jobs=N

Specifies the maximum number of concurrent jobs (commands) to run. If there is more than one -j option, the last one is effective.

-k, --keep-going

Continue as much as possible after an error. The target that failed and those that depend on it will not be remade, but other targets specified on the command line will still be processed.

-m

Ignored for compatibility with non-GNU versions of Make.

--max-drift=SECONDS

Set the maximum expected drift in the modification time of files to SECONDS. This value determines how long a file must be unmodified before its cached content signature will be used instead of calculating a new content signature (hash) of the file's contents. The default value is 2 days, which means a file must have a modification time of at least two days ago in order to have its cached content signature used. A negative value means to never cache the content signature and to ignore the cached value if there already is one. A value of 0 means to always use the cached signature, no matter how old the file is.

--md5-chunksize=KILOBYTES

A deprecated synonym for --hash-chunksize.

Changed in version 4.2: deprecated.

-n, --no-exec, --just-print, --dry-run, --recon

Set no-exec mode. Print the commands that would be executed to build any out-of-date targets, but do not execute those commands.

Only target building is suppressed - any work in the build system that is done directly (in regular Python code) will still be carried out. You can add guards around code which should not be executed in no-exec mode by checking the value of the option at run time with GetOption:

if not GetOption("no_exec"):
    # run regular instructions

The output is a best effort, as SCons cannot always precisely determine what would be built. For example, if a file generated by a builder action is also used as a source in the build, that file is not available to scan for dependencies at all in an unbuilt tree, and may contain out-of-date information in a previously built tree.

SCons cannot perform Configure checks in no-exec mode, as they would make changes to the filesystem (see $CONFIGUREDIR and $CONFIGURELOG). It can use stored information from a previous build, if it is not out-of-date, so a "priming" build may make subsequent no-exec runs more useful.

--no-site-dir

Do not read site directories. Neither the standard site directories (site_scons) nor the path specified via a previous --site-dir option are added to the module search path sys.path, searched for a site_init.py file, or have their site_tools directory included in the tool search path. Can be overridden by a subsequent --site-dir option.

--package-type=type

The type of package to create when using the Package builder. Multiple types can be specified by using a comma-separated string, in which case SCons will try to build for all of those package types. Note this option is only available if the packaging tool has been enabled.

--profile=file

Run SCons under the Python profiler and save the results to file. The results may be analyzed using the Python pstats module.

-q, --question

Do not run any commands, or print anything. Just return an exit status that is zero if the specified targets are already up-to-date, non-zero otherwise.

-Q

Suppress status messages about reading SConscript files, building targets and entering directories. Commands that are executed to rebuild target files are still printed.

--random

Build dependencies in a random order. This is useful when building multiple trees simultaneously with caching enabled, to prevent multiple builds from simultaneously trying to build or retrieve the same target files.

-s, --silent, --quiet

Silent. Do not print commands that are executed to rebuild target files. Also suppresses SCons status messages.

-S, --no-keep-going, --stop

Ignored for compatibility with GNU Make

--site-dir=path

Use path as the site directory rather than searching the list of default site directories. This directory will be prepended to sys.path, the module path/site_init.py will be loaded if it exists, and path/site_tools will be included in the tool search path. The option is not additive - if given more than once, the last path wins.

The default set of site directories searched when --site-dir is not specified depends on the system platform, as follows. Users or system administrators can tune site-specific or project-specific SCons behavior by setting up a site directory in one or more of these locations. Directories are examined in the order given, from most generic ("system" directories) to most specific (in the current project), so the last-executed site_init.py file is the most specific one, giving it the chance to override everything else), and the directories are prepended to the paths, again so the last directory examined comes first in the resulting path.

Windows:

%ALLUSERSPROFILE%/scons/site_scons
%LOCALAPPDATA%/scons/site_scons
%APPDATA%/scons/site_scons
%USERPROFILE%/.scons/site_scons
./site_scons

Note earlier versions of the documentation listed a different path for the "system" site directory, this path is still checked but its use is discouraged:

%ALLUSERSPROFILE%/Application Data/scons/site_scons

Mac OS X:

/Library/Application Support/SCons/site_scons
/opt/local/share/scons/site_scons (for MacPorts)
/sw/share/scons/site_scons (for Fink)
$HOME/Library/Application Support/SCons/site_scons
$HOME/.scons/site_scons
./site_scons

Solaris:

/opt/sfw/scons/site_scons
/usr/share/scons/site_scons
$HOME/.scons/site_scons
./site_scons

Linux, HPUX, and other Posix-like systems:

/usr/share/scons/site_scons
$HOME/.scons/site_scons
./site_scons

--stack-size=KILOBYTES

Set the size stack used to run threads to KILOBYTES. This value determines the stack size of the threads used to run jobs. These threads execute the actions of the builders for the nodes that are out-of-date. This option has no effect unless the number of concurrent build jobs is larger than one (as set by -j N or --jobs=N on the command line or SetOption in a script).

Using a stack size that is too small may cause stack overflow errors. This usually shows up as segmentation faults that cause scons to abort before building anything. Using a stack size that is too large will cause scons to use more memory than required and may slow down the entire build process. The default value is to use a stack size of 256 kilobytes, which should be appropriate for most uses. You should not need to increase this value unless you encounter stack overflow errors.

-t, --touch

Ignored for compatibility with GNU Make. (Touching a file to make it appear up-to-date is unnecessary when using scons.)

--taskmastertrace=file

Prints trace information to the specified file about how the internal Taskmaster object evaluates and controls the order in which Nodes are built. A file name of - may be used to specify the standard output.

--tree=type[,type...]

Prints a tree of the dependencies after each top-level target is built. This prints out some or all of the tree, in various formats, depending on the type specified:

all

Print the entire dependency tree after each top-level target is built. This prints out the complete dependency tree, including implicit dependencies and ignored dependencies.

derived

Restricts the tree output to only derived (target) files, not source files.

linedraw

Draw the tree output using Unicode line-drawing characters instead of plain ASCII text. This option acts as a modifier to the selected type(s). If specified alone, without any type, it behaves as if all had been specified.

New in version 4.0.

status

Prints status information for each displayed node.

prune

Prunes the tree to avoid repeating dependency information for nodes that have already been displayed. Any node that has already been displayed will have its name printed in [square brackets], as an indication that the dependencies for that node can be found by searching for the relevant output higher up in the tree.

Multiple type choices may be specified, separated by commas:

# Prints only derived files, with status information:
scons --tree=derived,status

# Prints all dependencies of target, with status information
# and pruning dependencies of already-visited Nodes:
scons --tree=all,prune,status target

-u, --up, --search-up

Walks up the directory structure until an SConstruct, Sconstruct, sconstruct, SConstruct.py, Sconstruct.py or sconstruct.py file is found, and uses that as the project top directory. If no targets are specified on the command line, only targets at or below the current directory will be built.

-U

Works exactly the same way as the -u option except for the way default targets are handled. When this option is used and no targets are specified on the command line, all default targets that are defined in the SConscript file(s) in the current directory are built, regardless of what directory the resultant targets end up in.

-v, --version

Print the scons version, copyright information, list of authors, and any other relevant information. Then exit.

-w, --print-directory

Print a message containing the working directory before and after other processing.

--no-print-directory

Turn off -w, even if it was turned on implicitly.

--warn=type, --warn=no-type

Enable or disable (with the prefix "no-") warnings (--warning is a synonym). type specifies the type of warnings to be enabled or disabled:

all

All warnings.

cache-version

Warnings about the derived-file cache directory specified by CacheDir not using the latest configuration information. These warnings are enabled by default.

cache-write-error

Warnings about errors trying to write a copy of a built file to a specified derived-file cache specified by CacheDir. These warnings are disabled by default.

cache-cleanup-error

Warnings about errors when a file retrieved from the derived-file cache could not be removed.

corrupt-sconsign

Warnings about unfamiliar signature data in .sconsign files. These warnings are enabled by default.

dependency

Warnings about dependencies. These warnings are disabled by default.

deprecated

Warnings about use of currently deprecated features. These warnings are enabled by default. Not all deprecation warnings can be disabled with the --warn=no-deprecated option as some deprecated features which are late in the deprecation cycle may have been designated as mandatory warnings, and these will still display. Warnings for certain deprecated features may also be enabled or disabled individually; see below.

duplicate-environment

Warnings about attempts to specify a build of a target with two different construction environments that use the same action. These warnings are enabled by default.

fortran-cxx-mix

Warnings about linking Fortran and C++ object files in a single executable, which can yield unpredictable behavior with some compilers.

future-reserved-variable

Warnings about construction variables which are currently allowed, but will become reserved variables in a future release.

future-deprecated

Warnings about features that will be deprecated in the future. Such warnings are disabled by default. Enabling future deprecation warnings is recommended for projects that redistribute SCons configurations for other users to build, so that the project can be warned as soon as possible about to-be-deprecated features that may require changes to the configuration.

link

Warnings about link steps.

misleading-keywords

Warnings about the use of two commonly misspelled keywords targets and sources to Builder calls. The correct spelling is the singular form, even though target and source can themselves refer to lists of names or nodes.

tool-qt-deprecated

Warnings about the qt tool being deprecated. These warnings are disabled by default for the first phase of deprecation. Enable to be reminded about use of this tool module. New in version 4.3.

no-object-count

Warnings about the --debug=object feature not working when scons is run with the Python -O option or from optimized Python (.pyo) modules.

Note the "no-" prefix is part of the name of this warning. Add another "-no" to disable.

no-parallel-support

Warnings about the version of Python not being able to support parallel builds when the -j option is used. These warnings are enabled by default.

Note the "no-" prefix is part of the name of this warning. Add another "-no" to disable.

python-version

Warnings about running SCons using a version of Python that has been deprecated. These warnings are enabled by default.

reserved-variable

Warnings about attempts to set the reserved construction variable names $CHANGED_SOURCES, $CHANGED_TARGETS, $TARGET, $TARGETS, $SOURCE, $SOURCES, $UNCHANGED_SOURCES or $UNCHANGED_TARGETS. These warnings are disabled by default.

stack-size

Warnings about requests to set the stack size that could not be honored. These warnings are enabled by default.

target-not-built

Warnings about a build rule not building the expected targets. These warnings are disabled by default.

-Y repository, --repository=repository, --srcdir=repository

Search repository for any input and target files not found in the local directory hierarchy. Multiple -Y options may be specified, with repositories searched in the given order. See Repository for more information.

SCONSCRIPT FILE REFERENCE

SConscript Files

The build configuration is described by one or more files, known as SConscript files. There must be at least one file for a valid build (scons will quit if it does not find one). scons by default looks for this file by the name SConstruct in the directory from which you run scons, though if necessary, also looks for alternative file names Sconstruct, sconstruct, SConstruct.py, Sconstruct.py and sconstruct.py in that order. A different file name (which can include a pathname part) may be specified via the -f option. Except for the SConstruct file, these files are not searched for automatically; you add additional configuration files to the build by calling the SConscript function. This allows parts of the build to be conditionally included or excluded at run-time depending on how scons is invoked.

Each SConscript file in a build configuration is invoked independently in a separate context. This provides necessary isolation so that different parts of the build don't accidentally step on each other. You have to be explicit about sharing information, by using the Export function or the exports argument to the SConscript function, as well as the Return function in a called SConscript file, and consume shared information by using the Import function.

The following sections describe the various SCons facilities that can be used in SConscript files. Quick links:

Construction Environments

Tools

Builder Methods

Functions and Environment Methods

SConscript Variables

Construction Variables

Configure Contexts

Command-Line Construction Variables

Node Objects

Construction Environments

A Construction Environment is the basic means by which you communicate build information to SCons. A new construction environment is created using the Environment function:

env = Environment()

Construction environment attributes called Construction Variables may be set either by specifying them as keyword arguments when the object is created or by assigning them a value after the object is created. These two are nominally equivalent:

env = Environment(FOO='foo')
env['FOO'] = 'foo'

Note that certain settings which affect tool detection are referenced only when the tools are initialized, so you need either to supply them as part of the call to Environment, or defer tool initialization. For example, initializing the Microsoft Visual C++ version you wish to use:

# initializes msvc to v14.1
env = Environment(MSVC_VERSION="14.1")

env = Environment()
# msvc tool was initialized to default, does not reinitialize
env['MSVC_VERSION'] = "14.1"

env = Environment(tools=[])
env['MSVC_VERSION'] = "14.1"
# msvc tool initialization was deferred, so will pick up new value
env.Tool('default')

As a convenience, construction variables may also be set or modified by the parse_flags keyword argument during object creation, which has the effect of the env.MergeFlags method being applied to the argument value after all other processing is completed. This is useful either if the exact content of the flags is unknown (for example, read from a control file) or if the flags need to be distributed to a number of construction variables. env.ParseFlags describes how these arguments are distributed to construction variables.

env = Environment(parse_flags='-Iinclude -DEBUG -lm')

This example adds 'include' to the $CPPPATH construction variable, 'EBUG' to $CPPDEFINES, and 'm' to $LIBS.

An existing construction environment can be duplicated by calling the env.Clone method. Without arguments, it will be a copy with the same settings. Otherwise, env.Clone takes the same arguments as Environment, and uses the arguments to create a modified copy.

SCons provides a special construction environment called the Default Environment. The default environment is used only for global functions, that is, construction activities called without the context of a regular construction environment. See DefaultEnvironment for more information.

By default, a new construction environment is initialized with a set of builder methods and construction variables that are appropriate for the current platform. The optional platform keyword argument may be used to specify that the construction environment should be initialized for a different platform:

env = Environment(platform='cygwin')

Specifying a platform initializes the appropriate construction variables in the environment to use and generate file names with prefixes and suffixes appropriate for that platform.

Note that the win32 platform adds the SystemDrive and SystemRoot variables from the user's external environment to the construction environment's ENV dictionary. This is so that any executed commands that use sockets to connect with other systems will work on Windows systems.

The platform argument may be a string value representing one of the pre-defined platforms (aix, cygwin, darwin, hpux, irix, os2, posix, sunos or win32), or a callable platform object returned by a call to Platform selecting a pre-defined platform, or it may be a user-supplied callable, in which case the Environment method will call it to update the new construction environment:

def my_platform(env):
    env['VAR'] = 'xyzzy'

env = Environment(platform=my_platform)

Note that supplying a non-default platform or custom function for initialization may bypass settings that should happen for the host system and should be used with care. It is most useful in the case where the platform is an alternative for the one that would be auto-detected, such as platform="cygwin" on a system which would otherwise identify as win32.

The optional tools and toolpath keyword arguments affect the way tools available to the environment are initialized. See the section called lqToolsrq for details.

The optional variables keyword argument allows passing a Variables object which will be used in the initialization of the construction environment See the section called lqComman-Line Construction Variablesrq for details.  

Tools

SCons has many included tool modules (more properly, tool specification modules) which are used to help initialize the construction environment prior to building, and more can be written to suit a particular purpose, or added from external sources (a repository of contributed tools is available). More information on writing custom tools can be found in the Extending SCons section and specifically Tool Modules.

An SCons tool is only responsible for setup. For example, if an SConscript file declares the need to construct an object file from a C-language source file by calling the Object builder, then a tool module representing an available C compiler needs to have run first, to set up that builder and all the construction variables it needs in the associated construction environment. The tool itself is not called in the process of the build. Tool setup happens when a construction environment is constructed, and in the basic case needs no intervention - platform-specific lists of default tools are used to examine the specific capabilities of that platform and configure the environment, skipping those tools which are not applicable.

If necessary, a specific set of tools to initialize in an environment during creation may be specified using the optional keyword argument tools. tools must be a list, even if there are one (or zero) tools. This is useful to override the defaults, to specify non-default built-in tools, and to cause added tools to be called:

env = Environment(tools=['msvc', 'lex'])

The tools argument overrides the default tool list, it does not add to it, so be sure to include all the tools you need. For example, if you are building a c/c++ program, you must specify a tool for at least a compiler and a linker, as in tools=['clang', 'link'].

If the tools argument is omitted, or if tools includes the reserved name 'default', then SCons will auto-detect usable tools, using the search path from the execution environment (that is, env['ENV']['PATH']) for looking up any external programs, and the platform name in effect to determine the default tools for that platform. Note the contents of PATH from the external environment os.environ is not used. Changing the PATH in the execution environment after the construction environment is constructed will not cause the tools to be re-detected.

Tools can also be directly called by using the Tool method (see below).

SCons supports the following tool specifications out of the box:

386asm

Sets construction variables for the 386ASM assembler for the Phar Lap ETS embedded operating system.

Sets: $AS, $ASCOM, $ASFLAGS, $ASPPCOM, $ASPPFLAGS.

Uses: $CC, $CPPFLAGS, $_CPPDEFFLAGS, $_CPPINCFLAGS.

aixc++

Sets construction variables for the IMB xlc / Visual Age C++ compiler.

Sets: $CXX, $CXXVERSION, $SHCXX, $SHOBJSUFFIX.

aixcc

Sets construction variables for the IBM xlc / Visual Age C compiler.

Sets: $CC, $CCVERSION, $SHCC.

aixf77

Sets construction variables for the IBM Visual Age f77 Fortran compiler.

Sets: $F77, $SHF77.

aixlink

Sets construction variables for the IBM Visual Age linker.

Sets: $LINKFLAGS, $SHLIBSUFFIX, $SHLINKFLAGS.

applelink

Sets construction variables for the Apple linker (similar to the GNU linker).

Sets: $APPLELINK_COMPATIBILITY_VERSION, $APPLELINK_CURRENT_VERSION, $APPLELINK_NO_COMPATIBILITY_VERSION, $APPLELINK_NO_CURRENT_VERSION, $FRAMEWORKPATHPREFIX, $LDMODULECOM, $LDMODULEFLAGS, $LDMODULEPREFIX, $LDMODULESUFFIX, $LINKCOM, $SHLINKCOM, $SHLINKFLAGS, $_APPLELINK_COMPATIBILITY_VERSION, $_APPLELINK_CURRENT_VERSION, $_FRAMEWORKPATH, $_FRAMEWORKS.

Uses: $FRAMEWORKSFLAGS.

ar

Sets construction variables for the ar library archiver.

Sets: $AR, $ARCOM, $ARFLAGS, $LIBPREFIX, $LIBSUFFIX, $RANLIB, $RANLIBCOM, $RANLIBFLAGS.

as

Sets construction variables for the as assembler.

Sets: $AS, $ASCOM, $ASFLAGS, $ASPPCOM, $ASPPFLAGS.

Uses: $CC, $CPPFLAGS, $_CPPDEFFLAGS, $_CPPINCFLAGS.

bcc32

Sets construction variables for the bcc32 compiler.

Sets: $CC, $CCCOM, $CCFLAGS, $CFILESUFFIX, $CFLAGS, $CPPDEFPREFIX, $CPPDEFSUFFIX, $INCPREFIX, $INCSUFFIX, $SHCC, $SHCCCOM, $SHCCFLAGS, $SHCFLAGS, $SHOBJSUFFIX.

Uses: $_CPPDEFFLAGS, $_CPPINCFLAGS.

cc

Sets construction variables for generic POSIX C compilers.

Sets: $CC, $CCCOM, $CCDEPFLAGS, $CCFLAGS, $CFILESUFFIX, $CFLAGS, $CPPDEFPREFIX, $CPPDEFSUFFIX, $FRAMEWORKPATH, $FRAMEWORKS, $INCPREFIX, $INCSUFFIX, $SHCC, $SHCCCOM, $SHCCFLAGS, $SHCFLAGS, $SHOBJSUFFIX.

Uses: $CCCOMSTR, $PLATFORM, $SHCCCOMSTR.

clang

Set construction variables for the Clang C compiler.

Sets: $CC, $CCDEPFLAGS, $CCVERSION, $SHCCFLAGS.

clangxx

Set construction variables for the Clang C++ compiler.

Sets: $CXX, $CXXVERSION, $SHCXXFLAGS, $SHOBJSUFFIX, $STATIC_AND_SHARED_OBJECTS_ARE_THE_SAME.

compilation_db

Sets up CompilationDatabase builder which generates a clang tooling compatible compilation database.

Sets: $COMPILATIONDB_COMSTR, $COMPILATIONDB_PATH_FILTER, $COMPILATIONDB_USE_ABSPATH.

cvf

Sets construction variables for the Compaq Visual Fortran compiler.

Sets: $FORTRAN, $FORTRANCOM, $FORTRANMODDIR, $FORTRANMODDIRPREFIX, $FORTRANMODDIRSUFFIX, $FORTRANPPCOM, $OBJSUFFIX, $SHFORTRANCOM, $SHFORTRANPPCOM.

Uses: $CPPFLAGS, $FORTRANFLAGS, $SHFORTRANFLAGS, $_CPPDEFFLAGS, $_FORTRANINCFLAGS, $_FORTRANMODFLAG.

cXX

Sets construction variables for generic POSIX C++ compilers.

Sets: $CPPDEFPREFIX, $CPPDEFSUFFIX, $CXX, $CXXCOM, $CXXFILESUFFIX, $CXXFLAGS, $INCPREFIX, $INCSUFFIX, $OBJSUFFIX, $SHCXX, $SHCXXCOM, $SHCXXFLAGS, $SHOBJSUFFIX.

Uses: $CXXCOMSTR, $SHCXXCOMSTR.

cyglink

Set construction variables for cygwin linker/loader.

Sets: $IMPLIBPREFIX, $IMPLIBSUFFIX, $LDMODULEVERSIONFLAGS, $LINKFLAGS, $RPATHPREFIX, $RPATHSUFFIX, $SHLIBPREFIX, $SHLIBSUFFIX, $SHLIBVERSIONFLAGS, $SHLINKCOM, $SHLINKFLAGS, $_LDMODULEVERSIONFLAGS, $_SHLIBVERSIONFLAGS.

default

Sets construction variables for a default list of Tool modules. Use default in the tools list to retain the original defaults, since the tools parameter is treated as a literal statement of the tools to be made available in that construction environment, not an addition.

The list of tools selected by default is not static, but is dependent both on the platform and on the software installed on the platform. Some tools will not initialize if an underlying command is not found, and some tools are selected from a list of choices on a first-found basis. The finished tool list can be examined by inspecting the $TOOLS construction variable in the construction environment.

On all platforms, the tools from the following list are selected if their respective conditions are met: filesystem;, wix, lex, yacc, rpcgen, swig, jar, javac, javah, rmic, dvipdf, dvips, gs, tex, latex, pdflatex, pdftex, tar, zip, textfile.

On Linux systems, the default tools list selects (first-found): a C compiler from gcc, intelc, icc, cc; a C++ compiler from g++, intelc, icc, cXX; an assembler from gas, nasm, masm; a linker from gnulink, ilink; a Fortran compiler from gfortran, g77, ifort, ifl, f95, f90, f77; and a static archiver ar. It also selects all found from the list m4 rpm.

On Windows systems, the default tools list selects (first-found): a C compiler from msvc, mingw, gcc, intelc, icl, icc, cc, bcc32; a C++ compiler from msvc, intelc, icc, g++, cXX, bcc32; an assembler from masm, nasm, gas, 386asm; a linker from mslink, gnulink, ilink, linkloc, ilink32; a Fortran compiler from gfortran, g77, ifl, cvf, f95, f90, fortran; and a static archiver from mslib, ar, tlib; It also selects all found from the list msvs, midl.

On MacOS systems, the default tools list selects (first-found): a C compiler from gcc, cc; a C++ compiler from g++, cXX; an assembler as; a linker from applelink, gnulink; a Fortran compiler from gfortran, f95, f90, g77; and a static archiver ar. It also selects all found from the list m4, rpm.

Default lists for other platforms can be found by examining the scons source code (see SCons/Tool/__init__.py).

dmd

Sets construction variables for D language compiler DMD.

Sets: $DC, $DCOM, $DDEBUG, $DDEBUGPREFIX, $DDEBUGSUFFIX, $DFILESUFFIX, $DFLAGPREFIX, $DFLAGS, $DFLAGSUFFIX, $DINCPREFIX, $DINCSUFFIX, $DLIB, $DLIBCOM, $DLIBDIRPREFIX, $DLIBDIRSUFFIX, $DLIBFLAGPREFIX, $DLIBFLAGSUFFIX, $DLIBLINKPREFIX, $DLIBLINKSUFFIX, $DLINK, $DLINKCOM, $DLINKFLAGPREFIX, $DLINKFLAGS, $DLINKFLAGSUFFIX, $DPATH, $DRPATHPREFIX, $DRPATHSUFFIX, $DVERPREFIX, $DVERSIONS, $DVERSUFFIX, $SHDC, $SHDCOM, $SHDLIBVERSIONFLAGS, $SHDLINK, $SHDLINKCOM, $SHDLINKFLAGS.

docbook

This tool tries to make working with Docbook in SCons a little easier. It provides several toolchains for creating different output formats, like HTML or PDF. Contained in the package is a distribution of the Docbook XSL stylesheets as of version 1.76.1. As long as you don't specify your own stylesheets for customization, these official versions are picked as default...which should reduce the inevitable setup hassles for you.

Implicit dependencies to images and XIncludes are detected automatically if you meet the HTML requirements. The additional stylesheet utils/xmldepend.xsl by Paul DuBois is used for this purpose.

Note, that there is no support for XML catalog resolving offered! This tool calls the XSLT processors and PDF renderers with the stylesheets you specified, that's it. The rest lies in your hands and you still have to know what you're doing when resolving names via a catalog.

For activating the tool "docbook", you have to add its name to the Environment constructor, like this

env = Environment(tools=['docbook'])

On its startup, the docbook tool tries to find a required xsltproc processor, and a PDF renderer, e.g. fop. So make sure that these are added to your system's environment PATH and can be called directly without specifying their full path.

For the most basic processing of Docbook to HTML, you need to have installed

* the Python lxml binding to libxml2, or

* a standalone XSLT processor, currently detected are xsltproc, saxon, saxon-xslt and xalan.

Rendering to PDF requires you to have one of the applications fop or xep installed.

Creating a HTML or PDF document is very simple and straightforward. Say

env = Environment(tools=['docbook'])
env.DocbookHtml('manual.html', 'manual.xml')
env.DocbookPdf('manual.pdf', 'manual.xml')

to get both outputs from your XML source manual.xml. As a shortcut, you can give the stem of the filenames alone, like this:

env = Environment(tools=['docbook'])
env.DocbookHtml('manual')
env.DocbookPdf('manual')

and get the same result. Target and source lists are also supported:

env = Environment(tools=['docbook'])
env.DocbookHtml(['manual.html','reference.html'], ['manual.xml','reference.xml'])

or even

env = Environment(tools=['docbook'])
env.DocbookHtml(['manual','reference'])

Important
Whenever you leave out the list of sources, you may not specify a file extension! The Tool uses the given names as file stems, and adds the suffixes for target and source files accordingly.

The rules given above are valid for the Builders DocbookHtml, DocbookPdf, DocbookEpub, DocbookSlidesPdf and DocbookXInclude. For the DocbookMan transformation you can specify a target name, but the actual output names are automatically set from the refname entries in your XML source.

The Builders DocbookHtmlChunked, DocbookHtmlhelp and DocbookSlidesHtml are special, in that:

1. they create a large set of files, where the exact names and their number depend on the content of the source file, and

2. the main target is always named index.html, i.e. the output name for the XSL transformation is not picked up by the stylesheets.

As a result, there is simply no use in specifying a target HTML name. So the basic syntax for these builders is always:

env = Environment(tools=['docbook'])
env.DocbookHtmlhelp('manual')

If you want to use a specific XSL file, you can set the additional xsl parameter to your Builder call as follows:

env.DocbookHtml('other.html', 'manual.xml', xsl='html.xsl')

Since this may get tedious if you always use the same local naming for your customized XSL files, e.g. html.xsl for HTML and pdf.xsl for PDF output, a set of variables for setting the default XSL name is provided. These are:

DOCBOOK_DEFAULT_XSL_HTML
DOCBOOK_DEFAULT_XSL_HTMLCHUNKED
DOCBOOK_DEFAULT_XSL_HTMLHELP
DOCBOOK_DEFAULT_XSL_PDF
DOCBOOK_DEFAULT_XSL_EPUB
DOCBOOK_DEFAULT_XSL_MAN
DOCBOOK_DEFAULT_XSL_SLIDESPDF
DOCBOOK_DEFAULT_XSL_SLIDESHTML

and you can set them when constructing your environment:

env = Environment(
    tools=['docbook'],
    DOCBOOK_DEFAULT_XSL_HTML='html.xsl',
    DOCBOOK_DEFAULT_XSL_PDF='pdf.xsl',
)
env.DocbookHtml('manual')  # now uses html.xsl

Sets: $DOCBOOK_DEFAULT_XSL_EPUB, $DOCBOOK_DEFAULT_XSL_HTML, $DOCBOOK_DEFAULT_XSL_HTMLCHUNKED, $DOCBOOK_DEFAULT_XSL_HTMLHELP, $DOCBOOK_DEFAULT_XSL_MAN, $DOCBOOK_DEFAULT_XSL_PDF, $DOCBOOK_DEFAULT_XSL_SLIDESHTML, $DOCBOOK_DEFAULT_XSL_SLIDESPDF, $DOCBOOK_FOP, $DOCBOOK_FOPCOM, $DOCBOOK_FOPFLAGS, $DOCBOOK_XMLLINT, $DOCBOOK_XMLLINTCOM, $DOCBOOK_XMLLINTFLAGS, $DOCBOOK_XSLTPROC, $DOCBOOK_XSLTPROCCOM, $DOCBOOK_XSLTPROCFLAGS, $DOCBOOK_XSLTPROCPARAMS.

Uses: $DOCBOOK_FOPCOMSTR, $DOCBOOK_XMLLINTCOMSTR, $DOCBOOK_XSLTPROCCOMSTR.

dvi

Attaches the DVI builder to the construction environment.

dvipdf

Sets construction variables for the dvipdf utility.

Sets: $DVIPDF, $DVIPDFCOM, $DVIPDFFLAGS.

Uses: $DVIPDFCOMSTR.

dvips

Sets construction variables for the dvips utility.

Sets: $DVIPS, $DVIPSFLAGS, $PSCOM, $PSPREFIX, $PSSUFFIX.

Uses: $PSCOMSTR.

f03

Set construction variables for generic POSIX Fortran 03 compilers.

Sets: $F03, $F03COM, $F03FLAGS, $F03PPCOM, $SHF03, $SHF03COM, $SHF03FLAGS, $SHF03PPCOM, $_F03INCFLAGS.

Uses: $F03COMSTR, $F03PPCOMSTR, $FORTRANCOMMONFLAGS, $SHF03COMSTR, $SHF03PPCOMSTR.

f08

Set construction variables for generic POSIX Fortran 08 compilers.

Sets: $F08, $F08COM, $F08FLAGS, $F08PPCOM, $SHF08, $SHF08COM, $SHF08FLAGS, $SHF08PPCOM, $_F08INCFLAGS.

Uses: $F08COMSTR, $F08PPCOMSTR, $FORTRANCOMMONFLAGS, $SHF08COMSTR, $SHF08PPCOMSTR.

f77

Set construction variables for generic POSIX Fortran 77 compilers.

Sets: $F77, $F77COM, $F77FILESUFFIXES, $F77FLAGS, $F77PPCOM, $F77PPFILESUFFIXES, $FORTRAN, $FORTRANCOM, $FORTRANFLAGS, $SHF77, $SHF77COM, $SHF77FLAGS, $SHF77PPCOM, $SHFORTRAN, $SHFORTRANCOM, $SHFORTRANFLAGS, $SHFORTRANPPCOM, $_F77INCFLAGS.

Uses: $F77COMSTR, $F77PPCOMSTR, $FORTRANCOMMONFLAGS, $FORTRANCOMSTR, $FORTRANFLAGS, $FORTRANPPCOMSTR, $SHF77COMSTR, $SHF77PPCOMSTR, $SHFORTRANCOMSTR, $SHFORTRANFLAGS, $SHFORTRANPPCOMSTR.

f90

Set construction variables for generic POSIX Fortran 90 compilers.

Sets: $F90, $F90COM, $F90FLAGS, $F90PPCOM, $SHF90, $SHF90COM, $SHF90FLAGS, $SHF90PPCOM, $_F90INCFLAGS.

Uses: $F90COMSTR, $F90PPCOMSTR, $FORTRANCOMMONFLAGS, $SHF90COMSTR, $SHF90PPCOMSTR.

f95

Set construction variables for generic POSIX Fortran 95 compilers.

Sets: $F95, $F95COM, $F95FLAGS, $F95PPCOM, $SHF95, $SHF95COM, $SHF95FLAGS, $SHF95PPCOM, $_F95INCFLAGS.

Uses: $F95COMSTR, $F95PPCOMSTR, $FORTRANCOMMONFLAGS, $SHF95COMSTR, $SHF95PPCOMSTR.

fortran

Set construction variables for generic POSIX Fortran compilers.

Sets: $FORTRAN, $FORTRANCOM, $FORTRANFLAGS, $SHFORTRAN, $SHFORTRANCOM, $SHFORTRANFLAGS, $SHFORTRANPPCOM.

Uses: $CPPFLAGS, $FORTRANCOMSTR, $FORTRANPPCOMSTR, $SHFORTRANCOMSTR, $SHFORTRANPPCOMSTR, $_CPPDEFFLAGS.

g++

Set construction variables for the g++ C++ compiler.

Sets: $CXX, $CXXVERSION, $SHCXXFLAGS, $SHOBJSUFFIX.

g77

Set construction variables for the g77 Fortran compiler.

Sets: $F77, $F77COM, $F77FILESUFFIXES, $F77PPCOM, $F77PPFILESUFFIXES, $FORTRAN, $FORTRANCOM, $FORTRANPPCOM, $SHF77, $SHF77COM, $SHF77FLAGS, $SHF77PPCOM, $SHFORTRAN, $SHFORTRANCOM, $SHFORTRANFLAGS, $SHFORTRANPPCOM.

Uses: $F77FLAGS, $FORTRANCOMMONFLAGS, $FORTRANFLAGS.

gas

Sets construction variables for the gas assembler. Calls the as tool.

Sets: $AS.

gcc

Set construction variables for the gcc C compiler.

Sets: $CC, $CCDEPFLAGS, $CCVERSION, $SHCCFLAGS.

gdc

Sets construction variables for the D language compiler GDC.

Sets: $DC, $DCOM, $DDEBUG, $DDEBUGPREFIX, $DDEBUGSUFFIX, $DFILESUFFIX, $DFLAGPREFIX, $DFLAGS, $DFLAGSUFFIX, $DINCPREFIX, $DINCSUFFIX, $DLIB, $DLIBCOM, $DLIBDIRPREFIX, $DLIBDIRSUFFIX, $DLIBFLAGPREFIX, $DLIBFLAGSUFFIX, $DLIBLINKPREFIX, $DLIBLINKSUFFIX, $DLINK, $DLINKCOM, $DLINKFLAGPREFIX, $DLINKFLAGS, $DLINKFLAGSUFFIX, $DPATH, $DRPATHPREFIX, $DRPATHSUFFIX, $DVERPREFIX, $DVERSIONS, $DVERSUFFIX, $SHDC, $SHDCOM, $SHDLIBVERSIONFLAGS, $SHDLINK, $SHDLINKCOM, $SHDLINKFLAGS.

gettext

A toolset supporting internationalization and localization of software being constructed with SCons. The toolset loads the following tools:

*

xgettext - extract internationalized messages from source code to POT file(s).

*

msginit - initialize PO files during initial translation of a project.

*

msgmerge - update PO files that already contain translated messages,

*

msgfmt - compile textual PO files to binary installable MO files.

When you enable gettext, it internally loads all the above-mentioned tools, so you're encouraged to see their individual documentation.

Each of the above tools provides its own builder(s) which may be used to perform particular activities related to software internationalization. You may be however interested in top-level Translate builder.

To use the gettext tools, add the 'gettext' tool to your construction environment:

env = Environment(tools=['default', 'gettext'])

gfortran

Sets construction variables for the GNU Fortran compiler. Calls the fortran Tool module to set variables.

Sets: $F77, $F90, $F95, $FORTRAN, $SHF77, $SHF77FLAGS, $SHF90, $SHF90FLAGS, $SHF95, $SHF95FLAGS, $SHFORTRAN, $SHFORTRANFLAGS.

gnulink

Set construction variables for GNU linker/loader.

Sets: $LDMODULEVERSIONFLAGS, $RPATHPREFIX, $RPATHSUFFIX, $SHLIBVERSIONFLAGS, $SHLINKFLAGS, $_LDMODULESONAME, $_SHLIBSONAME.

gs

This Tool sets the required construction variables for working with the Ghostscript software. It also registers an appropriate Action with the PDF Builder, such that the conversion from PS/EPS to PDF happens automatically for the TeX/LaTeX toolchain. Finally, it adds an explicit Gs Builder for Ghostscript to the environment.

Sets: $GS, $GSCOM, $GSFLAGS.

Uses: $GSCOMSTR.

hpc++

Set construction variables for the compilers aCC on HP/UX systems.

hpcc

Set construction variables for aCC compilers on HP/UX systems. Calls the cXX tool for additional variables.

Sets: $CXX, $CXXVERSION, $SHCXXFLAGS.

hplink

Sets construction variables for the linker on HP/UX systems.

Sets: $LINKFLAGS, $SHLIBSUFFIX, $SHLINKFLAGS.

icc

Sets construction variables for the icc compiler on OS/2 systems.

Sets: $CC, $CCCOM, $CFILESUFFIX, $CPPDEFPREFIX, $CPPDEFSUFFIX, $CXXCOM, $CXXFILESUFFIX, $INCPREFIX, $INCSUFFIX.

Uses: $CCFLAGS, $CFLAGS, $CPPFLAGS, $_CPPDEFFLAGS, $_CPPINCFLAGS.

icl

Sets construction variables for the Intel C/C++ compiler. Calls the intelc Tool module to set its variables.

ifl

Sets construction variables for the Intel Fortran compiler.

Sets: $FORTRAN, $FORTRANCOM, $FORTRANPPCOM, $SHFORTRANCOM, $SHFORTRANPPCOM.

Uses: $CPPFLAGS, $FORTRANFLAGS, $_CPPDEFFLAGS, $_FORTRANINCFLAGS.

ifort

Sets construction variables for newer versions of the Intel Fortran compiler for Linux.

Sets: $F77, $F90, $F95, $FORTRAN, $SHF77, $SHF77FLAGS, $SHF90, $SHF90FLAGS, $SHF95, $SHF95FLAGS, $SHFORTRAN, $SHFORTRANFLAGS.

ilink

Sets construction variables for the ilink linker on OS/2 systems.

Sets: $LIBDIRPREFIX, $LIBDIRSUFFIX, $LIBLINKPREFIX, $LIBLINKSUFFIX, $LINK, $LINKCOM, $LINKFLAGS.

ilink32

Sets construction variables for the Borland ilink32 linker.

Sets: $LIBDIRPREFIX, $LIBDIRSUFFIX, $LIBLINKPREFIX, $LIBLINKSUFFIX, $LINK, $LINKCOM, $LINKFLAGS.

install

Sets construction variables for file and directory installation.

Sets: $INSTALL, $INSTALLSTR.

intelc

Sets construction variables for the Intel C/C++ compiler (Linux and Windows, version 7 and later). Calls the gcc or msvc (on Linux and Windows, respectively) tool to set underlying variables.

Sets: $AR, $CC, $CXX, $INTEL_C_COMPILER_VERSION, $LINK.

jar

Sets construction variables for the jar utility.

Sets: $JAR, $JARCOM, $JARFLAGS, $JARSUFFIX.

Uses: $JARCOMSTR.

javac

Sets construction variables for the javac compiler.

Sets: $JAVABOOTCLASSPATH, $JAVAC, $JAVACCOM, $JAVACFLAGS, $JAVACLASSPATH, $JAVACLASSSUFFIX, $JAVAINCLUDES, $JAVASOURCEPATH, $JAVASUFFIX.

Uses: $JAVACCOMSTR.

javah

Sets construction variables for the javah tool.

Sets: $JAVACLASSSUFFIX, $JAVAH, $JAVAHCOM, $JAVAHFLAGS.

Uses: $JAVACLASSPATH, $JAVAHCOMSTR.

latex

Sets construction variables for the latex utility.

Sets: $LATEX, $LATEXCOM, $LATEXFLAGS.

Uses: $LATEXCOMSTR.

ldc

Sets construction variables for the D language compiler LDC2.

Sets: $DC, $DCOM, $DDEBUG, $DDEBUGPREFIX, $DDEBUGSUFFIX, $DFILESUFFIX, $DFLAGPREFIX, $DFLAGS, $DFLAGSUFFIX, $DINCPREFIX, $DINCSUFFIX, $DLIB, $DLIBCOM, $DLIBDIRPREFIX, $DLIBDIRSUFFIX, $DLIBFLAGPREFIX, $DLIBFLAGSUFFIX, $DLIBLINKPREFIX, $DLIBLINKSUFFIX, $DLINK, $DLINKCOM, $DLINKFLAGPREFIX, $DLINKFLAGS, $DLINKFLAGSUFFIX, $DPATH, $DRPATHPREFIX, $DRPATHSUFFIX, $DVERPREFIX, $DVERSIONS, $DVERSUFFIX, $SHDC, $SHDCOM, $SHDLIBVERSIONFLAGS, $SHDLINK, $SHDLINKCOM, $SHDLINKFLAGS.

lex

Sets construction variables for the lex lexical analyzer.

Sets: $LEX, $LEXCOM, $LEXFLAGS, $LEXUNISTD.

Uses: $LEXCOMSTR, $LEXFLAGS, $LEX_HEADER_FILE, $LEX_TABLES_FILE.

link

Sets construction variables for generic POSIX linkers. This is a "smart" linker tool which selects a compiler to complete the linking based on the types of source files.

Sets: $LDMODULE, $LDMODULECOM, $LDMODULEFLAGS, $LDMODULENOVERSIONSYMLINKS, $LDMODULEPREFIX, $LDMODULESUFFIX, $LDMODULEVERSION, $LDMODULEVERSIONFLAGS, $LIBDIRPREFIX, $LIBDIRSUFFIX, $LIBLINKPREFIX, $LIBLINKSUFFIX, $LINK, $LINKCOM, $LINKFLAGS, $SHLIBSUFFIX, $SHLINK, $SHLINKCOM, $SHLINKFLAGS, $__LDMODULEVERSIONFLAGS, $__SHLIBVERSIONFLAGS.

Uses: $LDMODULECOMSTR, $LINKCOMSTR, $SHLINKCOMSTR.

linkloc

Sets construction variables for the LinkLoc linker for the Phar Lap ETS embedded operating system.

Sets: $LIBDIRPREFIX, $LIBDIRSUFFIX, $LIBLINKPREFIX, $LIBLINKSUFFIX, $LINK, $LINKCOM, $LINKFLAGS, $SHLINK, $SHLINKCOM, $SHLINKFLAGS.

Uses: $LINKCOMSTR, $SHLINKCOMSTR.

m4

Sets construction variables for the m4 macro processor.

Sets: $M4, $M4COM, $M4FLAGS.

Uses: $M4COMSTR.

masm

Sets construction variables for the Microsoft assembler.

Sets: $AS, $ASCOM, $ASFLAGS, $ASPPCOM, $ASPPFLAGS.

Uses: $ASCOMSTR, $ASPPCOMSTR, $CPPFLAGS, $_CPPDEFFLAGS, $_CPPINCFLAGS.

midl

Sets construction variables for the Microsoft IDL compiler.

Sets: $MIDL, $MIDLCOM, $MIDLFLAGS.

Uses: $MIDLCOMSTR.

mingw

Sets construction variables for MinGW (Minimal Gnu on Windows).

Sets: $AS, $CC, $CXX, $LDMODULECOM, $LIBPREFIX, $LIBSUFFIX, $OBJSUFFIX, $RC, $RCCOM, $RCFLAGS, $RCINCFLAGS, $RCINCPREFIX, $RCINCSUFFIX, $SHCCFLAGS, $SHCXXFLAGS, $SHLINKCOM, $SHLINKFLAGS, $SHOBJSUFFIX, $WINDOWSDEFPREFIX, $WINDOWSDEFSUFFIX.

Uses: $RCCOMSTR, $SHLINKCOMSTR.

msgfmt

This tool is a part of the gettext toolset. It provides SCons an interface to the msgfmt(1) command by setting up the MOFiles builder, which generates binary message catalog (MO) files from a textual translation description (PO files).

Sets: $MOSUFFIX, $MSGFMT, $MSGFMTCOM, $MSGFMTCOMSTR, $MSGFMTFLAGS, $POSUFFIX.

Uses: $LINGUAS_FILE.

msginit

This tool is a part of scons gettext toolset. It provides SCons an interface to the msginit(1) program, by setting up the POInit builder, which creates a new PO file, initializing the meta information with values from the construction environment (or options).

Sets: $MSGINIT, $MSGINITCOM, $MSGINITCOMSTR, $MSGINITFLAGS, $POAUTOINIT, $POCREATE_ALIAS, $POSUFFIX, $POTSUFFIX, $_MSGINITLOCALE.

Uses: $LINGUAS_FILE, $POAUTOINIT, $POTDOMAIN.

msgmerge

This tool is a part of scons gettext toolset. It provides SCons an interface to the msgmerge(1) command, by setting up the POUpdate builder, which merges two Uniform style .po files together.

Sets: $MSGMERGE, $MSGMERGECOM, $MSGMERGECOMSTR, $MSGMERGEFLAGS, $POSUFFIX, $POTSUFFIX, $POUPDATE_ALIAS.

Uses: $LINGUAS_FILE, $POAUTOINIT, $POTDOMAIN.

mslib

Sets construction variables for the Microsoft mslib library archiver.

Sets: $AR, $ARCOM, $ARFLAGS, $LIBPREFIX, $LIBSUFFIX.

Uses: $ARCOMSTR.

mslink

Sets construction variables for the Microsoft linker.

Sets: $LDMODULE, $LDMODULECOM, $LDMODULEFLAGS, $LDMODULEPREFIX, $LDMODULESUFFIX, $LIBDIRPREFIX, $LIBDIRSUFFIX, $LIBLINKPREFIX, $LIBLINKSUFFIX, $LINK, $LINKCOM, $LINKFLAGS, $REGSVR, $REGSVRCOM, $REGSVRFLAGS, $SHLINK, $SHLINKCOM, $SHLINKFLAGS, $WINDOWSDEFPREFIX, $WINDOWSDEFSUFFIX, $WINDOWSEXPPREFIX, $WINDOWSEXPSUFFIX, $WINDOWSPROGMANIFESTPREFIX, $WINDOWSPROGMANIFESTSUFFIX, $WINDOWSSHLIBMANIFESTPREFIX, $WINDOWSSHLIBMANIFESTSUFFIX, $WINDOWS_INSERT_DEF.

Uses: $LDMODULECOMSTR, $LINKCOMSTR, $REGSVRCOMSTR, $SHLINKCOMSTR.

mssdk

Sets variables for Microsoft Platform SDK and/or Windows SDK. Note that unlike most other Tool modules, mssdk does not set construction variables, but sets the environment variables in the environment SCons uses to execute the Microsoft toolchain: %INCLUDE%, %LIB%, %LIBPATH% and %PATH%.

Uses: $MSSDK_DIR, $MSSDK_VERSION, $MSVS_VERSION.

msvc

Sets construction variables for the Microsoft Visual C++ compiler.

Sets: $BUILDERS, $CC, $CCCOM, $CCDEPFLAGS, $CCFLAGS, $CCPCHFLAGS, $CCPDBFLAGS, $CFILESUFFIX, $CFLAGS, $CPPDEFPREFIX, $CPPDEFSUFFIX, $CXX, $CXXCOM, $CXXFILESUFFIX, $CXXFLAGS, $INCPREFIX, $INCSUFFIX, $OBJPREFIX, $OBJSUFFIX, $PCHCOM, $PCHPDBFLAGS, $RC, $RCCOM, $RCFLAGS, $SHCC, $SHCCCOM, $SHCCFLAGS, $SHCFLAGS, $SHCXX, $SHCXXCOM, $SHCXXFLAGS, $SHOBJPREFIX, $SHOBJSUFFIX.

Uses: $CCCOMSTR, $CXXCOMSTR, $MSVC_NOTFOUND_POLICY, $MSVC_SCRIPTERROR_POLICY, $MSVC_SCRIPT_ARGS, $MSVC_SDK_VERSION, $MSVC_SPECTRE_LIBS, $MSVC_TOOLSET_VERSION, $MSVC_USE_SCRIPT, $MSVC_USE_SCRIPT_ARGS, $MSVC_USE_SETTINGS, $MSVC_VERSION, $PCH, $PCHSTOP, $PDB, $SHCCCOMSTR, $SHCXXCOMSTR.

msvs

Sets construction variables for Microsoft Visual Studio.

Sets: $MSVSBUILDCOM, $MSVSCLEANCOM, $MSVSENCODING, $MSVSPROJECTCOM, $MSVSREBUILDCOM, $MSVSSCONS, $MSVSSCONSCOM, $MSVSSCONSCRIPT, $MSVSSCONSFLAGS, $MSVSSOLUTIONCOM.

mwcc

Sets construction variables for the Metrowerks CodeWarrior compiler.

Sets: $CC, $CCCOM, $CFILESUFFIX, $CPPDEFPREFIX, $CPPDEFSUFFIX, $CXX, $CXXCOM, $CXXFILESUFFIX, $INCPREFIX, $INCSUFFIX, $MWCW_VERSION, $MWCW_VERSIONS, $SHCC, $SHCCCOM, $SHCCFLAGS, $SHCFLAGS, $SHCXX, $SHCXXCOM, $SHCXXFLAGS.

Uses: $CCCOMSTR, $CXXCOMSTR, $SHCCCOMSTR, $SHCXXCOMSTR.

mwld

Sets construction variables for the Metrowerks CodeWarrior linker.

Sets: $AR, $ARCOM, $LIBDIRPREFIX, $LIBDIRSUFFIX, $LIBLINKPREFIX, $LIBLINKSUFFIX, $LINK, $LINKCOM, $SHLINK, $SHLINKCOM, $SHLINKFLAGS.

nasm

Sets construction variables for the nasm Netwide Assembler.

Sets: $AS, $ASCOM, $ASFLAGS, $ASPPCOM, $ASPPFLAGS.

Uses: $ASCOMSTR, $ASPPCOMSTR.

ninja

Sets up the Ninja builder, which generates a ninja build file, and then optionally runs ninja.

Note
This is an experimental feature. This functionality is subject to change and/or removal without a deprecation cycle.

Sets: $IMPLICIT_COMMAND_DEPENDENCIES, $NINJA_ALIAS_NAME, $NINJA_CMD_ARGS, $NINJA_COMPDB_EXPAND, $NINJA_DEPFILE_PARSE_FORMAT, $NINJA_DIR, $NINJA_DISABLE_AUTO_RUN, $NINJA_ENV_VAR_CACHE, $NINJA_FILE_NAME, $NINJA_FORCE_SCONS_BUILD, $NINJA_GENERATED_SOURCE_ALIAS_NAME, $NINJA_GENERATED_SOURCE_SUFFIXES, $NINJA_MSVC_DEPS_PREFIX, $NINJA_POOL, $NINJA_REGENERATE_DEPS, $NINJA_SCONS_DAEMON_KEEP_ALIVE, $NINJA_SCONS_DAEMON_PORT, $NINJA_SYNTAX, $_NINJA_REGENERATE_DEPS_FUNC.

Uses: $AR, $ARCOM, $ARFLAGS, $CC, $CCCOM, $CCDEPFLAGS, $CCFLAGS, $CXX, $CXXCOM, $ESCAPE, $LINK, $LINKCOM, $PLATFORM, $PRINT_CMD_LINE_FUNC, $PROGSUFFIX, $RANLIB, $RANLIBCOM, $SHCCCOM, $SHCXXCOM, $SHLINK, $SHLINKCOM.

packaging

Sets construction variables for the Package Builder. If this tool is enabled, the --package-type command-line option is also enabled.

pdf

Sets construction variables for the Portable Document Format builder.

Sets: $PDFPREFIX, $PDFSUFFIX.

pdflatex

Sets construction variables for the pdflatex utility.

Sets: $LATEXRETRIES, $PDFLATEX, $PDFLATEXCOM, $PDFLATEXFLAGS.

Uses: $PDFLATEXCOMSTR.

pdftex

Sets construction variables for the pdftex utility.

Sets: $LATEXRETRIES, $PDFLATEX, $PDFLATEXCOM, $PDFLATEXFLAGS, $PDFTEX, $PDFTEXCOM, $PDFTEXFLAGS.

Uses: $PDFLATEXCOMSTR, $PDFTEXCOMSTR.

python

Loads the Python source scanner into the invoking environment. When loaded, the scanner will attempt to find implicit dependencies for any Python source files in the list of sources provided to an Action that uses this environment.

Available since scons 4.0..

qt

Placeholder tool to alert anyone still using qt tools to switch to qt3 or newer tool.

qt3

Sets construction variables for building Qt3 applications.

Note
This tool is only suitable for building targeted to Qt3, which is obsolete (the tool is deprecated since 4.3, and was renamed to qt3 in 4.5.0. ). There are contributed tools for Qt4 and Qt5, see m[blue]https://github.com/SCons/scons-contribm[][1]. Qt4 has also passed end of life for standard support (in Dec 2015).

Note paths for these construction variables are assembled using the os.path.join method so they will have the appropriate separator at runtime, but are listed here in the various entries only with the '/' separator for simplicity.

In addition, the construction variables $CPPPATH, $LIBPATH and $LIBS may be modified and the variables $PROGEMITTER, $SHLIBEMITTER and $LIBEMITTER are modified. Because the build-performance is affected when using this tool, you have to explicitly specify it at Environment creation:

Environment(tools=['default','qt3'])

The qt3 tool supports the following operations:

Automatic moc file generation from header files. You do not have to specify moc files explicitly, the tool does it for you. However, there are a few preconditions to do so: Your header file must have the same basename as your implementation file and must stay in the same directory. It must have one of the suffixes .h, .hpp, .H, .hxx, .hh. You can turn off automatic moc file generation by setting $QT3_AUTOSCAN to False. See also the corresponding Moc Builder.

Automatic moc file generation from C++ files. As described in the Qt documentation, include the moc file at the end of the C++ file. Note that you have to include the file, which is generated by the transformation ${QT3_MOCCXXPREFIX}<basename>${QT3_MOCCXXSUFFIX}, by default <basename>.mo. A warning is generated after building the moc file if you do not include the correct file. If you are using VariantDir, you may need to specify duplicate=True. You can turn off automatic moc file generation by setting $QT3_AUTOSCAN to False. See also the corresponding Moc Builder.

Automatic handling of .ui files. The implementation files generated from .ui files are handled much the same as yacc or lex files. Each .ui file given as a source of Program, Library or SharedLibrary will generate three files: the declaration file, the implementation file and a moc file. Because there are also generated headers, you may need to specify duplicate=True in calls to VariantDir. See also the corresponding Uic Builder.

Sets: $QT3DIR, $QT3_AUTOSCAN, $QT3_BINPATH, $QT3_CPPPATH, $QT3_LIB, $QT3_LIBPATH, $QT3_MOC, $QT3_MOCCXXPREFIX, $QT3_MOCCXXSUFFIX, $QT3_MOCFROMCXXCOM, $QT3_MOCFROMCXXFLAGS, $QT3_MOCFROMHCOM, $QT3_MOCFROMHFLAGS, $QT3_MOCHPREFIX, $QT3_MOCHSUFFIX, $QT3_UIC, $QT3_UICCOM, $QT3_UICDECLFLAGS, $QT3_UICDECLPREFIX, $QT3_UICDECLSUFFIX, $QT3_UICIMPLFLAGS, $QT3_UICIMPLPREFIX, $QT3_UICIMPLSUFFIX, $QT3_UISUFFIX.

Uses: $QT3DIR.

rmic

Sets construction variables for the rmic utility.

Sets: $JAVACLASSSUFFIX, $RMIC, $RMICCOM, $RMICFLAGS.

Uses: $RMICCOMSTR.

rpcgen

Sets construction variables for building with RPCGEN.

Sets: $RPCGEN, $RPCGENCLIENTFLAGS, $RPCGENFLAGS, $RPCGENHEADERFLAGS, $RPCGENSERVICEFLAGS, $RPCGENXDRFLAGS.

sgiar

Sets construction variables for the SGI library archiver.

Sets: $AR, $ARCOMSTR, $ARFLAGS, $LIBPREFIX, $LIBSUFFIX, $SHLINK, $SHLINKFLAGS.

Uses: $ARCOMSTR, $SHLINKCOMSTR.

sgic++

Sets construction variables for the SGI C++ compiler.

Sets: $CXX, $CXXFLAGS, $SHCXX, $SHOBJSUFFIX.

sgicc

Sets construction variables for the SGI C compiler.

Sets: $CXX, $SHOBJSUFFIX.

sgilink

Sets construction variables for the SGI linker.

Sets: $LINK, $RPATHPREFIX, $RPATHSUFFIX, $SHLINKFLAGS.

sunar

Sets construction variables for the Sun library archiver.

Sets: $AR, $ARCOM, $ARFLAGS, $LIBPREFIX, $LIBSUFFIX.

Uses: $ARCOMSTR.

sunc++

Sets construction variables for the Sun C++ compiler.

Sets: $CXX, $CXXVERSION, $SHCXX, $SHCXXFLAGS, $SHOBJPREFIX, $SHOBJSUFFIX.

suncc

Sets construction variables for the Sun C compiler.

Sets: $CXX, $SHCCFLAGS, $SHOBJPREFIX, $SHOBJSUFFIX.

sunf77

Set construction variables for the Sun f77 Fortran compiler.

Sets: $F77, $FORTRAN, $SHF77, $SHF77FLAGS, $SHFORTRAN, $SHFORTRANFLAGS.

sunf90

Set construction variables for the Sun f90 Fortran compiler.

Sets: $F90, $FORTRAN, $SHF90, $SHF90FLAGS, $SHFORTRAN, $SHFORTRANFLAGS.

sunf95

Set construction variables for the Sun f95 Fortran compiler.

Sets: $F95, $FORTRAN, $SHF95, $SHF95FLAGS, $SHFORTRAN, $SHFORTRANFLAGS.

sunlink

Sets construction variables for the Sun linker.

Sets: $RPATHPREFIX, $RPATHSUFFIX, $SHLINKFLAGS.

swig

Sets construction variables for the SWIG interface compiler.

Sets: $SWIG, $SWIGCFILESUFFIX, $SWIGCOM, $SWIGCXXFILESUFFIX, $SWIGDIRECTORSUFFIX, $SWIGFLAGS, $SWIGINCPREFIX, $SWIGINCSUFFIX, $SWIGPATH, $SWIGVERSION, $_SWIGINCFLAGS.

Uses: $SWIGCOMSTR.

tar

Sets construction variables for the tar archiver.

Sets: $TAR, $TARCOM, $TARFLAGS, $TARSUFFIX.

Uses: $TARCOMSTR.

tex

Sets construction variables for the TeX formatter and typesetter.

Sets: $BIBTEX, $BIBTEXCOM, $BIBTEXFLAGS, $LATEX, $LATEXCOM, $LATEXFLAGS, $MAKEINDEX, $MAKEINDEXCOM, $MAKEINDEXFLAGS, $TEX, $TEXCOM, $TEXFLAGS.

Uses: $BIBTEXCOMSTR, $LATEXCOMSTR, $MAKEINDEXCOMSTR, $TEXCOMSTR.

textfile

Set construction variables for the Textfile and Substfile builders.

Sets: $FILE_ENCODING, $LINESEPARATOR, $SUBSTFILEPREFIX, $SUBSTFILESUFFIX, $TEXTFILEPREFIX, $TEXTFILESUFFIX.

Uses: $SUBST_DICT.

tlib

Sets construction variables for the Borland tlib library archiver.

Sets: $AR, $ARCOM, $ARFLAGS, $LIBPREFIX, $LIBSUFFIX.

Uses: $ARCOMSTR.

xgettext

This tool is a part of the gettext toolset. It provides SCons an interface to the xgettext(1) program, which extracts internationalized messages from source code. The tool sets up the POTUpdate builder to make PO Template files.

Sets: $POTSUFFIX, $POTUPDATE_ALIAS, $XGETTEXTCOM, $XGETTEXTCOMSTR, $XGETTEXTFLAGS, $XGETTEXTFROM, $XGETTEXTFROMPREFIX, $XGETTEXTFROMSUFFIX, $XGETTEXTPATH, $XGETTEXTPATHPREFIX, $XGETTEXTPATHSUFFIX, $_XGETTEXTDOMAIN, $_XGETTEXTFROMFLAGS, $_XGETTEXTPATHFLAGS.

Uses: $POTDOMAIN.

yacc

Sets construction variables for the yacc parser generator.

Sets: $YACC, $YACCCOM, $YACCFLAGS, $YACCHFILESUFFIX, $YACCHXXFILESUFFIX, $YACCVCGFILESUFFIX, $YACC_GRAPH_FILE_SUFFIX.

Uses: $YACCCOMSTR, $YACCFLAGS, $YACC_GRAPH_FILE, $YACC_HEADER_FILE.

zip

Sets construction variables for the zip archiver.

Sets: $ZIP, $ZIPCOM, $ZIPCOMPRESSION, $ZIPFLAGS, $ZIPSUFFIX.

Uses: $ZIPCOMSTR.

Builder Methods

You tell SCons what to build by calling Builders, functions which take particular action(s) to produce target(s) of a particular type (conventionally hinted at by the builder name, e.g. Program) from the specified source files. A builder call is a declaration: SCons enters the specified relationship into its internal dependency node graph, and only later makes the decision on whether anything is actually built, since this depends on command-line options, target selection rules, and whether the target(s) are out-of-date with respect to the sources.

SCons provides a number of builders, and you can also write your own (see Builder Objects). Builders are created dynamically at run-time, often (though not always) by tools which determine whether the external dependencies for the builder are satisfied, and which perform the necessary setup (see Tools). Builders are attached to a construction environment as methods. The available builder methods are registered as key-value pairs in the $BUILDERS attribute of the construction environment, so the available builders can be examined. This example displays them for debugging purposes:

env = Environment()
print("Builders:", list(env['BUILDERS']))

Builder methods take two required arguments: target and source. The target and source arguments can be specified either as positional arguments, in which case target comes first, or as keyword arguments, using target= and source=. Although both arguments are nominally required, if there is a single source and the target can be inferred the target argument can be omitted (see below). Builder methods also take a variety of keyword arguments, described below.

Because long lists of file names can lead to a lot of quoting in a builder call, SCons supplies a Split global function and a same-named environment method that splits a single string into a list, using strings of white-space characters as the delimiter (similar to the Python string split method, but succeeds even if the input isn't a string).

The following are equivalent examples of calling the Program builder method:

env.Program('bar', ['bar.c', 'foo.c'])
env.Program('bar', Split('bar.c foo.c'))
env.Program('bar', env.Split('bar.c foo.c'))
env.Program(source=['bar.c', 'foo.c'], target='bar')
env.Program(target='bar', source=Split('bar.c foo.c'))
env.Program(target='bar', source=env.Split('bar.c foo.c'))
env.Program('bar', source='bar.c foo.c'.split())

Sources and targets can be specified as a scalar or as a list, composed of either strings or nodes (more on nodes below). When specifying path strings, Python follows the POSIX pathname convention: if a string begins with the operating system pathname separator (on Windows both the slash and backslash separator are accepted, and any leading drive specifier is ignored for the determination) it is considered an absolute path, otherwise it is a relative path. If the path string contains no separator characters, it is searched for as a file in the current directory. If it contains separator characters, the search follows down from the starting point, which is the top of the directory tree for an absolute path and the current directory for a relative path. The "current directory" in this context is the directory of the SConscript file currently being processed.

SCons also recognizes a third way to specify path strings: if the string begins with the # character it is top-relative - it works like a relative path, but the search follows down from the project top directory rather than from the current directory. The # can optionally be followed by a pathname separator, which is ignored if found in that position. Top-relative paths only work in places where scons will interpret the path (see some examples below). To be used in other contexts the string will need to be converted to a relative or absolute path first.

Examples:

# The comments describing the targets that will be built
# assume these calls are in a SConscript file in the
# a subdirectory named "subdir".

# Builds the program "subdir/foo" from "subdir/foo.c":
env.Program('foo', 'foo.c')

# Builds the program "/tmp/bar" from "subdir/bar.c":
env.Program('/tmp/bar', 'bar.c')

# An initial '#' or '#/' are equivalent; the following
# calls build the programs "foo" and "bar" (in the
# top-level SConstruct directory) from "subdir/foo.c" and
# "subdir/bar.c", respectively:
env.Program('#foo', 'foo.c')
env.Program('#/bar', 'bar.c')

# Builds the program "other/foo" (relative to the top-level
# SConstruct directory) from "subdir/foo.c":
env.Program('#other/foo', 'foo.c')

# This will not work, only SCons interfaces understand '#',
# os.path.exists is pure Python:
if os.path.exists('#inc/foo.h'):
    env.Append(CPPPATH='#inc')

When the target shares the same base name as the source and only the suffix varies, and if the builder method has a suffix defined for the target file type, then the target argument may be omitted completely, and scons will deduce the target file name from the source file name. The following examples all build the executable program bar (on POSIX systems) or bar.exe (on Windows systems) from the bar.c source file:

env.Program(target='bar', source='bar.c')
env.Program('bar', source='bar.c')
env.Program(source='bar.c')
env.Program('bar.c')

The optional srcdir keyword argument specifies that all source file strings that are not absolute paths or top-relative paths shall be interpreted relative to the specified srcdir. The following example will build the build/prog (or build/prog.exe on Windows) program from the files src/f1.c and src/f2.c:

env.Program('build/prog', ['f1.c', 'f2.c'], srcdir='src')

The optional parse_flags keyword argument causes behavior similar to the env.MergeFlags method, where the argument value is broken into individual settings and merged into the appropriate construction variables.

env.Program('hello', 'hello.c', parse_flags='-Iinclude -DEBUG -lm')

This example adds 'include' to the $CPPPATH construction variable, 'EBUG' to $CPPDEFINES, and 'm' to $LIBS.

The optional chdir keyword argument specifies that the Builder's action(s) should be executed after changing directory. If the chdir argument is a path string or a directory Node, scons will change to the specified directory. If the chdir is not a string or Node and evaluates true, then scons will change to the target file's directory.

Warning

Python only keeps one current directory location even if there are multiple threads. This means that use of the chdir argument will not work with the SCons -j option, because individual worker threads spawned by SCons interfere with each other when they start changing directory.

# scons will change to the "sub" subdirectory
# before executing the "cp" command.
env.Command(
    target='sub/dir/foo.out',
    source='sub/dir/foo.in',
    action="cp dir/foo.in dir/foo.out",
    chdir='sub',
)

# Because chdir is not a string, scons will change to the
# target's directory ("sub/dir") before executing the
# "cp" command.
env.Command('sub/dir/foo.out', 'sub/dir/foo.in', "cp foo.in foo.out", chdir=True)

Note that SCons will not automatically modify its expansion of construction variables like $TARGET and $SOURCE when using the chdir keyword argument--that is, the expanded file names will still be relative to the project top directory, and consequently incorrect relative to the chdir directory. If you use the chdir keyword argument, you will typically need to supply a different command line using expansions like ${TARGET.file} and ${SOURCE.file} to use just the filename portion of the target and source.

Keyword arguments that are not specifically recognized are treated as construction variable overrides, which replace or add those variables on a limited basis. These overrides will only be in effect when building the target of the builder call, and will not affect other parts of the build. For example, if you want to specify some libraries needed by just one program:

env.Program('hello', 'hello.c', LIBS=['gl', 'glut'])

or generate a shared library with a non-standard suffix:

env.SharedLibrary(
    target='word',
    source='word.cpp',
    SHLIBSUFFIX='.ocx',
    LIBSUFFIXES=['.ocx'],
)

Note that both the $SHLIBSUFFIX and $LIBSUFFIXES construction variables must be set if you want scons to search automatically for dependencies on the non-standard library names; see the descriptions of these variables for more information.

Although the builder methods defined by scons are, in fact, methods of a construction environment object, many may also be called without an explicit environment:

Program('hello', 'hello.c')
SharedLibrary('word', 'word.cpp')

If called this way, the builder will internally use the Default Environment that consists of the tools and values that scons has determined are appropriate for the local system.

Builder methods that can be called without an explicit environment (indicated in the listing of builders below without a leading env.) may be called from custom Python modules that you import into an SConscript file by adding the following to the Python module:

from SCons.Script import *

A builder may add additional targets beyond those requested if an attached Emitter chooses to do so (see the section called lqBuilder Objectsrq for more information. $PROGEMITTER is an example). For example, the GNU linker takes a command-line argument -Map=mapfile, which causes it to produce a linker map file in addition to the executable file actually being linked. If the Program builder's emitter is configured to add this mapfile if the option is set, then two targets will be returned when you only provided for one.

For this reason, builder methods always return a NodeList, a list-like object whose elements are Nodes. Nodes are the internal representation of build targets or sources (see the section called lqNode Objectsrq for more information). The returned NodeList object can be passed to other builder methods as source(s) or to other SCons functions or methods where a path string would normally be accepted.

For example, to add a specific preprocessor define when compiling one specific object file but not the others:

bar_obj_list = env.StaticObject('bar.c', CPPDEFINES='-DBAR')
env.Program("prog", ['foo.c', bar_obj_list, 'main.c'])

Using a Node as in this example makes for a more portable build by avoiding having to specify a platform-specific object suffix when calling the Program builder method.

The NodeList object is also convenient to pass to the Default function, for the same reason of avoiding a platform-specific name:

tgt = env.Program("prog", ["foo.c", "bar.c", "main.c"])
Default(tgt)

Builder calls will automatically "flatten" lists passed as source and target, so they are free to contain elements which are themselves lists, such as bar_obj_list returned by the StaticObject call. If you need to manipulate a list of lists returned by builders directly in Python code, you can either build a new list by hand:

foo = Object('foo.c')
bar = Object('bar.c')
objects = ['begin.o'] + foo + ['middle.o'] + bar + ['end.o']
for obj in objects:
    print(str(obj))

Or you can use the Flatten function supplied by SCons to create a list containing just the Nodes, which may be more convenient:

foo = Object('foo.c')
bar = Object('bar.c')
objects = Flatten(['begin.o', foo, 'middle.o', bar, 'end.o'])
for obj in objects:
    print(str(obj))

Since builder calls return a list-like object, not an actual Python list, it is not appropriate to use the Python add operator (+ or +=) to append builder results to a Python list. Because the list and the object are different types, Python will not update the original list in place, but will instead create a new NodeList object containing the concatenation of the list elements and the builder results. This will cause problems for any other Python variables in your SCons configuration that still hold on to a reference to the original list. Instead, use the Python list extend method to make sure the list is updated in-place. Example:

object_files = []

# Do NOT use += here:
#    object_files += Object('bar.c')
#
# It will not update the object_files list in place.
#
# Instead, use the list extend method:
object_files.extend(Object('bar.c'))

The path name for a Node's file may be used by passing the Node to Python's built-in str function:

bar_obj_list = env.StaticObject('bar.c', CPPDEFINES='-DBAR')
print("The path to bar_obj is:", str(bar_obj_list[0]))

Note that because the Builder call returns a NodeList, you have to access the first element in the list (bar_obj_list[0] in the example) to get at the Node that actually represents the object file.

When trying to handle errors that may occur in a builder method, consider that the corresponding Action is executed at a different time than the SConscript file statement calling the builder. It is not useful to wrap a builder call in a try block, since success in the builder call is not the same as the builder itself succeeding. If necessary, a Builder's Action should be coded to exit with a useful exception message indicating the problem in the SConscript files - programmatically recovering from build errors is rarely useful.

The following builder methods are predefined in the SCons core software distribution. Depending on the setup of a particular construction environment and on the type and software installation status of the underlying system, not all builders may be available in that construction environment. Since the function calling signature is the same for all builders:

Buildername(target, source, [key=val, ...])

it is omitted in this listing for brevity.

CFile(), env.CFile()

Builds a C source file given a lex (.l) or yacc (.y) input file. The suffix specified by the $CFILESUFFIX construction variable (.c by default) is automatically added to the target if it is not already present. Example:

# builds foo.c
env.CFile(target='foo.c', source='foo.l')

# builds bar.c
env.CFile(target='bar', source='bar.y')

Command(), env.Command()

There is actually no Builder named Command, rather the term "Command Builder" refers to a function which, on each call, creates and calls an anonymous Builder. This is useful for "one-off" builds where a full Builder is not needed. Since the anonymous Builder is never hooked into the standard Builder framework, an Action must always be specified. See the Command function description for the calling syntax and details.

CompilationDatabase(), env.CompilationDatabase()

CompilationDatabase is a special builder which adds a target to create a JSON formatted compilation database compatible with clang tooling (see the m[blue]LLVM specificationm[][2]). This database is suitable for consumption by various tools and editors who can use it to obtain build and dependency information which otherwise would be internal to SCons. The builder does not require any source files to be specified, rather it arranges to emit information about all of the C, C++ and assembler source/output pairs identified in the build that are not excluded by the optional filter $COMPILATIONDB_PATH_FILTER. The target is subject to the usual SCons target selection rules.

If called with no arguments, the builder will default to a target name of compile_commands.json.

If called with a single positional argument, scons will "deduce" the target name from that source argument, giving it the same name, and then ignore the source. This is the usual way to call the builder if a non-default target name is wanted.

If called with either the target= or source= keyword arguments, the value of the argument is taken as the target name. If called with both, the target= value is used and source= is ignored. If called with multiple sources, the source list will be ignored, since there is no way to deduce what the intent was; in this case the default target name will be used.

Note
You must load the compilation_db tool prior to specifying any part of your build or some source/output files will not show up in the compilation database.

Available since scons 4.0.

CXXFile(), env.CXXFile()

Builds a C++ source file given a lex (.ll) or yacc (.yy) input file. The suffix specified by the $CXXFILESUFFIX construction variable (.cc by default) is automatically added to the target if it is not already present. Example:

# builds foo.cc
env.CXXFile(target='foo.cc', source='foo.ll')

# builds bar.cc
env.CXXFile(target='bar', source='bar.yy')

DocbookEpub(), env.DocbookEpub()

A pseudo-Builder, providing a Docbook toolchain for EPUB output.

env = Environment(tools=['docbook'])
env.DocbookEpub('manual.epub', 'manual.xml')

or simply

env = Environment(tools=['docbook'])
env.DocbookEpub('manual')

DocbookHtml(), env.DocbookHtml()

A pseudo-Builder, providing a Docbook toolchain for HTML output.

env = Environment(tools=['docbook'])
env.DocbookHtml('manual.html', 'manual.xml')

or simply

env = Environment(tools=['docbook'])
env.DocbookHtml('manual')

DocbookHtmlChunked(), env.DocbookHtmlChunked()

A pseudo-Builder providing a Docbook toolchain for chunked HTML output. It supports the base.dir parameter. The chunkfast.xsl file (requires "EXSLT") is used as the default stylesheet. Basic syntax:

env = Environment(tools=['docbook'])
env.DocbookHtmlChunked('manual')

where manual.xml is the input file.

If you use the root.filename parameter in your own stylesheets you have to specify the new target name. This ensures that the dependencies get correct, especially for the cleanup via lqscons -crq:

env = Environment(tools=['docbook'])
env.DocbookHtmlChunked('mymanual.html', 'manual', xsl='htmlchunk.xsl')

Some basic support for the base.dir parameter is provided. You can add the base_dir keyword to your Builder call, and the given prefix gets prepended to all the created filenames:

env = Environment(tools=['docbook'])
env.DocbookHtmlChunked('manual', xsl='htmlchunk.xsl', base_dir='output/')

Make sure that you don't forget the trailing slash for the base folder, else your files get renamed only!

DocbookHtmlhelp(), env.DocbookHtmlhelp()

A pseudo-Builder, providing a Docbook toolchain for HTMLHELP output. Its basic syntax is:

env = Environment(tools=['docbook'])
env.DocbookHtmlhelp('manual')

where manual.xml is the input file.

If you use the root.filename parameter in your own stylesheets you have to specify the new target name. This ensures that the dependencies get correct, especially for the cleanup via lqscons -crq:

env = Environment(tools=['docbook'])
env.DocbookHtmlhelp('mymanual.html', 'manual', xsl='htmlhelp.xsl')

Some basic support for the base.dir parameter is provided. You can add the base_dir keyword to your Builder call, and the given prefix gets prepended to all the created filenames:

env = Environment(tools=['docbook'])
env.DocbookHtmlhelp('manual', xsl='htmlhelp.xsl', base_dir='output/')

Make sure that you don't forget the trailing slash for the base folder, else your files get renamed only!

DocbookMan(), env.DocbookMan()

A pseudo-Builder, providing a Docbook toolchain for Man page output. Its basic syntax is:

env = Environment(tools=['docbook'])
env.DocbookMan('manual')

where manual.xml is the input file. Note, that you can specify a target name, but the actual output names are automatically set from the refname entries in your XML source.

DocbookPdf(), env.DocbookPdf()

A pseudo-Builder, providing a Docbook toolchain for PDF output.

env = Environment(tools=['docbook'])
env.DocbookPdf('manual.pdf', 'manual.xml')

or simply

env = Environment(tools=['docbook'])
env.DocbookPdf('manual')

DocbookSlidesHtml(), env.DocbookSlidesHtml()

A pseudo-Builder, providing a Docbook toolchain for HTML slides output.

env = Environment(tools=['docbook'])
env.DocbookSlidesHtml('manual')

If you use the titlefoil.html parameter in your own stylesheets you have to give the new target name. This ensures that the dependencies get correct, especially for the cleanup via lqscons -crq:

env = Environment(tools=['docbook'])
env.DocbookSlidesHtml('mymanual.html','manual', xsl='slideshtml.xsl')

Some basic support for the base.dir parameter is provided. You can add the base_dir keyword to your Builder call, and the given prefix gets prepended to all the created filenames:

env = Environment(tools=['docbook'])
env.DocbookSlidesHtml('manual', xsl='slideshtml.xsl', base_dir='output/')

Make sure that you don't forget the trailing slash for the base folder, else your files get renamed only!

DocbookSlidesPdf(), env.DocbookSlidesPdf()

A pseudo-Builder, providing a Docbook toolchain for PDF slides output.

env = Environment(tools=['docbook'])
env.DocbookSlidesPdf('manual.pdf', 'manual.xml')

or simply

env = Environment(tools=['docbook'])
env.DocbookSlidesPdf('manual')

DocbookXInclude(), env.DocbookXInclude()

A pseudo-Builder, for resolving XIncludes in a separate processing step.

env = Environment(tools=['docbook'])
env.DocbookXInclude('manual_xincluded.xml', 'manual.xml')

DocbookXslt(), env.DocbookXslt()

A pseudo-Builder, applying a given XSL transformation to the input file.

env = Environment(tools=['docbook'])
env.DocbookXslt('manual_transformed.xml', 'manual.xml', xsl='transform.xslt')

Note, that this builder requires the xsl parameter to be set.

DVI(), env.DVI()

Builds a .dvi file from a .tex, .ltx or .latex input file. If the source file suffix is .tex, scons will examine the contents of the file; if the string documentclass or documentstyle is found, the file is assumed to be a LaTeX file and the target is built by invoking the $LATEXCOM command line; otherwise, the $TEXCOM command line is used. If the file is a LaTeX file, the DVI builder method will also examine the contents of the .aux file and invoke the $BIBTEX command line if the string bibdata is found, start $MAKEINDEX to generate an index if a .ind file is found and will examine the contents .log file and re-run the $LATEXCOM command if the log file says it is necessary.

The suffix .dvi (hard-coded within TeX itself) is automatically added to the target if it is not already present. Examples:

# builds from aaa.tex
env.DVI(target = 'aaa.dvi', source = 'aaa.tex')
# builds bbb.dvi
env.DVI(target = 'bbb', source = 'bbb.ltx')
# builds from ccc.latex
env.DVI(target = 'ccc.dvi', source = 'ccc.latex')

Gs(), env.Gs()

A Builder for explicitly calling the gs executable. Depending on the underlying OS, the different names gs, gsos2 and gswin32c are tried.

env = Environment(tools=['gs'])
env.Gs(
    'cover.jpg',
    'scons-scons.pdf',
    GSFLAGS='-dNOPAUSE -dBATCH -sDEVICE=jpeg -dFirstPage=1 -dLastPage=1 -q',
)

Install(), env.Install()

Installs one or more source files or directories in the specified target, which must be a directory. The names of the specified source files or directories remain the same within the destination directory. The sources may be given as a string or as a node returned by a builder.

env.Install(target='/usr/local/bin', source=['foo', 'bar'])

Note that if target paths chosen for the Install builder (and the related InstallAs and InstallVersionedLib builders) are outside the project tree, such as in the example above, they may not be selected for "building" by default, since in the absence of other instructions scons builds targets that are underneath the top directory (the directory that contains the SConstruct file, usually the current directory). Use command line targets or the Default function in this case.

If the --install-sandbox command line option is given, the target directory will be prefixed by the directory path specified. This is useful to test installation behavior without installing to a "live" location in the system.

See also FindInstalledFiles. For more thoughts on installation, see the User Guide (particularly the section on Command-Line Targets and the chapters on Installing Files and on Alias Targets).

InstallAs(), env.InstallAs()

Installs one or more source files or directories to specific names, allowing changing a file or directory name as part of the installation. It is an error if the target and source arguments list different numbers of files or directories.

env.InstallAs(target='/usr/local/bin/foo',
              source='foo_debug')
env.InstallAs(target=['../lib/libfoo.a', '../lib/libbar.a'],
              source=['libFOO.a', 'libBAR.a'])

See the note under Install.

InstallVersionedLib(), env.InstallVersionedLib()

Installs a versioned shared library. The symlinks appropriate to the architecture will be generated based on symlinks of the source library.

env.InstallVersionedLib(target='/usr/local/bin/foo',
                        source='libxyz.1.5.2.so')

See the note under Install.

Jar(), env.Jar()

Builds a Java archive (.jar) file from the specified list of sources. Any directories in the source list will be searched for .class files). Any .java files in the source list will be compiled to .class files by calling the Java Builder.

If the $JARCHDIR value is set, the jar command will change to the specified directory using the -C option. If $JARCHDIR is not set explicitly, SCons will use the top of any subdirectory tree in which Java .class were built by the Java Builder.

If the contents any of the source files begin with the string Manifest-Version, the file is assumed to be a manifest and is passed to the jar command with the m option set.

env.Jar(target = 'foo.jar', source = 'classes')

env.Jar(target = 'bar.jar',
        source = ['bar1.java', 'bar2.java'])

Java(), env.Java()

Builds one or more Java class files. The sources may be any combination of explicit .java files, or directory trees which will be scanned for .java files.

SCons will parse each source .java file to find the classes (including inner classes) defined within that file, and from that figure out the target .class files that will be created. The class files will be placed underneath the specified target directory.

SCons will also search each Java file for the Java package name, which it assumes can be found on a line beginning with the string package in the first column; the resulting .class files will be placed in a directory reflecting the specified package name. For example, the file Foo.java defining a single public Foo class and containing a package name of sub.dir will generate a corresponding sub/dir/Foo.class class file.

Examples:

env.Java(target='classes', source='src')
env.Java(target='classes', source=['src1', 'src2'])
env.Java(target='classes', source=['File1.java', 'File2.java'])
            

Java source files can use the native encoding for the underlying OS. Since SCons compiles in simple ASCII mode by default, the compiler will generate warnings about unmappable characters, which may lead to errors as the file is processed further. In this case, the user must specify the LANG environment variable to tell the compiler what encoding is used. For portability, it's best if the encoding is hard-coded, so that the compilation works when run on a system with a different encoding.

env = Environment()
env['ENV']['LANG'] = 'en_GB.UTF-8'
            

JavaH(), env.JavaH()

Builds C header and source files for implementing Java native methods. The target can be either a directory in which the header files will be written, or a header file name which will contain all of the definitions. The source can be the names of .class files, the names of .java files to be compiled into .class files by calling the Java builder method, or the objects returned from the Java builder method.

If the construction variable $JAVACLASSDIR is set, either in the environment or in the call to the JavaH builder method itself, then the value of the variable will be stripped from the beginning of any .class file names.

Examples:

# builds java_native.h
classes = env.Java(target="classdir", source="src")
env.JavaH(target="java_native.h", source=classes)

# builds include/package_foo.h and include/package_bar.h
env.JavaH(target="include", source=["package/foo.class", "package/bar.class"])

# builds export/foo.h and export/bar.h
env.JavaH(
    target="export",
    source=["classes/foo.class", "classes/bar.class"],
    JAVACLASSDIR="classes",
)

Note
Java versions starting with 10.0 no longer use the javah command for generating JNI headers/sources, and indeed have removed the command entirely (see Java Enhancement Proposal m[blue]JEP 313m[][3]), making this tool harder to use for that purpose. SCons may autodiscover a javah belonging to an older release if there are multiple Java versions on the system, which will lead to incorrect results. To use with a newer Java, override the default values of $JAVAH (to contain the path to the javac) and $JAVAHFLAGS (to contain at least a -h flag) and note that generating headers with javac requires supplying source .java files only, not .class files.

Library(), env.Library()

A synonym for the StaticLibrary builder method.

LoadableModule(), env.LoadableModule()

On most systems, this is the same as SharedLibrary. On Mac OS X (Darwin) platforms, this creates a loadable module bundle.

M4(), env.M4()

Builds an output file from an M4 input file. This uses a default $M4FLAGS value of -E, which considers all warnings to be fatal and stops on the first warning when using the GNU version of m4. Example:

env.M4(target = 'foo.c', source = 'foo.c.m4')

Moc(), env.Moc()

Builds an output file from a moc input file. moc input files are either header files or C++ files. This builder is only available after using the tool qt3. See the $QT3DIR variable for more information. Example:

env.Moc('foo.h')  # generates moc_foo.cc
env.Moc('foo.cpp')  # generates foo.moc

MOFiles(), env.MOFiles()

This builder is set up by the msgfmt tool. The builder compiles PO files to MO files. MOFiles is a single-source builder. The source parameter can also be omitted if $LINGUAS_FILE is set.

Example 1. Create pl.mo and en.mo by compiling pl.po and en.po:

env.MOFiles(['pl', 'en'])

Example 2. Compile files for languages defined in LINGUAS file:

env.MOFiles(LINGUAS_FILE=True)

Example 3. Create pl.mo and en.mo by compiling pl.po and en.po plus files for languages defined in LINGUAS file:

env.MOFiles(['pl', 'en'], LINGUAS_FILE=True)

Example 4. Compile files for languages defined in LINGUAS file (another version):

env['LINGUAS_FILE'] = True
env.MOFiles()

MSVSProject(), env.MSVSProject()

Build a Microsoft Visual C++ project file and solution file.

Builds a Microsoft Visual C++ project file based on the version of Visual Studio (or to be more precise, of MSBuild) that is configured: either the latest installed version, or the version specified by $MSVC_VERSION in the current construction environment. For Visual Studio 6.0 a .dsp file is generated. For Visual Studio versions 2002-2008, a .vcproj file is generated. For Visual Studio 2010 and later a .vcxproj file is generated. Note there are multiple versioning schemes involved in the Microsoft compilation environment - see the description of $MSVC_VERSION for equivalences. Note SCons does not know how to construct project files for other languages (e.g. .csproj for C#, .vbproj for Visual Basic or .pyproject for Python).

For the .vcxproj file, the underlying format is the MSBuild XML Schema, and the details conform to: m[blue]https://learn.microsoft.com/en-us/cpp/build/reference/vcxproj-file-structurem[][4]. The generated solution file enables Visual Studio to understand the project structure, and allows building it using MSBuild to call back to SCons. The project file encodes a toolset version that has been selected by SCons as described above. Since recent Visual Studio versions support multiple concurrent toolsets, use $MSVC_VERSION to select the desired one if it does not match the SCons default. The project file also includes entries which describe how to call SCons to build the project from within Visual Studio (or from an MSBuild command line). In some situations SCons may generate this incorrectly - notably when using the scons-local distribution, which is not installed in a way that that matches the default invocation line. If so, the $SCONS_HOME construction variable can be used to describe the right way to locate the SCons code so that it can be imported.

By default, a matching solution file for the project is also generated. This behavior may be disabled by specifying auto_build_solution=0 to the MSVSProject builder. The solution file can also be independently generated by calling the MSVSSolution builder, such as in the case where a solution should describe multiple projects. See the MSVSSolution description for further information.

The MSVSProject builder accepts several keyword arguments describing lists of filenames to be placed into the project file. Currently, srcs, incs, localincs, resources, and misc are recognized. The names are intended to be self-explanatory, but note that the filenames need to be specified as strings, not as SCons File Nodes (for example if you generate files for inclusion by using the Glob function, the results should be converted to a list of strings before passing them to MSVSProject). This is because Visual Studio and MSBuild know nothing about SCons Node types. Each of the filename lists are individually optional, but at least one list must be specified for the resulting project file to be non-empty.

In addition to the above lists of values, the following values may be specified as keyword arguments:

target

The name of the target .dsp or .vcproj file. The correct suffix for the version of Visual Studio must be used, but the $MSVSPROJECTSUFFIX construction variable will be defined to the correct value (see example below).

variant

The name of this particular variant. Except for Visual Studio 6 projects, this can also be a list of variant names. These are typically things like "Debug" or "Release", but really can be anything you want. For Visual Studio 7 projects, they may also specify a target platform separated from the variant name by a | (vertical pipe) character: Debug|Xbox. The default target platform is Win32. Multiple calls to MSVSProject with different variants are allowed; all variants will be added to the project file with their appropriate build targets and sources.

cmdargs

Additional command line arguments for the different variants. The number of cmdargs entries must match the number of variant entries, or be empty (not specified). If you give only one, it will automatically be propagated to all variants.

cppdefines

Preprocessor definitions for the different variants. The number of cppdefines entries must match the number of variant entries, or be empty (not specified). If you give only one, it will automatically be propagated to all variants. If you don't give this parameter, SCons will use the invoking environment's $CPPDEFINES entry for all variants.

cppflags

Compiler flags for the different variants. If a /std:c++ flag is found then /Zc:__cplusplus is appended to the flags if not already found, this ensures that Intellisense uses the /std:c++ switch. The number of cppflags entries must match the number of variant entries, or be empty (not specified). If you give only one, it will automatically be propagated to all variants. If you don't give this parameter, SCons will combine the invoking environment's $CCFLAGS, $CXXFLAGS, $CPPFLAGS entries for all variants.

cpppaths

Compiler include paths for the different variants. The number of cpppaths entries must match the number of variant entries, or be empty (not specified). If you give only one, it will automatically be propagated to all variants. If you don't give this parameter, SCons will use the invoking environment's $CPPPATH entry for all variants.

buildtarget

An optional string, node, or list of strings or nodes (one per build variant), to tell the Visual Studio debugger what output target to use in what build variant. The number of buildtarget entries must match the number of variant entries.

runfile

The name of the file that Visual Studio 7 and later will run and debug. This appears as the value of the Output field in the resulting Microsoft Visual C++ project file. If this is not specified, the default is the same as the specified buildtarget value.

Note

SCons and Microsoft Visual Studio understand projects in different ways, and the mapping is sometimes imperfect:

Because SCons always executes its build commands from the directory in which the SConstruct file is located, if you generate a project file in a different directory than the directory of the SConstruct file, users will not be able to double-click on the file name in compilation error messages displayed in the Visual Studio console output window. This can be remedied by adding the Microsoft Visual C++ /FC compiler option to the $CCFLAGS variable so that the compiler will print the full path name of any files that cause compilation errors.

If the project file is only used to teach the Visual Studio project browser about the file layout there should be no issues, However, Visual Studio should not be used to make changes to the project structure, build options, etc. as these will (a) not feed back to the SCons description of the project and (b) be lost if SCons regenerates the project file. The SConscript files should remain the definitive description of the build.

If the project file is used to drive MSBuild (such as selecting "build" from the Visual Studio interface) you lose the direct control of target selection and command-line options you would have if launching the build directly from SCons, because these will be hard-coded in the project file to the values specified in the MSVSProject call. You can regain some of this control by defining multiple variants, using multiple MSVSProject calls to arrange different build targets, arguments, defines, flags and paths for different variants.

If the build is divided into a solution with multiple MSBuild projects the mapping is further strained. In this case, it is important not to set Visual Studio to do parallel builds, as it will then launch the separate project builds in parallel, and SCons does not work well if called that way. Instead, you can set up the SCons build for parallel building - see the SetOption function for how to do this with num_jobs.

Example usage:

barsrcs = ['bar.cpp']
barincs = ['bar.h']
barlocalincs = ['StdAfx.h']
barresources = ['bar.rc', 'resource.h']
barmisc = ['bar_readme.txt']

dll = env.SharedLibrary(target='bar.dll', source=barsrcs)
buildtarget = [s for s in dll if str(s).endswith('dll')]
env.MSVSProject(
    target='Bar' + env['MSVSPROJECTSUFFIX'],
    srcs=barsrcs,
    incs=barincs,
    localincs=barlocalincs,
    resources=barresources,
    misc=barmisc,
    buildtarget=buildtarget,
    variant='Release',
)
      

DebugSettings

A dictionary of debug settings that get written to the .vcproj.user or the .vcxproj.user file, depending on the version installed. As for cmdargs, you can specify a DebugSettings dictionary per variant. If you give only one, it will be propagated to all variants.

Changed in version 2.4: Added the optional DebugSettings parameter.

Currently, only Visual Studio v9.0 and Visual Studio version v11 are implemented, for other versions no file is generated. To generate the user file, you just need to add a DebugSettings dictionary to the environment with the right parameters for your MSVS version. If the dictionary is empty, or does not contain any good value, no file will be generated.

Following is a more contrived example, involving the setup of a project for variants and DebugSettings:

# Assuming you store your defaults in a file
vars = Variables('variables.py')
msvcver = vars.args.get('vc', '9')

# Check command args to force one Microsoft Visual Studio version
if msvcver == '9' or msvcver == '11':
    env = Environment(MSVC_VERSION=msvcver + '.0', MSVC_BATCH=False)
else:
    env = Environment()

AddOption(
    '--userfile',
    action='store_true',
    dest='userfile',
    default=False,
    help="Create Visual C++ project file",
)

#
# 1. Configure your Debug Setting dictionary with options you want in the list
# of allowed options, for instance if you want to create a user file to launch
# a specific application for testing your dll with Microsoft Visual Studio 2008 (v9):
#
V9DebugSettings = {
    'Command': 'c:myappusingthisdll.exe',
    'WorkingDirectory': 'c:myappusing',
    'CommandArguments': '-p password',
    # 'Attach':'false',
    # 'DebuggerType':'3',
    # 'Remote':'1',
    # 'RemoteMachine': None,
    # 'RemoteCommand': None,
    # 'HttpUrl': None,
    # 'PDBPath': None,
    # 'SQLDebugging': None,
    # 'Environment': '',
    # 'EnvironmentMerge':'true',
    # 'DebuggerFlavor': None,
    # 'MPIRunCommand': None,
    # 'MPIRunArguments': None,
    # 'MPIRunWorkingDirectory': None,
    # 'ApplicationCommand': None,
    # 'ApplicationArguments': None,
    # 'ShimCommand': None,
    # 'MPIAcceptMode': None,
    # 'MPIAcceptFilter': None,
}

#
# 2. Because there are a lot of different options depending on the Microsoft
# Visual Studio version, if you use more than one version you have to
# define a dictionary per version, for instance if you want to create a user
# file to launch a specific application for testing your dll with Microsoft
# Visual Studio 2012 (v11):
#
V10DebugSettings = {
    'LocalDebuggerCommand': 'c:myappusingthisdll.exe',
    'LocalDebuggerWorkingDirectory': 'c:myappusing',
    'LocalDebuggerCommandArguments': '-p password',
    # 'LocalDebuggerEnvironment': None,
    # 'DebuggerFlavor': 'WindowsLocalDebugger',
    # 'LocalDebuggerAttach': None,
    # 'LocalDebuggerDebuggerType': None,
    # 'LocalDebuggerMergeEnvironment': None,
    # 'LocalDebuggerSQLDebugging': None,
    # 'RemoteDebuggerCommand': None,
    # 'RemoteDebuggerCommandArguments': None,
    # 'RemoteDebuggerWorkingDirectory': None,
    # 'RemoteDebuggerServerName': None,
    # 'RemoteDebuggerConnection': None,
    # 'RemoteDebuggerDebuggerType': None,
    # 'RemoteDebuggerAttach': None,
    # 'RemoteDebuggerSQLDebugging': None,
    # 'DeploymentDirectory': None,
    # 'AdditionalFiles': None,
    # 'RemoteDebuggerDeployDebugCppRuntime': None,
    # 'WebBrowserDebuggerHttpUrl': None,
    # 'WebBrowserDebuggerDebuggerType': None,
    # 'WebServiceDebuggerHttpUrl': None,
    # 'WebServiceDebuggerDebuggerType': None,
    # 'WebServiceDebuggerSQLDebugging': None,
}

#
# 3. Select the dictionary you want depending on the version of Visual Studio
# Files you want to generate.
#
if not env.GetOption('userfile'):
    dbgSettings = None
elif env.get('MSVC_VERSION', None) == '9.0':
    dbgSettings = V9DebugSettings
elif env.get('MSVC_VERSION', None) == '11.0':
    dbgSettings = V10DebugSettings
else:
    dbgSettings = None

#
# 4. Add the dictionary to the DebugSettings keyword.
#
barsrcs = ['bar.cpp', 'dllmain.cpp', 'stdafx.cpp']
barincs = ['targetver.h']
barlocalincs = ['StdAfx.h']
barresources = ['bar.rc', 'resource.h']
barmisc = ['ReadMe.txt']

dll = env.SharedLibrary(target='bar.dll', source=barsrcs)

env.MSVSProject(
    target='Bar' + env['MSVSPROJECTSUFFIX'],
    srcs=barsrcs,
    incs=barincs,
    localincs=barlocalincs,
    resources=barresources,
    misc=barmisc,
    buildtarget=[dll[0]] * 2,
    variant=('Debug|Win32', 'Release|Win32'),
    cmdargs=f'vc={msvcver}',
    DebugSettings=(dbgSettings, {}),
)
      

MSVSSolution(), env.MSVSSolution()

Build a Microsoft Visual Studio Solution file.

Builds a Visual Studio solution file based on the version of Visual Studio that is configured: either the latest installed version, or the version specified by $MSVC_VERSION in the construction environment. For Visual Studio 6, a .dsw file is generated. For Visual Studio .NET 2002 and later, it will generate a .sln file. Note there are multiple versioning schemes involved in the Microsoft compilation environment - see the description of $MSVC_VERSION for equivalences.

The solution file is a container for one or more projects, and follows the format described at m[blue]https://learn.microsoft.com/en-us/visualstudio/extensibility/internals/solution-dot-sln-filem[][5].

The following values must be specified:

target

The name of the target .dsw or .sln file. The correct suffix for the version of Visual Studio must be used, but the value $MSVSSOLUTIONSUFFIX will be defined to the correct value (see example below).

variant

The name of this particular variant, or a list of variant names (the latter is only supported for MSVS 7 solutions). These are typically things like "Debug" or "Release", but really can be anything you want. For MSVS 7 they may also specify target platform, like this "Debug|Xbox". Default platform is Win32.

projects

A list of project file names, or Project nodes returned by calls to the MSVSProject Builder, to be placed into the solution file. Note that these filenames need to be specified as strings, NOT as SCons File Nodes. This is because the solution file will be interpreted by MSBuild and by Visual Studio, which know nothing about SCons Node types.

In addition to the mandatory arguments above, the following optional values may be specified as keyword arguments:

auto_filter_projects

Under certain circumstances, solution file names or solution file nodes may be present in the projects argument list. When solution file names or nodes are present in the projects argument list, the generated solution file may contain erroneous Project records resulting in VS IDE error messages when opening the generated solution file. By default, an exception is raised when a solution file name or solution file node is detected in the projects argument list.

The accepted values for auto_filter_projects are:

None

An exception is raised when a solution file name or solution file node is detected in the projects argument list.

None is the default value.

True or evaluates True

Automatically remove solution file names and solution file nodes from the projects argument list.

False or evaluates False

Leave the solution file names and solution file nodes in the projects argument list. An exception is not raised.

When opening the generated solution file with the VS IDE, the VS IDE will likely report that there are erroneous Project records that are not supported or that need to be modified.

Example Usage:

env.MSVSSolution(
    target="Bar" + env["MSVSSOLUTIONSUFFIX"],
    projects=["bar" + env["MSVSPROJECTSUFFIX"]],
    variant="Release",
)
      

Ninja(), env.Ninja()

A special builder which adds a target to create a Ninja build file. The builder does not require any source files to be specified.

Note
This is an experimental feature. To enable it you must use one of the following methods

# On the command line
--experimental=ninja

# Or in your SConstruct
SetOption('experimental', 'ninja')
                

This functionality is subject to change and/or removal without deprecation cycle.

To use this tool you need to install the Python ninja package, as the tool by default depends on being able to do an import of the package This can be done via:

python -m pip install ninja
                    

If called with no arguments, the builder will default to a target name of ninja.build.

If called with a single positional argument, scons will "deduce" the target name from that source argument, giving it the same name, and then ignore the source. This is the usual way to call the builder if a non-default target name is wanted.

If called with either the target= or source= keyword arguments, the value of the argument is taken as the target name. If called with both, the target= value is used and source= is ignored. If called with multiple sources, the source list will be ignored, since there is no way to deduce what the intent was; in this case the default target name will be used.

Available since scons 4.2.

Object(), env.Object()

A synonym for the StaticObject builder method.

Package(), env.Package()

Builds software distribution packages. A package is a container format which includes files to install along with metadata. Packaging is optional, and must be enabled by specifying the packaging tool. For example:

env = Environment(tools=['default', 'packaging'])

SCons can build packages in a number of well known packaging formats. The target package type may be selected with the $PACKAGETYPE construction variable or the --package-type command line option. The package type may be a list, in which case SCons will attempt to build packages for each type in the list. Example:

env.Package(PACKAGETYPE=['src_zip', 'src_targz'], ...other args...)

The currently supported packagers are:

msi	Microsoft Installer package
rpm	RPM Package Manager package
ipkg	Itsy Package Management package
tarbz2	bzip-compressed tar file
targz	gzi-compressed tar file
tarxz	x-compressed tar file
zip	zip file
src_tarbz2	bzip-compressed tar file suitable as source to another packager
src_targz	gzi-compressed tar file suitable as source to another packager
src_tarxz	x-compressed tar file suitable as source to another packager
src_zip	zip file suitable as source to another packager

The file list to include in the package may be specified with the source keyword argument. If omitted, the FindInstalledFiles function is called behind the scenes to select all files that have an Install, InstallAs or InstallVersionedLib Builder attached. If the target keyword argument is omitted, the target name(s) will be deduced from the package type(s).

The metadata comes partly from attributes of the files to be packaged, and partly from packaging tags. Tags can be passed as keyword arguments to the Package builder call, and may also be attached to files (or more accurately, Nodes representing files) with the Tag function. Some package-level tags are mandatory, and will lead to errors if omitted. The mandatory tags vary depending on the package type.

While packaging, the builder uses a temporary location named by the value of the $PACKAGEROOT variable - the package sources are copied there before packaging.

Packaging example:

env = Environment(tools=["default", "packaging"])
env.Install("/bin/", "my_program")
env.Package(
    NAME="foo",
    VERSION="1.2.3",
    PACKAGEVERSION=0,
    PACKAGETYPE="rpm",
    LICENSE="gpl",
    SUMMARY="balalalalal",
    DESCRIPTION="this should be really really long",
    X_RPM_GROUP="Application/fu",
    SOURCE_URL="https://foo.org/foo-1.2.3.tar.gz",
)

In this example, the target /bin/my_program created by the Install call would not be built by default since it is not under the project top directory. However, since no source is specified to the Package builder, it is selected for packaging by the default sources rule. Since packaging is done using $PACKAGEROOT, no write is actually done to the system's /bin directory, and the target will be selected since after rebasing to underneath $PACKAGEROOT it is now under the top directory of the project.

PCH(), env.PCH()

Builds a Microsoft Visual C++ precompiled header. Calling this builder returns a list of two target nodes: the PCH as the first element, and the object file as the second element. Normally the object file is ignored. The PCH builder is generally used in conjunction with the $PCH construction variable to force object files to use the precompiled header:

env['PCH'] = env.PCH('StdAfx.cpp')[0]

Note
This builder is specific to the PCH implementation in Microsoft Visual C++. Other compiler chains also implement precompiled header support, but PCH does not work with them at this time. As a result, the builder is only generated into the construction environment when Microsoft Visual C++ is being used as the compiler.

The builder only works correctly in a C++ project. The Microsoft implementation distinguishes between precompiled headers from C and C++. Use of the builder will cause the PCH generation to happen with a flag that tells cl.exe all of the files are C++ files; if that PCH file is then supplied when compiling a C source file, cl.exe will fail the build with a compatibility violation.

If possible, arrange the project so that a C++ source file passed to the PCH builder is not also included in the list of sources to be otherwise compiled in the project. SCons will correctly track that file in the dependency tree as a result of the PCH call, and (for MSVC 11.0 and greater) automatically add the corresponding object file to the link line. If the source list is automatically generated, for example using the Glob function, it may be necessary to remove that file from the list.

PDF(), env.PDF()

Builds a .pdf file from a .dvi input file (or, by extension, a .tex, .ltx, or .latex input file). The suffix specified by the $PDFSUFFIX construction variable (.pdf by default) is added automatically to the target if it is not already present. PDF is a single-source builder. Example:

# builds from aaa.tex
env.PDF(target = 'aaa.pdf', source = 'aaa.tex')
# builds bbb.pdf from bbb.dvi
env.PDF(target = 'bbb', source = 'bbb.dvi')

POInit(), env.POInit()

This builder is set up by the msginit tool. The builder initializes missing PO file(s) if $POAUTOINIT is set. If $POAUTOINIT is not set (the default), POInit prints instruction for the user (such as a translator), telling how the PO file should be initialized. In normal projects you should not use POInit and use POUpdate instead. POUpdate chooses intelligently between msgmerge(1) and msginit(1). POInit always uses msginit(1) and should be regarded as builder for special purposes or for temporary use (e.g. for quick, one time initialization of a bunch of PO files) or for tests. POInit is a single-source builder. The source parameter can also be omitted if $LINGUAS_FILE is set.

Target nodes defined through POInit are not built by default (they're Ignored from '.' node) but are added to special Alias ('po-create' by default). The alias name may be changed through the $POCREATE_ALIAS construction variable. All PO files defined through POInit may be easily initialized by scons po-create.

Example 1. Initialize en.po and pl.po from messages.pot:

env.POInit(['en', 'pl']) # messages.pot --> [en.po, pl.po]

Example 2. Initialize en.po and pl.po from foo.pot:

env.POInit(['en', 'pl'], ['foo']) # foo.pot --> [en.po, pl.po]

Example 3. Initialize en.po and pl.po from foo.pot but using the $POTDOMAIN construction variable:

env.POInit(['en', 'pl'], POTDOMAIN='foo') # foo.pot --> [en.po, pl.po]

Example 4. Initialize PO files for languages defined in LINGUAS file. The files will be initialized from template messages.pot:

env.POInit(LINGUAS_FILE=True)  # needs 'LINGUAS' file

Example 5. Initialize en.po and pl.pl PO files plus files for languages defined in LINGUAS file. The files will be initialized from template messages.pot:

env.POInit(['en', 'pl'], LINGUAS_FILE=True)

Example 6. You may preconfigure your environment first, and then initialize PO files:

env['POAUTOINIT'] = True
env['LINGUAS_FILE'] = True
env['POTDOMAIN'] = 'foo'
env.POInit()

which has same efect as:

env.POInit(POAUTOINIT=True, LINGUAS_FILE=True, POTDOMAIN='foo')

PostScript(), env.PostScript()

Builds a .ps file from a .dvi input file (or, by extension, a .tex, .ltx, or .latex input file). The suffix specified by the $PSSUFFIX construction variable (.ps by default) is added automatically to the target if it is not already present. PostScript is a single-source builder. Example:

# builds from aaa.tex
env.PostScript(target = 'aaa.ps', source = 'aaa.tex')
# builds bbb.ps from bbb.dvi
env.PostScript(target = 'bbb', source = 'bbb.dvi')

POTUpdate(), env.POTUpdate()

The builder is set up by the xgettext tool, part of the gettext toolset. The builder updates the target POT file if exists or creates it if it doesn't. The target node is not selected for building by default (e.g. scons .), but only on demand (i.e. when the given POT file is required or when special alias is invoked). This builder adds its target node (messages.pot, say) to a special alias (pot-update by default, see $POTUPDATE_ALIAS) so you can update/create them easily with scons pot-update. The file is not written until there is no real change in internationalized messages (or in comments that enter POT file).

Note
You may see xgettext(1) being invoked by the xgettext tool even if there is no real change in internationalized messages (so the POT file is not being updated). This happens every time a source file has changed. In such case we invoke xgettext(1) and compare its output with the content of POT file to decide whether the file should be updated or not.

Example 1. Let's create po/ directory and place following SConstruct script there:

# SConstruct in 'po/' subdir
env = Environment(tools=['default', 'xgettext'])
env.POTUpdate(['foo'], ['../a.cpp', '../b.cpp'])
env.POTUpdate(['bar'], ['../c.cpp', '../d.cpp'])

Then invoke scons few times:

$ scons             # Does not create foo.pot nor bar.pot
$ scons foo.pot     # Updates or creates foo.pot
$ scons pot-update  # Updates or creates foo.pot and bar.pot
$ scons -c          # Does not clean foo.pot nor bar.pot.

the results shall be as the comments above say.

Example 2. The target argument can be omitted, in which case the default target name messages.pot is used. The target may also be overridden by setting the $POTDOMAIN construction variable or providing it as an override to the POTUpdate builder:

# SConstruct script
env = Environment(tools=['default', 'xgettext'])
env['POTDOMAIN'] = "foo"
env.POTUpdate(source=["a.cpp", "b.cpp"])  # Creates foo.pot ...
env.POTUpdate(POTDOMAIN="bar", source=["c.cpp", "d.cpp"])  # and bar.pot

Example 3. The source parameter may also be omitted, if it is specified in a separate file, for example POTFILES.in:

# POTFILES.in in 'po/' subdirectory
../a.cpp
../b.cpp
# end of file

The name of the file (POTFILES.in) containing the list of sources is provided via $XGETTEXTFROM:

# SConstruct file in 'po/' subdirectory
env = Environment(tools=['default', 'xgettext'])
env.POTUpdate(XGETTEXTFROM='POTFILES.in')

Example 4. You can use $XGETTEXTPATH to define the source search path. Assume, for example, that you have files a.cpp, b.cpp, po/SConstruct, po/POTFILES.in. Then your POT-related files could look like this:

# POTFILES.in in 'po/' subdirectory
a.cpp
b.cpp
# end of file

# SConstruct file in 'po/' subdirectory
env = Environment(tools=['default', 'xgettext'])
env.POTUpdate(XGETTEXTFROM='POTFILES.in', XGETTEXTPATH='../')

Example 5. Multiple search directories may be defined as a list, i.e. XGETTEXTPATH=['dir1', 'dir2', ...]. The order in the list determines the search order of source files. The path to the first file found is used.

Let's create 0/1/po/SConstruct script:

# SConstruct file in '0/1/po/' subdirectory
env = Environment(tools=['default', 'xgettext'])
env.POTUpdate(XGETTEXTFROM='POTFILES.in', XGETTEXTPATH=['../', '../../'])

and 0/1/po/POTFILES.in:

# POTFILES.in in '0/1/po/' subdirectory
a.cpp
# end of file

Write two *.cpp files, the first one is 0/a.cpp:

/* 0/a.cpp */
gettext("Hello from ../../a.cpp")

and the second is 0/1/a.cpp:

/* 0/1/a.cpp */
gettext("Hello from ../a.cpp")

then run scons. You'll obtain 0/1/po/messages.pot with the message "Hello from ../a.cpp". When you reverse order in $XGETTEXTFOM, i.e. when you write SConscript as

# SConstruct file in '0/1/po/' subdirectory
env = Environment(tools=['default', 'xgettext'])
env.POTUpdate(XGETTEXTFROM='POTFILES.in', XGETTEXTPATH=['../../', '../'])

then the messages.pot will contain msgid "Hello from ../../a.cpp" line and not msgid "Hello from ../a.cpp".

POUpdate(), env.POUpdate()

The builder is set up by the msgmerge tool. part of the gettext toolset. The builder updates PO files with msgmerge(1), or initializes missing PO files as described in the documentation of the msginit tool and the POInit builder (see also $POAUTOINIT). POUpdate is a single-source builder. The source parameter can also be omitted if $LINGUAS_FILE is set.

The target nodes are not selected for building by default (e.g. scons .). Instead, they are added automatically to special Alias ('po-update' by default). The alias name may be changed through the $POUPDATE_ALIAS construction variable. You can easily update PO files in your project by scons po-update. Note that POUpdate does not add its targets to the po-create alias as POInit does.

Example 1. Update en.po and pl.po from messages.pot template (see also $POTDOMAIN), assuming that the later one exists or there is rule to build it (see POTUpdate):

env.POUpdate(['en','pl'])  # messages.pot --> [en.po, pl.po]

Example 2. Update en.po and pl.po from foo.pot template:

env.POUpdate(['en', 'pl'], ['foo'])  # foo.pot -->  [en.po, pl.pl]

Example 3. Update en.po and pl.po from foo.pot (another version):

env.POUpdate(['en', 'pl'], POTDOMAIN='foo')  # foo.pot -- > [en.po, pl.pl]

Example 4. Update files for languages defined in LINGUAS file. The files are updated from messages.pot template:

env.POUpdate(LINGUAS_FILE=True)  # needs 'LINGUAS' file

Example 5. Same as above, but update from foo.pot template:

env.POUpdate(LINGUAS_FILE=True, source=['foo'])

Example 6. Update en.po and pl.po plus files for languages defined in LINGUAS file. The files are updated from messages.pot template:

# produce 'en.po', 'pl.po' + files defined in 'LINGUAS':
env.POUpdate(['en', 'pl' ], LINGUAS_FILE=True)

Example 7. Use $POAUTOINIT to automatically initialize PO file if it doesn't exist:

env.POUpdate(LINGUAS_FILE=True, POAUTOINIT=True)

Example 8. Update PO files for languages defined in LINGUAS file. The files are updated from foo.pot template. All necessary settings are pre-configured via environment.

env['POAUTOINIT'] = True
env['LINGUAS_FILE'] = True
env['POTDOMAIN'] = 'foo'
env.POUpdate()

Program(), env.Program()

Builds an executable given one or more object files or C, C++, D, or Fortran source files. If any C, C++, D or Fortran source files are specified, then they will be automatically compiled to object files using the Object builder method; see that builder method's description for a list of legal source file suffixes and how they are interpreted. The target executable file prefix, specified by the $PROGPREFIX construction variable (nothing by default), and suffix, specified by the $PROGSUFFIX construction variable (by default, .exe on Windows systems, nothing on POSIX systems), are automatically added to the target if not already present. Example:

env.Program(target='foo', source=['foo.o', 'bar.c', 'baz.f'])

ProgramAllAtOnce(), env.ProgramAllAtOnce()

Builds an executable from D sources without first creating individual objects for each file.

D sources can be compiled file-by-file as C and C++ source are, and D is integrated into the scons Object and Program builders for this model of build. D codes can though do whole source meta-programming (some of the testing frameworks do this). For this it is imperative that all sources are compiled and linked in a single call to the D compiler. This builder serves that purpose.

    env.ProgramAllAtOnce('executable', ['mod_a.d, mod_b.d', 'mod_c.d'])
  

This command will compile the modules mod_a, mod_b, and mod_c in a single compilation process without first creating object files for the modules. Some of the D compilers will create executable.o others will not.

RES(), env.RES()

Builds a Microsoft Visual C++ resource file. This builder method is only provided when Microsoft Visual C++ or MinGW is being used as the compiler. The .res (or .o for MinGW) suffix is added to the target name if no other suffix is given. The source file is scanned for implicit dependencies as though it were a C file. Example:

env.RES('resource.rc')

RMIC(), env.RMIC()

Builds stub and skeleton class files for remote objects from Java .class files. The target is a directory relative to which the stub and skeleton class files will be written. The source can be the names of .class files, or the objects return from the Java builder method.

If the construction variable $JAVACLASSDIR is set, either in the environment or in the call to the RMIC builder method itself, then the value of the variable will be stripped from the beginning of any .class file names.

classes = env.Java(target='classdir', source='src')
env.RMIC(target='outdir1', source=classes)
env.RMIC(
    target='outdir2',
    source=['package/foo.class', 'package/bar.class'],
)
env.RMIC(
    target='outdir3',
    source=['classes/foo.class', 'classes/bar.class'],
    JAVACLASSDIR='classes',
)

RPCGenClient(), env.RPCGenClient()

Generates an RPC client stub (_clnt.c) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif_clnt.c
env.RPCGenClient('src/rpcif.x')

RPCGenHeader(), env.RPCGenHeader()

Generates an RPC header (.h) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif.h
env.RPCGenHeader('src/rpcif.x')

RPCGenService(), env.RPCGenService()

Generates an RPC server-skeleton (_svc.c) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif_svc.c
env.RPCGenClient('src/rpcif.x')

RPCGenXDR(), env.RPCGenXDR()

Generates an RPC XDR routine (_xdr.c) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif_xdr.c
env.RPCGenClient('src/rpcif.x')

SharedLibrary(), env.SharedLibrary()

Builds a shared library given one or more object files and/or C, C++, D or Fortran source files. Any source files listed in the source parameter will be automatically compiled to object files suitable for use in a shared library. Any object files listed in the source parameter must have been built for a shared library (that is, using the SharedObject builder method). scons will raise an error if there is any mismatch.

The target library file prefix, specified by the $SHLIBPREFIX construction variable (by default, lib on POSIX systems, nothing on Windows systems), and suffix, specified by the $SHLIBSUFFIX construction variable (by default, .dll on Windows systems, .so on POSIX systems), are automatically added (if not already present) to the target name to make up the library filename. On a POSIX system, if the $SHLIBVERSION construction variable is set, it is appended (following a period) to the resulting library name.

Example:

env.SharedLibrary(target='bar', source=['bar.c', 'foo.o'])

On Windows systems, the SharedLibrary builder method will always build an import library (.lib) in addition to the shared library (.dll), adding a .lib library with the same basename if there is not already a .lib file explicitly listed in the targets.

On Cygwin systems, the SharedLibrary builder method will always build an import library (.dll.a) in addition to the shared library (.dll), adding a .dll.a library with the same basename if there is not already a .dll.a file explicitly listed in the targets.

On some platforms, there is a distinction between a shared library (loaded automatically by the system to resolve external references) and a loadable module (explicitly loaded by user action). For maximum portability, use the LoadableModule builder for the latter.

If $SHLIBVERSION is defined, a versioned shared library is created. This modifies $SHLINKFLAGS as required, adds the version number to the library name, and creates any symbolic links that are needed.

env.SharedLibrary(target='bar', source=['bar.c', 'foo.o'], SHLIBVERSION='1.5.2')

On a POSIX system, supplying a simple version string (no dots) creates exactly one symbolic link: SHLIBVERSION="1" would create (for example) library libbar.so.1 and symbolic link libbar.so. Supplying a dotted version string will create two symbolic links (irrespective of the number of segments in the version): SHLIBVERSION="1.5.2" for the same library would create library libbar.so.1.5.2 and symbolic links libbar.so and libbar.so.1. A Darwin (OSX) system creates one symlink in either case, for the second example the library would be libbar.1.5.2.dylib and the link would be libbar.dylib.

On Windows systems, specifying the register=1 keyword argument will cause the .dll to be registered after it is built. The command that is run is determined by the $REGSVR construction variable (regsvr32 by default), and the flags passed are determined by $REGSVRFLAGS. By default, $REGSVRFLAGS includes the /s option, to prevent dialogs from popping up and requiring user attention when it is run. If you change $REGSVRFLAGS, be sure to include the /s option. For example,

env.SharedLibrary(target='bar', source=['bar.cxx', 'foo.obj'], register=1)

will register bar.dll as a COM object when it is done linking it.

SharedObject(), env.SharedObject()

Builds an object file intended for inclusion in a shared library. Source files must have one of the same set of extensions specified above for the StaticObject builder method. On some platforms building a shared object requires additional compiler option (e.g. -fPIC for gcc) in addition to those needed to build a normal (static) object, but on some platforms there is no difference between a shared object and a normal (static) one. When there is a difference, SCons will only allow shared objects to be linked into a shared library, and will use a different suffix for shared objects. On platforms where there is no difference, SCons will allow both normal (static) and shared objects to be linked into a shared library, and will use the same suffix for shared and normal (static) objects. The target object file prefix, specified by the $SHOBJPREFIX construction variable (by default, the same as $OBJPREFIX), and suffix, specified by the $SHOBJSUFFIX construction variable, are automatically added to the target if not already present. Examples:

env.SharedObject(target='ddd', source='ddd.c')
env.SharedObject(target='eee.o', source='eee.cpp')
env.SharedObject(target='fff.obj', source='fff.for')

Note that the source files will be scanned according to the suffix mappings in the SourceFileScanner object. See the manpage section "Scanner Objects" for more information.

StaticLibrary(), env.StaticLibrary()

Builds a static library given one or more object files or C, C++, D or Fortran source files. If any source files are given, then they will be automatically compiled to object files. The static library file prefix, specified by the $LIBPREFIX construction variable (by default, lib on POSIX systems, nothing on Windows systems), and suffix, specified by the $LIBSUFFIX construction variable (by default, .lib on Windows systems, .a on POSIX systems), are automatically added to the target if not already present. Example:

env.StaticLibrary(target='bar', source=['bar.c', 'foo.o'])

Any object files listed in the source must have been built for a static library (that is, using the StaticObject builder method). scons will raise an error if there is any mismatch.

StaticObject(), env.StaticObject()

Builds a static object file from one or more C, C++, D, or Fortran source files. Source files must have one of the following extensions:

  .asm    assembly language file
  .ASM    assembly language file
  .c      C file
  .C      Windows:  C file
          POSIX:  C++ file
  .cc     C++ file
  .cpp    C++ file
  .cxx    C++ file
  .cxx    C++ file
  .c++    C++ file
  .C++    C++ file
  .d      D file
  .f      Fortran file
  .F      Windows:  Fortran file
          POSIX:  Fortran file + C pre-processor
  .for    Fortran file
  .FOR    Fortran file
  .fpp    Fortran file + C pre-processor
  .FPP    Fortran file + C pre-processor
  .m      Object C file
  .mm     Object C++ file
  .s      assembly language file
  .S      Windows:  assembly language file
          ARM: CodeSourcery Sourcery Lite
  .sx     assembly language file + C pre-processor
          POSIX:  assembly language file + C pre-processor
  .spp    assembly language file + C pre-processor
  .SPP    assembly language file + C pre-processor

The target object file prefix, specified by the $OBJPREFIX construction variable (nothing by default), and suffix, specified by the $OBJSUFFIX construction variable (.obj on Windows systems, .o on POSIX systems), are automatically added to the target if not already present. Examples:

env.StaticObject(target='aaa', source='aaa.c')
env.StaticObject(target='bbb.o', source='bbb.c++')
env.StaticObject(target='ccc.obj', source='ccc.f')

Note that the source files will be scanned according to the suffix mappings in the SourceFileScanner object. See the manpage section "Scanner Objects" for more information.

Substfile(), env.Substfile()

The Substfile builder creates a single text file from a template consisting of a file or set of files (or nodes), replacing text using the $SUBST_DICT construction variable (if set). If a set, they are concatenated into the target file using the value of the $LINESEPARATOR construction variable as a separator between contents; the separator is not emitted after the contents of the last file. Nested lists of source files are flattened. See also Textfile.

By default, the target file encoding is "utf-8" and can be changed by $FILE_ENCODING Examples:

If a single source file name is specified and has a .in suffix, the suffix is stripped and the remainder of the name is used as the default target name.

The prefix and suffix specified by the $SUBSTFILEPREFIX and $SUBSTFILESUFFIX construction variables (an empty string by default in both cases) are automatically added to the target if they are not already present.

If a construction variable named $SUBST_DICT is present, it may be either a Python dictionary or a sequence of (key, value) tuples. If it is a dictionary it is converted into a list of tuples with unspecified order, so if one key is a prefix of another key or if one substitution could be further expanded by another substitution, it is unpredictable whether the expansion will occur.

Any occurrences of a key in the source are replaced by the corresponding value, which may be a Python callable function or a string. If the value is a callable, it is called with no arguments to get a string. Strings are subst-expanded and the result replaces the key.

env = Environment(tools=['default'])

env['prefix'] = '/usr/bin'
script_dict = {'@prefix@': '/bin', '@exec_prefix@': '$prefix'}
env.Substfile('script.in', SUBST_DICT=script_dict)

conf_dict = {'%VERSION%': '1.2.3', '%BASE%': 'MyProg'}
env.Substfile('config.h.in', conf_dict, SUBST_DICT=conf_dict)

# UNPREDICTABLE - one key is a prefix of another
bad_foo = {'$foo': '$foo', '$foobar': '$foobar'}
env.Substfile('foo.in', SUBST_DICT=bad_foo)

# PREDICTABLE - keys are applied longest first
good_foo = [('$foobar', '$foobar'), ('$foo', '$foo')]
env.Substfile('foo.in', SUBST_DICT=good_foo)

# UNPREDICTABLE - one substitution could be further expanded
bad_bar = {'@bar@': '@soap@', '@soap@': 'lye'}
env.Substfile('bar.in', SUBST_DICT=bad_bar)

# PREDICTABLE - substitutions are expanded in order
good_bar = (('@bar@', '@soap@'), ('@soap@', 'lye'))
env.Substfile('bar.in', SUBST_DICT=good_bar)

# the SUBST_DICT may be in common (and not an override)
substutions = {}
subst = Environment(tools=['textfile'], SUBST_DICT=substitutions)
substitutions['@foo@'] = 'foo'
subst['SUBST_DICT']['@bar@'] = 'bar'
subst.Substfile(
    'pgm1.c',
    [Value('#include "@foo@.h"'), Value('#include "@bar@.h"'), "common.in", "pgm1.in"],
)
subst.Substfile(
    'pgm2.c',
    [Value('#include "@foo@.h"'), Value('#include "@bar@.h"'), "common.in", "pgm2.in"],
)

Tar(), env.Tar()

Builds a tar archive of the specified files and/or directories. Unlike most builder methods, the Tar builder method may be called multiple times for a given target; each additional call adds to the list of entries that will be built into the archive. Any source directories will be scanned for changes to any on-disk files, regardless of whether or not scons knows about them from other Builder or function calls.

env.Tar('src.tar', 'src')

# Create the stuff.tar file.
env.Tar('stuff', ['subdir1', 'subdir2'])
# Also add "another" to the stuff.tar file.
env.Tar('stuff', 'another')

# Set TARFLAGS to create a gzip-filtered archive.
env = Environment(TARFLAGS = '-c -z')
env.Tar('foo.tar.gz', 'foo')

# Also set the suffix to .tgz.
env = Environment(TARFLAGS = '-c -z',
                  TARSUFFIX = '.tgz')
env.Tar('foo')

Textfile(), env.Textfile()

The Textfile builder generates a single text file from a template consisting of a list of strings, replacing text using the $SUBST_DICT construction variable (if set) - see Substfile for a description of replacement. The strings will be separated in the target file using the value of the $LINESEPARATOR construction variable; the line separator is not emitted after the last string. Nested lists of source strings are flattened. Source strings need not literally be Python strings: they can be Nodes or Python objects that convert cleanly to Value nodes.

The prefix and suffix specified by the $TEXTFILEPREFIX and $TEXTFILESUFFIX construction variables (by default an empty string and .txt, respectively) are automatically added to the target if they are not already present.

By default, the target file encoding is "utf-8" and can be changed by $FILE_ENCODING Examples:

# builds/writes foo.txt
env.Textfile(target='foo.txt', source=['Goethe', 42, 'Schiller'])

# builds/writes bar.txt
env.Textfile(target='bar', source=['lalala', 'tanteratei'], LINESEPARATOR='|*')

# nested lists are flattened automatically
env.Textfile(target='blob', source=['lalala', ['Goethe', 42, 'Schiller'], 'tanteratei'])

# files may be used as input by wrapping them in File()
env.Textfile(
    target='concat',  # concatenate files with a marker between
    source=[File('concat1'), File('concat2')],
    LINESEPARATOR='====================n',
)

Results:

foo.txt

  Goethe
  42
  Schiller

bar.txt

  lalala|*tanteratei

blob.txt

  lalala
  Goethe
  42
  Schiller
  tanteratei

Translate(), env.Translate()

This pseudo-Builder is part of the gettext toolset. The builder extracts internationalized messages from source files, updates the POT template (if necessary) and then updates PO translations (if necessary). If $POAUTOINIT is set, missing PO files will be automatically created (i.e. without translator person intervention). The variables $LINGUAS_FILE and $POTDOMAIN are taken into account too. All other construction variables used by POTUpdate, and POUpdate work here too.

Example 1. The simplest way is to specify input files and output languages inline in a SCons script when invoking Translate:

# SConscript in 'po/' directory
env = Environment(tools=["default", "gettext"])
env['POAUTOINIT'] = True
env.Translate(['en', 'pl'], ['../a.cpp', '../b.cpp'])

Example 2. If you wish, you may also stick to the conventional style known from autotools, i.e. using POTFILES.in and LINGUAS files to specify the targets and sources:

# LINGUAS
en pl
# end

# POTFILES.in
a.cpp
b.cpp
# end

# SConscript
env = Environment(tools=["default", "gettext"])
env['POAUTOINIT'] = True
env['XGETTEXTPATH'] = ['../']
env.Translate(LINGUAS_FILE=True, XGETTEXTFROM='POTFILES.in')

The last approach is perhaps the recommended one. It allows easily split internationalization/localization onto separate SCons scripts, where a script in source tree is responsible for translations (from sources to PO files) and script(s) under variant directories are responsible for compilation of PO to MO files to and for installation of MO files. The "gluing factor" synchronizing these two scripts is then the content of LINGUAS file. Note, that the updated POT and PO files are usually going to be committed back to the repository, so they must be updated within the source directory (and not in variant directories). Additionally, the file listing of po/ directory contains LINGUAS file, so the source tree looks familiar to translators, and they may work with the project in their usual way.

Example 3. Let's prepare a development tree as below

 project/
  + SConstruct
  + build/
  + src/
      + po/
          + SConscript
          + SConscript.i18n
          + POTFILES.in
          + LINGUAS

with build being the variant directory. Write the top-level SConstruct script as follows

# SConstruct
env = Environment(tools=["default", "gettext"])
VariantDir('build', 'src', duplicate=False)
env['POAUTOINIT'] = True
SConscript('src/po/SConscript.i18n', exports='env')
SConscript('build/po/SConscript', exports='env')

the src/po/SConscript.i18n as

# src/po/SConscript.i18n
Import('env')
env.Translate(LINGUAS_FILE=True, XGETTEXTFROM='POTFILES.in', XGETTEXTPATH=['../'])

and the src/po/SConscript

# src/po/SConscript
Import('env')
env.MOFiles(LINGUAS_FILE=True)

Such a setup produces POT and PO files under the source tree in src/po/ and binary MO files under the variant tree in build/po/. This way the POT and PO files are separated from other output files, which must not be committed back to source repositories (e.g. MO files).

Note
In the above example, the PO files are not updated, nor created automatically when you issue the command scons .. The files must be updated (created) by hand via scons po-update and then MO files can be compiled by running scons ..

TypeLibrary(), env.TypeLibrary()

Builds a Windows type library (.tlb) file from an input IDL file (.idl). In addition, it will build the associated interface stub and proxy source files, naming them according to the base name of the .idl file. For example,

env.TypeLibrary(source="foo.idl")

Will create foo.tlb, foo.h, foo_i.c, foo_p.c and foo_data.c files.

Uic(), env.Uic()

Builds a header file, an implementation file and a moc file from an ui file. and returns the corresponding nodes in the that order. This builder is only available after using the tool qt3. Note: you can specify .ui files directly as source files to the Program, Library and SharedLibrary builders without using this builder. Using this builder lets you override the standard naming conventions (be careful: prefixes are always prepended to names of built files; if you don't want prefixes, you may set them to ``). See the $QT3DIR variable for more information. Example:

env.Uic('foo.ui')  # -> ['foo.h', 'uic_foo.cc', 'moc_foo.cc']
env.Uic(
    target=Split('include/foo.h gen/uicfoo.cc gen/mocfoo.cc'),
    source='foo.ui'
)  # -> ['include/foo.h', 'gen/uicfoo.cc', 'gen/mocfoo.cc']

Zip(), env.Zip()

Builds a zip archive of the specified files and/or directories. Unlike most builder methods, the Zip builder method may be called multiple times for a given target; each additional call adds to the list of entries that will be built into the archive. Any source directories will be scanned for changes to any on-disk files, regardless of whether or not scons knows about them from other Builder or function calls.

env.Zip('src.zip', 'src')

# Create the stuff.zip file.
env.Zip('stuff', ['subdir1', 'subdir2'])
# Also add "another" to the stuff.tar file.
env.Zip('stuff', 'another')

All targets of builder methods automatically depend on their sources. An explicit dependency can be specified using the env.Depends method of a construction environment (see below).

In addition, scons automatically scans source files for various programming languages, so the dependencies do not need to be specified explicitly. By default, SCons can C source files, C++ source files, Fortran source files with .F (POSIX systems only), .fpp, or .FPP file extensions, and assembly language files with .S (POSIX systems only), .spp, or .SPP files extensions for C preprocessor dependencies. SCons also has default support for scanning D source files, You can also write your own Scanners to add support for additional source file types. These can be added to the default Scanner object used by the Object, StaticObject and SharedObject Builders by adding them to the SourceFileScanner object. See the section called lqScanner Objectsrq for more information about defining your own Scanner objects and using the SourceFileScanner object.  

SCons Functions and Environment Methods

SCons provides a variety of construction environment methods and global functions to manipulate the build configuration. Often, a construction environment method and a global function with the same name exist for convenience. In this section, both forms are shown if the function can be called in either way. The documentation style for these is as follows:

Function(arguments, [optional arguments, ...])  # Global function
env.Function(arguments, [optional arguments, ...])  # Environment method

In these function signatures, arguments in brackets ([]) are optional, and ellipses (...) indicate possible repetition. Positional vs. keyword arguments are usually detailed in the following text, not in the signature itself. The Python positional-only (/) and keyword-only (*) markers are not used.

When the Python keyword=value style is shown, it can have two meanings. If the keyword argument is known to the function, the value is the default for that argument if it is omitted. If the keyword is unknown to the function, some methods treat it as a construction variable assignment; otherwise an exception is raised for an unknown argument.

A global function and a same-named construction environment method have the same base functionality, with two key differences:

1.

Construction environment methods that change the environment act on the environment instance from which they are called, while the corresponding global function acts on a special lqhiddenrq construction environment called the Default Environment. In some cases, the global function may take an initial argument giving the object to operate on.

2. String-valued arguments (including strings in list-valued arguments) are subject to construction variable expansion by the environment method form; variable expansion is not immediately performed in the global function. For example, Default('$MYTARGET') adds '$MYTARGET' to the list of default targets, while if the value in env of MYTARGET is 'mine', env.Default('$MYTARGET' adds 'mine' to the default targets. For more details on construction variable expansion, see the Construction variables section.

Global functions are automatically in scope inside SConscript files. If your project adds Python modules that you include via the Python import statement from an SConscript file, such code will need to add the functions to that modulecqs global scope explicitly. You can do that by adding the following import to the Python module: from SCons.Script import *.

SCons provides the following construction environment methods and global functions. The list can be augmented on a project basis using AddMethod

Action(action, [output, [var, ...]] [key=value, ...]), env.Action(action, [output, [var, ...]] [key=value, ...])

A factory function to create an Action object for the specified action. See the manpage section "Action Objects" for a complete explanation of the arguments and behavior.

Note that the env.Action form of the invocation will expand construction variables in any argument strings, including the action argument, at the time it is called using the construction variables in the construction environment through which env.Action was called. The Action global function form delays all variable expansion until the Action object is actually used.

AddMethod(object, function, [name]), env.AddMethod(function, [name])

Adds function to an object as a method. function will be called with an instance object as the first argument as for other methods. If name is given, it is used as the name of the new method, else the name of function is used.

When the global function AddMethod is called, the object to add the method to must be passed as the first argument; typically this will be Environment, in order to create a method which applies to all construction environments subsequently constructed. When called using the env.AddMethod form, the method is added to the specified construction environment only. Added methods propagate through env.Clone calls.

More examples:

# Function to add must accept an instance argument.
# The Python convention is to call this 'self'.
def my_method(self, arg):
    print("my_method() got", arg)

# Use the global function to add a method to the Environment class:
AddMethod(Environment, my_method)
env = Environment()
env.my_method('arg')

# Use the optional name argument to set the name of the method:
env.AddMethod(my_method, 'other_method_name')
env.other_method_name('another arg')

AddOption(opt_str, ..., attr=value, ...)

Adds a local (project-specific) command-line option. One or more opt_str values are the strings representing how the option can be called, while the keyword arguments define attributes of the option. For the most part these are the same as for the OptionParser.add_option method in the standard Python library module optparse, but with a few additional capabilities noted below. See the m[blue]optparse documentationm[][6] for a thorough discussion of its option-processing capabilities. All options added through AddOption are placed in a special "Local Options" option group.

In addition to the arguments and values supported by the optparse add_option method, AddOption allows setting the nargs keyword value to a string '?' (question mark) to indicate that the option argument for that option string may be omitted. If the option string is present on the command line but has no matching option argument, the value of the const keyword argument is produced as the value of the option. If the option string is omitted from the command line, the value of the default keyword argument is produced, as usual; if there is no default keyword argument in the AddOption call, None is produced.

optparse recognizes abbreviations of long option names, as long as they can be unambiguously resolved. For example, if add_option is called to define a --devicename option, it will recognize --device, --dev and so forth as long as there is no other option which could also match to the same abbreviation. Options added via AddOption do not support the automatic recognition of abbreviations. Instead, to allow specific abbreviations, include them as synonyms in the AddOption call itself.

Once a new command-line option has been added with AddOption, the option value may be accessed using GetOption or env.GetOption. If the settable=True argument was supplied in the AddOption call, the value may also be set later using SetOption or env.SetOption, if conditions in an SConscript file require overriding any default value. Note however that a value specified on the command line will always override a value set in an SConscript file.

Changed in 4.8.0: added the settable keyword argument to enable an added option to be settable via SetOption.

Help text for an option is a combination of the string supplied in the help keyword argument to AddOption and information collected from the other keyword arguments. Such help is displayed if the -h command line option is used (but not with -H). Help for all local options is displayed under the separate heading Local Options. The options are unsorted - they will appear in the help text in the order in which the AddOption calls occur.

Example:

AddOption(
    '--prefix',
    dest='prefix',
    nargs=1,
    type='string',
    action='store',
    metavar='DIR',
    help='installation prefix',
)
env = Environment(PREFIX=GetOption('prefix'))

For that example, the following help text would be produced:

Local Options:
  --prefix=DIR                installation prefix

Help text for local options may be unavailable if the Help function has been called, see the Help documentation for details.

Note
As an artifact of the internal implementation, the behavior of options added by AddOption which take option arguments is undefined if whitespace (rather than an = sign) is used as the separator on the command line. Users should avoid such usage; it is recommended to add a note to this effect to project documentation if the situation is likely to arise. In addition, if the nargs keyword is used to specify more than one following option argument (that is, with a value of 2 or greater), such arguments would necessarily be whitespace separated, triggering the issue. Developers should not use AddOption this way. Future versions of SCons will likely forbid such usage.

AddPostAction(target, action), env.AddPostAction(target, action)

Arranges for the specified action to be performed after the specified target has been built. action may be an Action object, or anything that can be converted into an Action object. See the manpage section "Action Objects" for a complete explanation.

When multiple targets are supplied, the action may be called multiple times, once after each action that generates one or more targets in the list.

foo = Program('foo.c')
# remove execute permission from binary:
AddPostAction(foo, Chmod('$TARGET', "a-x"))

AddPreAction(target, action), env.AddPreAction(target, action)

Arranges for the specified action to be performed before the specified target is built. action may be an Action object, or anything that can be converted into an Action object. See the manpage section "Action Objects" for a complete explanation.

When multiple targets are specified, the action(s) may be called multiple times, once before each action that generates one or more targets in the list.

Note that if any of the targets are built in multiple steps, the action will be invoked just before the "final" action that specifically generates the specified target(s). For example, when building an executable program from a specified source .c file via an intermediate object file:

foo = Program('foo.c')
AddPreAction(foo, 'pre_action')

The specified pre_action would be executed before scons calls the link command that actually generates the executable program binary foo, not before compiling the foo.c file into an object file.

Alias(alias, [source, [action]]), env.Alias(alias, [source, [action]])

Creates an alias target that can be used as a reference to zero or more other targets, specified by the optional source parameter. Aliases provide a way to give a shorter or more descriptive name to specific targets, and to group multiple targets under a single name. The alias name, or an Alias Node object, may be used as a dependency of any other target, including another alias.

alias and source may each be a string or Node object, or a list of strings or Node objects; if Nodes are used for alias they must be Alias nodes. If source is omitted, the alias is created but has no reference; if selected for building this will result in a lqNothing to be done.rq message. An empty alias can be used to define the alias in a visible place in the project; it can later be appended to in a subsidiary SConscript file with the actual target(s) to refer to. The optional action parameter specifies an action or list of actions that will be executed whenever the any of the alias targets are out-of-date.

Alias can be called for an existing alias, which appends the alias and/or action arguments to the existing lists for that alias.

Returns a list of Alias Node objects representing the alias(es), which exist outside of any physical file system. The alias name space is separate from the name space for tangible targets; to avoid confusion do not reuse target names as alias names.

Examples:

Alias('install')
Alias('install', '/usr/bin')
Alias(['install', 'install-lib'], '/usr/local/lib')

env.Alias('install', ['/usr/local/bin', '/usr/local/lib'])
env.Alias('install', ['/usr/local/man'])

env.Alias('update', ['file1', 'file2'], "update_database $SOURCES")

AllowSubstExceptions([exception, ...])

Specifies the exceptions that will be ignored when expanding construction variables. By default, any construction variable expansions that generate a NameError or IndexError exception will expand to a '' (an empty string) and not cause scons to fail. All exceptions not in the specified list will generate an error message and terminate processing.

If AllowSubstExceptions is called multiple times, each call completely overwrites the previous list of ignored exceptions. Calling it with no arguments means no exceptions will be ignored.

Example:

# Requires that all construction variable names exist.
# (You may wish to do this if you want to enforce strictly
# that all construction variables must be defined before use.)
AllowSubstExceptions()

# Also allow a string containing a zero-division expansion
# like '${1 / 0}' to evaluate to ''.
AllowSubstExceptions(IndexError, NameError, ZeroDivisionError)

AlwaysBuild(target, ...), env.AlwaysBuild(target, ...)

Marks each given target so that it is always assumed to be out-of-date, and will always be rebuilt if needed. Note, however, that AlwaysBuild does not add its target(s) to the default target list, so the targets will only be built if they are specified on the command line, or are a dependent of a target specified on the command line--but they will always be built if so specified. Multiple targets can be passed in to a single call to AlwaysBuild.

env.Append(key=val, [...])

Appends value(s) intelligently to construction variables in env. The construction variables and values to add to them are passed as key=val pairs (Python keyword arguments). env.Append is designed to allow adding values without having to think about the data type of an existing construction variable. Regular Python syntax can also be used to manipulate the construction variable, but for that you may need to know the types involved, for example pure Python lets you directly "add" two lists of strings, but adding a string to a list or a list to a string requires different syntax - things Append takes care of. Some pre-defined construction variables do have type expectations based on how SCons will use them: for example $CPPDEFINES is often a string or a list of strings, but can also be a list of tuples or a dictionary; while $LIBEMITTER is expected to be a callable or list of callables, and $BUILDERS is expected to be a dictionary. Consult the documentation for the various construction variables for more details.

The following descriptions apply to both the Append and Prepend methods, as well as their Unique variants, with the differences being the insertion point of the added values and whether duplication is allowed.

val can be almost any type. If env does not have a construction variable named key, then key is simply stored with a value of val. Otherwise, val is combined with the existing value, possibly converting into an appropriate type which can hold the expanded contents. There are a few special cases to be aware of. Normally, when two strings are combined, the result is a new string containing their concatenation (and you are responsible for supplying any needed separation); however, the contents of $CPPDEFINES will be post-processed by adding a prefix and/or suffix to each entry when the command line is produced, so SCons keeps them separate - appending a string will result in a separate string entry, not a combined string. For $CPPDEFINES. as well as $LIBS, and the various *PATH variables, SCons will amend the variable by supplying the compiler-specific syntax (e.g. prepending a -D or /D prefix for $CPPDEFINES), so you should omit this syntax when adding values to these variables. Examples (gcc syntax shown in the expansion of CPPDEFINES):

env = Environment(CXXFLAGS="-std=c11", CPPDEFINES="RELEASE")
print(f"CXXFLAGS = {env['CXXFLAGS']}, CPPDEFINES = {env['CPPDEFINES']}")
# notice including a leading space in CXXFLAGS addition
env.Append(CXXFLAGS=" -O", CPPDEFINES="EXTRA")
print(f"CXXFLAGS = {env['CXXFLAGS']}, CPPDEFINES = {env['CPPDEFINES']}")
print("CPPDEFINES will expand to", env.subst('$_CPPDEFFLAGS'))

$ scons -Q
CXXFLAGS = -std=c11, CPPDEFINES = RELEASE
CXXFLAGS = -std=c11 -O, CPPDEFINES = deque(['RELEASE', 'EXTRA'])
CPPDEFINES will expand to -DRELEASE -DEXTRA
scons: `.' is up to date.

Because $CPPDEFINES is intended for command-line specification of C/C++ preprocessor macros, additional syntax is accepted when adding to it. The preprocessor accepts arguments to predefine a macro name by itself (-DFOO for most compilers, /DFOO for Microsoft C++), which gives it an implicit value of 1, or can be given with a replacement value (-DBAR=TEXT). SCons follows these rules when adding to $CPPDEFINES:

* A string is split on spaces, giving an easy way to enter multiple macros in one addition. Use an = to specify a valued macro.

* A tuple is treated as a valued macro. Use the value None if the macro should not have a value. It is an error to supply more than two elements in such a tuple.

* A list is processed in order, adding each item without further interpretation. In this case, space-separated strings are not split.

* A dictionary is processed in order, adding each key-value pair as a valued macro. Use the value None if the macro should not have a value.

Examples:

env = Environment(CPPDEFINES="FOO")
print("CPPDEFINES =", env['CPPDEFINES'])
env.Append(CPPDEFINES="BAR=1")
print("CPPDEFINES =", env['CPPDEFINES'])
env.Append(CPPDEFINES=[("OTHER", 2)])
print("CPPDEFINES =", env['CPPDEFINES'])
env.Append(CPPDEFINES={"EXTRA": "arg"})
print("CPPDEFINES =", env['CPPDEFINES'])
print("CPPDEFINES will expand to", env.subst('$_CPPDEFFLAGS'))

$ scons -Q
CPPDEFINES = FOO
CPPDEFINES = deque(['FOO', 'BAR=1'])
CPPDEFINES = deque(['FOO', 'BAR=1', ('OTHER', 2)])
CPPDEFINES = deque(['FOO', 'BAR=1', ('OTHER', 2), ('EXTRA', 'arg')])
CPPDEFINES will expand to -DFOO -DBAR=1 -DOTHER=2 -DEXTRA=arg
scons: `.' is up to date.

Examples of adding multiple macros:

env = Environment()
env.Append(CPPDEFINES=[("ONE", 1), "TWO", ("THREE", )])
print("CPPDEFINES =", env['CPPDEFINES'])
env.Append(CPPDEFINES={"FOUR": 4, "FIVE": None})
print("CPPDEFINES =", env['CPPDEFINES'])
print("CPPDEFINES will expand to", env.subst('$_CPPDEFFLAGS'))

$ scons -Q
CPPDEFINES = [('ONE', 1), 'TWO', ('THREE',)]
CPPDEFINES = deque([('ONE', 1), 'TWO', ('THREE',), ('FOUR', 4), ('FIVE', None)])
CPPDEFINES will expand to -DONE=1 -DTWO -DTHREE -DFOUR=4 -DFIVE
scons: `.' is up to date.

Changed in version 4.5: clarified the use of tuples vs. other types, handling is now consistent across the four functions.

env = Environment()
env.Append(CPPDEFINES=("MACRO1", "MACRO2"))
print("CPPDEFINES =", env['CPPDEFINES'])
env.Append(CPPDEFINES=[("MACRO3", "MACRO4")])
print("CPPDEFINES =", env['CPPDEFINES'])
print("CPPDEFINES will expand to", env.subst('$_CPPDEFFLAGS'))

$ scons -Q
CPPDEFINES = ('MACRO1', 'MACRO2')
CPPDEFINES = deque(['MACRO1', 'MACRO2', ('MACRO3', 'MACRO4')])
CPPDEFINES will expand to -DMACRO1 -DMACRO2 -DMACRO3=MACRO4
scons: `.' is up to date.

See $CPPDEFINES for more details.

Appending a string val to a dictionary-typed construction variable enters val as the key in the dictionary, and None as its value. Using a tuple type to supply a key-value pair only works for the special case of $CPPDEFINES described above.

Although most combinations of types work without needing to know the details, some combinations do not make sense and Python raises an exception.

When using env.Append to modify construction variables which are path specifications (conventionally, the names of such end in PATH), it is recommended to add the values as a list of strings, even if you are only adding a single string. The same goes for adding library names to $LIBS.

env.Append(CPPPATH=["#/include"])

See also env.AppendUnique, env.Prepend and env.PrependUnique.

env.AppendENVPath(name, newpath, [envname, sep, delete_existing=False])

Append path elements specified by newpath to the given search path string or list name in mapping envname in the construction environment. Supplying envname is optional: the default is the execution environment $ENV. Optional sep is used as the search path separator, the default is the platform's separator (os.pathsep). A path element will only appear once. Any duplicates in newpath are dropped, keeping the last appearing (to preserve path order). If delete_existing is False (the default) any addition duplicating an existing path element is ignored; if delete_existing is True the existing value will be dropped and the path element will be added at the end. To help maintain uniqueness all paths are normalized (using os.path.normpath and os.path.normcase).

Example:

print('before:', env['ENV']['INCLUDE'])
include_path = '/foo/bar:/foo'
env.AppendENVPath('INCLUDE', include_path)
print('after:', env['ENV']['INCLUDE'])

Yields:

before: /foo:/biz
after: /biz:/foo/bar:/foo

See also env.PrependENVPath.

env.AppendUnique(key=val, [...], [delete_existing=False])

Append values to construction variables in the current construction environment, maintaining uniqueness. Works like env.Append, except that values that would become duplicates are not added. If delete_existing is set to a true value, then for any duplicate, the existing instance of val is first removed, then val is appended, having the effect of moving it to the end.

Example:

env.AppendUnique(CCFLAGS='-g', FOO=['foo.yyy'])

See also env.Append, env.Prepend and env.PrependUnique.

Builder(action, [arguments]), env.Builder(action, [arguments])

Creates a Builder object for the specified action. See the manpage section "Builder Objects" for a complete explanation of the arguments and behavior.

Note that the env.Builder() form of the invocation will expand construction variables in any arguments strings, including the action argument, at the time it is called using the construction variables in the env construction environment through which env.Builder was called. The Builder form delays all variable expansion until after the Builder object is actually called.

CacheDir(cache_dir, custom_class=None), env.CacheDir(cache_dir, custom_class=None)

Direct scons to maintain a derived-file cache in cache_dir. The derived files in the cache will be shared among all the builds specifying the same cache_dir. Specifying a cache_dir of None disables derived file caching.

Calling the environment method env.CacheDir limits the effect to targets built through the specified construction environment. Calling the global function CacheDir sets a global default that will be used by all targets built through construction environments that do not set up environment-specific caching by calling env.CacheDir.

Caching behavior can be configured by passing a specialized cache class as the optional custom_class parameter. This class must be a subclass of SCons.CacheDir.CacheDir. SCons will internally invoke the custom class for performing caching operations. If the parameter is omitted or set to None, SCons will use the default SCons.CacheDir.CacheDir class.

When derived-file caching is being used and scons finds a derived file that needs to be rebuilt, it will first look in the cache to see if a file with matching build signature exists (indicating the input file(s) and build action(s) were identical to those for the current target), and if so, will retrieve the file from the cache. scons will report Retrieved `file' from cache instead of the normal build message. If the derived file is not present in the cache, scons will build it and then place a copy of the built file in the cache, identified by its build signature, for future use.

The Retrieved `file' from cache messages are useful for human consumption, but less useful when comparing log files between scons runs which will show differences that are noisy and not actually significant. To disable, use the --cache-show option. With this option, scons changes printing to always show the action that would have been used to build the file without caching.

Derived-file caching may be disabled for any invocation of scons by giving the --cache-disable command line option; cache updating may be disabled, leaving cache fetching enabled, by giving the --cache-readonly option.

If the --cache-force option is used, scons will place a copy of all derived files into the cache, even if they already existed and were not built by this invocation. This is useful to populate a cache the first time a cache_dir is used for a build, or to bring a cache up to date after a build with cache updating disabled (--cache-disable or --cache-readonly) has been done.

The NoCache method can be used to disable caching of specific files. This can be useful if inputs and/or outputs of some tool are impossible to predict or prohibitively large.

Note that (at this time) SCons provides no facilities for managing the derived-file cache. It is up to the developer to arrange for cache pruning, expiry, access control, etc. if needed.

Clean(targets, files), env.Clean(targets, files)

Set additional files for removal when any of targets are selected for cleaning (-c command line option). targets and files can each be a single filename or node, or a list of filenames or nodes. These can refer to files or directories. Calling this method repeatedly has an additive effect.

The related NoClean method has higher priority: any target specified to NoClean will not be cleaned even if also given as a files parameter to Clean.

Examples:

Clean('foo', ['bar', 'baz'])
Clean('dist', env.Program('hello', 'hello.c'))
Clean(['foo', 'bar'], 'something_else_to_clean')

SCons does not directly track directories as targets - they are created if needed and not normally removed in clean mode. In this example, installing the project creates a subdirectory for the documentation. The Clean call ensures that the subdirectory is removed if the project is uninstalled.

Clean(docdir, os.path.join(docdir, projectname))

env.Clone([key=val, ...])

Returns an independent copy of a construction environment. If there are any unrecognized keyword arguments specified, they are added as construction variables in the copy, overwriting any existing values for those keywords. See the manpage section "Construction Environments" for more details.

Example:

env2 = env.Clone()
env3 = env.Clone(CCFLAGS='-g')

A list of tools and a toolpath may be specified, as in the Environment constructor:

def MyTool(env):
    env['FOO'] = 'bar'

env4 = env.Clone(tools=['msvc', MyTool])

The parse_flags keyword argument is also recognized, to allow merging command-line style arguments into the appropriate construction variables (see env.MergeFlags).

# create an environment for compiling programs that use wxWidgets
wx_env = env.Clone(parse_flags='!wx-config --cflags --cxxflags')

The variables keyword argument is also recognized, to allow (re)initializing construction variables from a Variables object.

Changed in version 4.8.0: the variables parameter was added.

Command(target, source, action, [key=val, ...]), env.Command(target, source, action, [key=val, ...])

Creates an anonymous builder and calls it, thus recording action to build target from source into the dependency tree. This can be more convenient for a single special-case build than having to define and add a new named Builder.

The Command function accepts the source_scanner and target_scanner keyword arguments which are used to specify custom scanners for the specified sources or targets. The value must be a Scanner object. For example, the global DirScanner object can be used if any of the sources will be directories that must be scanned on-disk for changes to files that aren't already specified in other Builder or function calls.

The Command function also accepts the source_factory and target_factory keyword arguments which are used to specify factory functions to create SCons Nodes from any sources or targets specified as strings. If any sources or targets are already Node objects, they are not further transformed even if a factory is specified for them. The default for each is the Entry factory.

These four arguments, if given, are used in the creation of the Builder. Other Builder-specific keyword arguments are not recognized as such. See the manpage section "Builder Objects" for more information about how these arguments work in a Builder.

Any remaining keyword arguments are passed on to the generated builder when it is called, and behave as described in the manpage section "Builder Methods", in short: recognized arguments have their specified meanings, while the rest are used to override any same-named existing construction variables from the construction environment.

action can be an external command, specified as a string, or a callable Python object; see the manpage section "Action Objects" for more complete information. Also note that a string specifying an external command may be preceded by an at-sign (@) to suppress printing the command in question, or by a hyphen (-) to ignore the exit status of the external command.

Examples:

env.Command(
    target='foo.out',
    source='foo.in',
    action="$FOO_BUILD < $SOURCES > $TARGET"
)

env.Command(
    target='bar.out',
    source='bar.in',
    action=["rm -f $TARGET", "$BAR_BUILD < $SOURCES > $TARGET"],
    ENV={'PATH': '/usr/local/bin/'},
)


import os
def rename(env, target, source):
    os.rename('.tmp', str(target[0]))


env.Command(
    target='baz.out',
    source='baz.in',
    action=["$BAZ_BUILD < $SOURCES > .tmp", rename],
)

Note that the Command function will usually assume, by default, that the specified targets and/or sources are Files, if no other part of the configuration identifies what type of entries they are. If necessary, you can explicitly specify that targets or source nodes should be treated as directories by using the Dir or env.Dir functions.

Examples:

env.Command('ddd.list', Dir('ddd'), 'ls -l $SOURCE > $TARGET')

env['DISTDIR'] = 'destination/directory'
env.Command(env.Dir('$DISTDIR')), None, make_distdir)

Also note that SCons will usually automatically create any directory necessary to hold a target file, so you normally don't need to create directories by hand.

Configure(env, [custom_tests, conf_dir, log_file, config_h]), env.Configure([custom_tests, conf_dir, log_file, config_h])

Creates a Configure object for integrated functionality similar to GNU autoconf. See the manpage section "Configure Contexts" for a complete explanation of the arguments and behavior.

DebugOptions([json])

Allows setting options for SCons debug options. Currently, the only supported value is json which sets the path to the JSON file created when --debug=json is set.

DebugOptions(json='#/build/output/scons_stats.json')

New in version 4.6.0.

Decider(function), env.Decider(function)

Specifies that all up-to-date decisions for targets built through this construction environment will be handled by function. function can be the name of a function or one of the following strings that specify a predefined decider function:

"content"

Specifies that a target shall be considered out-of-date and rebuilt if the dependency's content has changed since the last time the target was built, as determined by performing a checksum on the dependency's contents using the selected hash function, and comparing it to the checksum recorded the last time the target was built. content is the default decider.

Changed in version 4.1: The decider was renamed to content since the hash function is now selectable. The former name, MD5, can still be used as a synonym, but is deprecated.

"content-timestamp"

Specifies that a target shall be considered out-of-date and rebuilt if the dependency's content has changed since the last time the target was built, except that dependencies with a timestamp that matches the last time the target was rebuilt will be assumed to be up-to-date and not rebuilt. This provides behavior very similar to the content behavior of always checksumming file contents, with an optimization of not checking the contents of files whose timestamps haven't changed. The drawback is that SCons will not detect if a file's content has changed but its timestamp is the same, as might happen in an automated script that runs a build, updates a file, and runs the build again, all within a single second.

Changed in version 4.1: The decider was renamed to content-timestamp since the hash function is now selectable. The former name, MD5-timestamp, can still be used as a synonym, but is deprecated.

"timestamp-newer"

Specifies that a target shall be considered out-of-date and rebuilt if the dependency's timestamp is newer than the target file's timestamp. This is the behavior of the classic Make utility, and make can be used a synonym for timestamp-newer.

"timestamp-match"

Specifies that a target shall be considered out-of-date and rebuilt if the dependency's timestamp is different than the timestamp recorded the last time the target was built. This provides behavior very similar to the classic Make utility (in particular, files are not opened up so that their contents can be checksummed) except that the target will also be rebuilt if a dependency file has been restored to a version with an earlier timestamp, such as can happen when restoring files from backup archives.

Examples:

# Use exact timestamp matches by default.
Decider('timestamp-match')

# Use hash content signatures for any targets built
# with the attached construction environment.
env.Decider('content')

In addition to the above already-available functions, the function argument may be a Python function you supply. Such a function must accept the following four arguments:

dependency

The Node (file) which should cause the target to be rebuilt if it has "changed" since the last time target was built.

target

The Node (file) being built. In the normal case, this is what should get rebuilt if the dependency has "changed."

prev_ni

Stored information about the state of the dependency the last time the target was built. This can be consulted to match various file characteristics such as the timestamp, size, or content signature.

repo_node

If set, use this Node instead of the one specified by dependency to determine if the dependency has changed. This argument is optional so should be written as a default argument (typically it would be written as repo_node=None). A caller will normally only set this if the target only exists in a Repository.

The function should return a value which evaluates True if the dependency has "changed" since the last time the target was built (indicating that the target should be rebuilt), and a value which evaluates False otherwise (indicating that the target should not be rebuilt). Note that the decision can be made using whatever criteria are appropriate. Ignoring some or all of the function arguments is perfectly normal.

Example:

def my_decider(dependency, target, prev_ni, repo_node=None):
    return not os.path.exists(str(target))

env.Decider(my_decider)

Default(target[, ...]), env.Default(target[, ...])

Specify default targets to the SCons target selection mechanism. Any call to Default will cause SCons to use the defined default target list instead of its built-in algorithm for determining default targets (see the manpage section "Target Selection").

target may be one or more strings, a list of strings, a NodeList as returned by a Builder, or None. A string target may be the name of a file or directory, or a target previously defined by a call to Alias (defining the alias later will still create the alias, but it will not be recognized as a default). Calls to Default are additive. A target of None will clear any existing default target list; subsequent calls to Default will add to the (now empty) default target list like normal.

Both forms of this call affect the same global list of default targets; the construction environment method applies construction variable expansion to the targets.

The current list of targets added using Default is available in the DEFAULT_TARGETS list (see below).

Examples:

Default('foo', 'bar', 'baz')
env.Default(['a', 'b', 'c'])
hello = env.Program('hello', 'hello.c')
env.Default(hello)

DefaultEnvironment([key=value, ...])

Instantiates and returns the global construction environment object. The Default Environment is used internally by SCons when executing a global function or the global form of a Builder method that requires access to a construction environment.

On the first call, arguments are interpreted as for the Environment function. The Default Environment is a singleton; subsequent calls to DefaultEnvironment return the already-constructed object, and any keyword arguments are silently ignored.

The Default Environment can be modified after instantiation, similar to other construction environments, although some construction environment methods may be unavailable. Modifying the Default Environment has no effect on any other construction environment, either existing or newly constructed.

It is not necessary to explicitly call DefaultEnvironment. SCons instantiates the default environment automatically when the build phase begins, if has not already been done. However, calling it explicitly provides the opportunity to affect and examine its contents. Instantiation occurs even if nothing in the build system appears to use it, due to internal uses.

If the project SConscript files do not use global functions or Builders, a small performance gain may be achieved by calling DefaultEnvironment with an empty tools list (DefaultEnvironment(tools=[])). This avoids the tool initialization cost for the Default Environment, which is mainly of interest in the test suite where scons is launched repeatedly in a short time period.

Depends(target, dependency), env.Depends(target, dependency)

Specifies an explicit dependency; the target will be rebuilt whenever the dependency has changed. Both the specified target and dependency can be a string (usually the path name of a file or directory) or Node objects, or a list of strings or Node objects (such as returned by a Builder call). This should only be necessary for cases where the dependency is not caught by a Scanner for the file.

Example:

env.Depends('foo', 'other-input-file-for-foo')

mylib = env.Library('mylib.c')
installed_lib = env.Install('lib', mylib)
bar = env.Program('bar.c')

# Arrange for the library to be copied into the installation
# directory before trying to build the "bar" program.
# (Note that this is for example only.  A "real" library
# dependency would normally be configured through the $LIBS
# and $LIBPATH variables, not using an env.Depends() call.)

env.Depends(bar, installed_lib)

env.Detect(progs)

Find an executable from one or more choices: progs may be a string or a list of strings. Returns the first value from progs that was found, or None. Executable is searched by checking the paths in the execution environment (env['ENV']['PATH']). On Windows systems, additionally applies the filename suffixes found in the execution environment (env['ENV']['PATHEXT']) but will not include any such extension in the return value. env.Detect is a wrapper around env.WhereIs.

env.Dictionary([var, ...], [as_dict=])

Return an object containing construction variables from env. If var is omitted, all the construction variables with their values are returned in a dict. If var is specified, and as_dict is true, the specified construction variables are returned in a dict; otherwise (the default, for backwards compatibility), values only are returned, as a scalar if one var is given, or as a list if multiples.

Example:

cvars = env.Dictionary()
cc_values = env.Dictionary('CC', 'CCFLAGS', 'CCCOM')

Note
The object returned by env.Dictionary should be treated as a read-only view into the construction variables. Some construction variables require special internal handling, and modifying them through the env.Dictionary object can bypass that handling and cause data inconsistencies. The primary use of env.Dictionary is for diagnostic purposes - it is used widely by test cases specifically because it bypasses the special handling so that behavior can be verified.

Changed in 4.9.0: as_dict added.

Dir(name, [directory]), env.Dir(name, [directory])

Returns Directory Node(s). A Directory Node is an object that represents a directory. name can be a relative or absolute path or a list of such paths. directory is an optional directory that will be used as the parent directory. If no directory is specified, the current script's directory is used as the parent.

If name is a single pathname, the corresponding node is returned. If name is a list, SCons returns a list of nodes. Construction variables are expanded in name.

Directory Nodes can be used anywhere you would supply a string as a directory name to a Builder method or function. Directory Nodes have attributes and methods that are useful in many situations; see manpage section "Filesystem Nodes" for more information.

env.Dump([var, ...], [format=TYPE])

Serialize construction variables from env to a string. If var is omitted, all the construction variables are serialized. If one or more var values are supplied, only those variables and their values are serialized.

The optional format string selects the serialization format:

pretty

Returns a pretty-printed representation of the construction variables - the result will look like a Python dict (this is the default).

json

Returns a JSON-formatted representation of the variables. The variables will be presented as a JSON object literal, the JSON equivalent of a Python dict..

Changed in 4.9.0: More than one key can be specified. The returned string always looks like a dict (or equivalent in other formats); previously a single key serialized only the value, not the key with the value.

Examples: this SConstruct

env = Environment()
print(env.Dump('CCCOM'))
print(env.Dump('CC', 'CCFLAGS', format='json'))

will print something like:

{'CCCOM': '$CC -o $TARGET -c $CFLAGS $CCFLAGS $_CCCOMCOM $SOURCES'}
{
    "CC": "gcc",
    "CCFLAGS": []
}

While this SConstruct:

env = Environment()
print(env.Dump())

will print something like:

{ 'AR': 'ar',
  'ARCOM': '$AR $ARFLAGS $TARGET $SOURCESn$RANLIB $RANLIBFLAGS $TARGET',
  'ARFLAGS': ['r'],
  'AS': 'as',
  'ASCOM': '$AS $ASFLAGS -o $TARGET $SOURCES',
  'ASFLAGS': [],
  ...

EnsurePythonVersion(major, minor)

Ensure that the Python version is at least major.minor. This function will print out an error message and exit SCons with a non-zero exit code if the actual Python version is not late enough.

Example:

EnsurePythonVersion(2,2)

EnsureSConsVersion(major, minor, [revision])

Ensure that the SCons version is at least major.minor, or major.minor.revision. if revision is specified. This function will print out an error message and exit SCons with a non-zero exit code if the actual SCons version is not late enough.

Examples:

EnsureSConsVersion(0,14)

EnsureSConsVersion(0,96,90)

Environment([key=value, ...]), env.Environment([key=value, ...])

Return a new construction environment initialized with the specified key=value pairs. The keyword arguments parse_flags, platform, toolpath, tools and variables are specially recognized and do not lead to construction variable creation. See the manpage section "Construction Environments" for more details.

Execute(action, [actionargs ...]), env.Execute(action, [actionargs ...])

Executes an Action. action may be an Action object or it may be a command-line string, list of commands, or executable Python function, each of which will first be converted into an Action object and then executed. Any additional arguments to Execute are passed on to the Action factory function which actually creates the Action object (see the manpage section Action Objects for a description). Example:

Execute(Copy('file.out', 'file.in'))

Execute performs its action immediately, as part of the SConscript-reading phase. There are no sources or targets declared in an Execute call, so any objects it manipulates will not be tracked as part of the SCons dependency graph. In the example above, neither file.out nor file.in will be tracked objects.

Execute returns the exit value of the command or return value of the Python function. scons prints an error message if the executed action fails (exits with or returns a non-zero value), however it does not, automatically terminate the build for such a failure. If you want the build to stop in response to a failed Execute call, you must explicitly check for a non-zero return value:

if Execute("mkdir sub/dir/ectory"):
    # The mkdir failed, don't try to build.
    Exit(1)

Exit([value])

This tells scons to exit immediately with the specified value. A default exit value of 0 (zero) is used if no value is specified.

Export([vars...], [key=value...]), env.Export([vars...], [key=value...])

Exports variables for sharing with other SConscript files. The variables are added to a global collection where they can be imported by other SConscript files. vars may be one or more strings, or a list of strings. If any string contains whitespace, it is split automatically into individual strings. Each string must match the name of a variable that is in scope during evaluation of the current SConscript file, or an exception is raised.

A vars argument may also be a dictionary or individual keyword arguments; in accordance with Python syntax rules, keyword arguments must come after any non-keyword arguments. The dictionary/keyword form can be used to map the local name of a variable to a different name to be used for imports. See the Examples for an illustration of the syntax.

Export calls are cumulative. Specifying a previously exported variable will replace the previous value in the collection. Both local variables and global variables can be exported.

To use an exported variable, an SConscript must call Import to bring it into its own scope. Importing creates an additional reference to the object that was originally exported, so if that object is mutable, changes made will be visible to other users of that object.

Examples:

env = Environment()
# Make env available for all SConscript files to Import().
Export("env")

package = 'my_name'
# Make env and package available for all SConscript files:.
Export("env", "package")

# Make env and package available for all SConscript files:
Export(["env", "package"])

# Make env available using the name debug:
Export(debug=env)

# Make env available using the name debug:
Export({"debug": env})

Note that the SConscript function also supports an exports argument that allows exporting one or more variables to the SConscript files invoked by that call (only). See the description of that function for details.

File(name, [directory]), env.File(name, [directory])

Returns File Node(s). A File Node is an object that represents a file. name can be a relative or absolute path or a list of such paths. directory is an optional directory that will be used as the parent directory. If no directory is specified, the current script's directory is used as the parent.

If name is a single pathname, the corresponding node is returned. If name is a list, SCons returns a list of nodes. Construction variables are expanded in name.

File Nodes can be used anywhere you would supply a string as a file name to a Builder method or function. File Nodes have attributes and methods that are useful in many situations; see manpage section "Filesystem Nodes" for more information.

FindFile(file, dirs), env.FindFile(file, dirs)

Search for file in the path specified by dirs. dirs may be a list of directory names or a single directory name. In addition to searching for files that exist in the filesystem, this function also searches for derived files that have not yet been built.

Example:

foo = env.FindFile('foo', ['dir1', 'dir2'])

FindInstalledFiles(), env.FindInstalledFiles()

Returns the list of targets set up by the Install or InstallAs builders.

This function serves as a convenient method to select the contents of a binary package.

Example:

Install('/bin', ['executable_a', 'executable_b'])

# will return the file node list
# ['/bin/executable_a', '/bin/executable_b']
FindInstalledFiles()

Install('/lib', ['some_library'])

# will return the file node list
# ['/bin/executable_a', '/bin/executable_b', '/lib/some_library']
FindInstalledFiles()

FindPathDirs(variable)

Returns a function (actually a callable Python object) intended to be used as the path_function of a Scanner object. The returned object will look up the specified variable in a construction environment and treat the construction variable's value as a list of directory paths that should be searched (like $CPPPATH, $LIBPATH, etc.).

Note that use of FindPathDirs is generally preferable to writing your own path_function for the following reasons: 1) The returned list will contain all appropriate directories found in source trees (when VariantDir is used) or in code repositories (when Repository or the -Y option are used). 2) scons will identify expansions of variable that evaluate to the same list of directories as, in fact, the same list, and avoid re-scanning the directories for files, when possible.

Example:

def my_scan(node, env, path, arg):
    # Code to scan file contents goes here...
    return include_files

scanner = Scanner(name = 'myscanner',
                  function = my_scan,
                  path_function = FindPathDirs('MYPATH'))

FindSourceFiles(node='"."'), env.FindSourceFiles(node='"."')

Returns the list of nodes which serve as the source of the built files. It does so by inspecting the dependency tree starting at the optional argument node which defaults to the '"."'-node. It will then return all leaves of node. These are all children which have no further children.

This function is a convenient method to select the contents of a Source Package.

Example:

Program('src/main_a.c')
Program('src/main_b.c')
Program('main_c.c')

# returns ['main_c.c', 'src/main_a.c', 'SConstruct', 'src/main_b.c']
FindSourceFiles()

# returns ['src/main_b.c', 'src/main_a.c' ]
FindSourceFiles('src')

As you can see, build support files (SConstruct in the above example) will also be returned by this function.

Flatten(sequence), env.Flatten(sequence)

Takes a sequence (that is, a Python list or tuple) that may contain nested sequences and returns a flattened list containing all of the individual elements in any sequence. This can be helpful for collecting the lists returned by calls to Builders; other Builders will automatically flatten lists specified as input, but direct Python manipulation of these lists does not.

Examples:

foo = Object('foo.c')
bar = Object('bar.c')

# Because `foo' and `bar' are lists returned by the Object() Builder,
# `objects' will be a list containing nested lists:
objects = ['f1.o', foo, 'f2.o', bar, 'f3.o']

# Passing such a list to another Builder is all right because
# the Builder will flatten the list automatically:
Program(source = objects)

# If you need to manipulate the list directly using Python, you need to
# call Flatten() yourself, or otherwise handle nested lists:
for object in Flatten(objects):
    print(str(object))

GetBuildFailures()

Returns a list of exceptions for the actions that failed while attempting to build targets. Each element in the returned list is a BuildError object with the following attributes that record various aspects of the build failure:

.node The node that was being built when the build failure occurred.

.status The numeric exit status returned by the command or Python function that failed when trying to build the specified Node.

.errstr The SCons error string describing the build failure. (This is often a generic message like "Error 2" to indicate that an executed command exited with a status of 2.)

.filename The name of the file or directory that actually caused the failure. This may be different from the .node attribute. For example, if an attempt to build a target named sub/dir/target fails because the sub/dir directory could not be created, then the .node attribute will be sub/dir/target but the .filename attribute will be sub/dir.

.executor The SCons Executor object for the target Node being built. This can be used to retrieve the construction environment used for the failed action.

.action The actual SCons Action object that failed. This will be one specific action out of the possible list of actions that would have been executed to build the target.

.command The actual expanded command that was executed and failed, after expansion of $TARGET, $SOURCE, and other construction variables.

Note that the GetBuildFailures function will always return an empty list until any build failure has occurred, which means that GetBuildFailures will always return an empty list while the SConscript files are being read. Its primary intended use is for functions that will be executed before SCons exits by passing them to the standard Python atexit.register() function. Example:

import atexit

def print_build_failures():
    from SCons.Script import GetBuildFailures
    for bf in GetBuildFailures():
        print("%s failed: %s" % (bf.node, bf.errstr))

atexit.register(print_build_failures)

GetBuildPath(file, [...]), env.GetBuildPath(file, [...])

Returns the scons path name (or names) for the specified file (or files). The specified file or files may be scons Nodes or strings representing path names.

GetLaunchDir()

Returns the absolute path name of the directory from which scons was initially invoked. This can be useful when using the -u, -U or -D options, which internally change to the directory in which the SConstruct file is found.

GetOption(name), env.GetOption(name)

Query the value of settable options which may have been set on the command line, via option defaults, or by using the SetOption function. The value of the option is returned in a type matching how the option was declared - see the documentation of the corresponding command line option for information about each specific option.

name can be an entry from the following table, which shows the corresponding command line arguments that could affect the value. name can be also be the destination variable name from a project-specific option added using the AddOption function, as long as that addition has been processed prior to the GetOption call in the SConscript files.

Query name	Comman-line options	Notes
cache_debug
cache_disable	,
cache_force	,
cache_readonly
cache_show
clean	,       ,
climb_up
config
debug
directory	,
diskcheck
duplicate
enable_virtualenv
experimental		since 4.2
file	,       ,       ,
hash_format		since 4.2
help	,
ignore_errors	,
ignore_virtualenv
implicit_cache
implicit_deps_changed
implicit_deps_unchanged
include_dir	,
install_sandbox		Available only if the install tool has been called
keep_going	,
max_drift
md5_chunksize	,	since 4.2
no_exec	,       ,       ,       ,
no_progress
num_jobs	,
package_type		Available only if the packaging tool has been called
profile_file
question	,
random
repository	,       ,
silent	,       ,
site_dir	,
stack_size
taskmastertrace_file
tree_printers
warn	,

GetSConsVersion()

Returns the current SCons version in the form of a Tuple[int, int, int], representing the major, minor, and revision values respectively. Added in 4.8.0.

Glob(pattern, [ondisk=True, source=False, strings=False, exclude=None]), env.Glob(pattern, [ondisk=True, source=False, strings=False, exclude=None])

Returns a possibly empty list of Nodes (or strings) that match pathname specification pattern. pattern can be absolute, top-relative, or (most commonly) relative to the directory of the current SConscript file. Glob matches both files stored on disk and Nodes which SCons already knows about, even if any corresponding file is not currently stored on disk. The environment method form (env.Glob) performs string substitution on pattern and returns whatever matches the resulting expanded pattern. The results are sorted, unlike for the similar Python glob.glob function, to ensure build order will be stable.

pattern can contain POSIX-style shell metacharacters for matching:

Pattern	Meaning
*	matches everything
?	matches any single character
[seq]	matches any character in seq       (can be a list or a range).
[!seq]	matches any character not in seq

For a literal match, wrap the metacharacter in brackets to escape the normal behavior. For example, '[?]' matches the character '?'.

Filenames starting with a dot are specially handled - they can only be matched by patterns that start with a dot (or have a dot immediately following a pathname separator character, or slash), they are not not matched by the metacharacters. Metacharacter matches also do not span directory separators.

Glob understands repositories (see the Repository function) and source directories (see the VariantDir function) and returns a Node (or string, if so configured) match in the local (SConscript) directory if a matching Node is found anywhere in a corresponding repository or source directory.

If the optional ondisk argument evaluates false, the search for matches on disk is disabled, and only matches from already-configured File or Dir Nodes are returned. The default is to return Nodes for matches on disk as well.

If the optional source argument evaluates true, and the local directory is a variant directory, then Glob returns Nodes from the corresponding source directory, rather than the local directory.

If the optional strings argument evaluates true, Glob returns matches as strings, rather than Nodes. The returned strings will be relative to the local (SConscript) directory. (Note that while this may make it easier to perform arbitrary manipulation of file names, it loses the context SCons would have in the Node, so if the returned strings are passed to a different SConscript file, any Node translation there will be relative to that SConscript directory, not to the original SConscript directory.)

The optional exclude argument may be set to a pattern or a list of patterns describing files or directories to filter out of the match list. Elements matching a least one specified pattern will be excluded. These patterns use the same syntax as for pattern.

Examples:

Program("foo", Glob("*.c"))
Zip("/tmp/everything", Glob(".??*") + Glob("*"))
sources = Glob("*.cpp", exclude=["os_*_specific_*.cpp"]) 
    + Glob("os_%s_specific_*.cpp" % currentOS)

Help(text, append=False, local_only=False), env.Help(text, append=False, local_only=False)

Adds text to the help message shown when scons is called with the -h or --help argument.

On the first call to Help, if append is False (the default), any existing help text is discarded. The default help text is the help for the scons command itself plus help collected from any project-local AddOption calls. This is the help printed if Help has never been called. If append is True, text is appended to the existing help text. If local_only is also True (the default is False), the project-local help from AddOption calls is preserved in the help message but the scons command help is not.

Subsequent calls to Help ignore the keyword arguments append and local_only and always append to the existing help text.

Changed in 4.6.0: added local_only.

Ignore(target, dependency), env.Ignore(target, dependency)

Ignores dependency when deciding if target needs to be rebuilt. target and dependency can each be a single filename or Node or a list of filenames or Nodes.

Ignore can also be used to remove a target from the default build by specifying the directory the target will be built in as target and the file you want to skip selecting for building as dependency. Note that this only removes the target from the default target selection algorithm: if it is a dependency of another object being built SCons still builds it normally. See the third and forth examples below.

Examples:

env.Ignore('foo', 'foo.c')
env.Ignore('bar', ['bar1.h', 'bar2.h'])
env.Ignore('.', 'foobar.obj')
env.Ignore('bar', 'bar/foobar.obj')

Import(vars...), env.Import(vars...)

Imports variables into the scope of the current SConscript file. vars must be strings representing names of variables which have been previously exported either by the Export function or by the exports argument to the SConscript function. Variables exported by the SConscript call take precedence. Multiple variable names can be passed to Import as separate arguments, as a list of strings, or as words in a space-separated string. The wildcard "*" can be used to import all available variables.

If the imported variable is mutable, changes made locally will be reflected in the object the variable is bound to. This allows subsidiary SConscript files to contribute to building up, for example, a construction environment.

Examples:

Import("env")
Import("env", "variable")
Import(["env", "variable"])
Import("*")

Literal(string), env.Literal(string)

The specified string will be preserved as-is and not have construction variables expanded.

Local(targets), env.Local(targets)

The specified targets will have copies made in the local tree, even if an already up-to-date copy exists in a repository. Returns a list of the target Node or Nodes.

env.MergeFlags(arg, [unique])

Merges values from arg into construction variables in env. If arg is a dictionary, each key-value pair represents a construction variable name and the corresponding flags to merge. If arg is not a dictionary, MergeFlags attempts to convert it to one before the values are merged. env.ParseFlags is used for this, so values to be converted are subject to the same limitations: ParseFlags has knowledge of which construction variables certain flags should go to, but not all; and only for GCC and compatible compiler chains. arg must be a single object, so to pass multiple strings, enclose them in a list.

If unique is true (the default), duplicate values are not retained. In case of duplication, any construction variable names that end in PATH keep the left-most value so the path search order is not altered. All other construction variables keep the right-most value. If unique is false, values are appended even if they are duplicates.

Examples:

# Add an optimization flag to $CCFLAGS.
env.MergeFlags({'CCFLAGS': '-O3'})

# Combine the flags returned from running pkg-config with an optimization
# flag and merge the result into the construction variables.
env.MergeFlags(['!pkg-config gtk+-2.0 --cflags', '-O3'])

# Combine an optimization flag with the flags returned from running pkg-config
# for two distinct packages and merge into the construction variables.
env.MergeFlags(
    [
        '-O3',
        '!pkg-config gtk+-2.0 --cflags --libs',
        '!pkg-config libpng12 --cflags --libs',
    ]
)

NoCache(target, ...), env.NoCache(target, ...)

Specifies a list of files which should not be cached whenever the CacheDir method has been activated. The specified targets may be a list or an individual target.

Multiple files should be specified either as separate arguments to the NoCache method, or as a list. NoCache will also accept the return value of any of the construction environment Builder methods.

Calling NoCache on directories and other non-File Node types has no effect because only File Nodes are cached.

Examples:

NoCache('foo.elf')
NoCache(env.Program('hello', 'hello.c'))

NoClean(targets, ...), env.NoClean(targets, ...)

Specifies files or directories which should not be removed whenever a specified target (or its dependencies) is selected and clean mode is active (-c command line option). targets may be one or more file or directory names or nodes, and/or lists of names or nodes. NoClean can be called multiple times.

Calling NoClean for a target overrides calling Clean for the same target, so any targets passed to both functions will not be removed in clean mode.

Examples:

NoClean('foo.elf')
NoClean(env.Program('hello', 'hello.c'))

env.ParseConfig(command, [function, unique])

Updates the current construction environment with the values extracted from the output of running external command, by passing it to a helper function. command may be a string or a list of strings representing the command and its arguments. If function is omitted or None, env.MergeFlags is used. By default, duplicate values are not added to any construction variables; you can specify unique=False to allow duplicate values to be added.

command is executed using the SCons execution environment (that is, the construction variable $ENV in the current construction environment). If command needs additional information to operate properly, that needs to be set in the execution environment. For example, pkg-config may need a custom value set in the PKG_CONFIG_PATH environment variable.

env.MergeFlags needs to understand the output produced by command in order to distribute it to appropriate construction variables. env.MergeFlags uses a separate function to do that processing - see env.ParseFlags for the details, including a table of options and corresponding construction variables. To provide alternative processing of the output of command, you can supply a custom function, which must accept three arguments: the construction environment to modify, a string argument containing the output from running command, and the optional unique flag.

ParseDepends(filename, [must_exist, only_one]), env.ParseDepends(filename, [must_exist, only_one])

Parses the contents of filename as a list of dependencies in the style of Make or mkdep, and explicitly establishes all of the listed dependencies.

By default, it is not an error if filename does not exist. The optional must_exist argument may be set to True to have SCons raise an exception if the file does not exist, or is otherwise inaccessible.

The optional only_one argument may be set to True to have SCons raise an exception if the file contains dependency information for more than one target. This can provide a small sanity check for files intended to be generated by, for example, the gcc -M flag, which should typically only write dependency information for one output file into a corresponding .d file.

filename and all of the files listed therein will be interpreted relative to the directory of the SConscript file which calls the ParseDepends function.

env.ParseFlags(flags, ...)

Parses one or more strings containing typical command-line flags for GCC-style tool chains and returns a dictionary with the flag values separated into the appropriate SCons construction variables. Intended as a companion to the env.MergeFlags method, but allows for the values in the returned dictionary to be modified, if necessary, before merging them into the construction environment. (Note that env.MergeFlags will call this method if its argument is not a dictionary, so it is usually not necessary to call env.ParseFlags directly unless you want to manipulate the values.)

If the first character in any string is an exclamation mark (!), the rest of the string is executed as a command, and the output from the command is parsed as GCC tool chain command-line flags and added to the resulting dictionary. This can be used to call a *-config command typical of the POSIX programming environment (for example, pkg-config). Note that such a command is executed using the SCons execution environment; if the command needs additional information, that information needs to be explicitly provided. See ParseConfig for more details.

Flag values are translated according to the prefix found, and added to the following construction variables:

-arch                   CCFLAGS, LINKFLAGS
-D                      CPPDEFINES
-framework              FRAMEWORKS
-frameworkdir=          FRAMEWORKPATH
-fmerge-all-constants   CCFLAGS, LINKFLAGS
-fopenmp                CCFLAGS, LINKFLAGS
-fsanitize              CCFLAGS, LINKFLAGS
-include                CCFLAGS
-imacros                CCFLAGS
-isysroot               CCFLAGS, LINKFLAGS
-isystem                CCFLAGS
-iquote                 CCFLAGS
-idirafter              CCFLAGS
-I                      CPPPATH
-l                      LIBS
-L                      LIBPATH
-mno-cygwin             CCFLAGS, LINKFLAGS
-mwindows               LINKFLAGS
-openmp                 CCFLAGS, LINKFLAGS
-pthread                CCFLAGS, LINKFLAGS
-std=                   CFLAGS
-stdlib=                CXXFLAGS
-Wa,                    ASFLAGS, CCFLAGS
-Wl,-rpath=             RPATH
-Wl,-R,                 RPATH
-Wl,-R                  RPATH
-Wl,                    LINKFLAGS
-Wp,                    CPPFLAGS
-                       CCFLAGS
+                       CCFLAGS, LINKFLAGS

Any other strings not associated with options are assumed to be the names of libraries and added to the $LIBS construction variable.

Examples (all of which produce the same result):

dict = env.ParseFlags('-O2 -Dfoo -Dbar=1')
dict = env.ParseFlags('-O2', '-Dfoo', '-Dbar=1')
dict = env.ParseFlags(['-O2', '-Dfoo -Dbar=1'])
dict = env.ParseFlags('-O2', '!echo -Dfoo -Dbar=1')

Platform(plat), env.Platform(plat)

When called as a global function, returns a callable platform object selected by plat (defaults to the detected platform for the current system) that can be used to initialize a construction environment by passing it as the platform keyword argument to the Environment function.

Example:

env = Environment(platform=Platform('win32'))

When called as a method of an environment, calls the platform object indicated by plat to update that environment.

env.Platform('posix')

See the manpage section "Construction Environments" for more details.

Precious(target, ...), env.Precious(target, ...)

Marks target as precious so it is not deleted before it is rebuilt. Normally SCons deletes a target before building it. Multiple targets can be passed in a single call, and may be strings and/or nodes. Returns a list of the affected target nodes.

env.Prepend(key=val, [...])

Prepend values to construction variables in the current construction environment, works like env.Append (see for details), except that values are added to the front, rather than the end, of any existing value of the construction variable

Example:

env.Prepend(CCFLAGS='-g ', FOO=['foo.yyy'])

See also env.Append, env.AppendUnique and env.PrependUnique.

env.PrependENVPath(name, newpath, [envname, sep, delete_existing=True])

Prepend path elements specified by newpath to the given search path string or list name in mapping envname in the construction environment. Supplying envname is optional: the default is the execution environment $ENV. Optional sep is used as the search path separator, the default is the platform's separator (os.pathsep). A path element will only appear once. Any duplicates in newpath are dropped, keeping the first appearing (to preserve path order). If delete_existing is False any addition duplicating an existing path element is ignored; if delete_existing is True (the default) the existing value will be dropped and the path element will be inserted at the beginning. To help maintain uniqueness all paths are normalized (using os.path.normpath and os.path.normcase).

Example:

print('before:', env['ENV']['INCLUDE'])
include_path = '/foo/bar:/foo'
env.PrependENVPath('INCLUDE', include_path)
print('after:', env['ENV']['INCLUDE'])

Yields:

before: /biz:/foo
after: /foo/bar:/foo:/biz

See also env.AppendENVPath.

env.PrependUnique(key=val, [...], [delete_existing=False])

Prepend values to construction variables in the current construction environment, maintaining uniqueness. Works like env.Append, except that values are added to the front, rather than the end, of the construction variable, and values that would become duplicates are not added. If delete_existing is set to a true value, then for any duplicate, the existing instance of val is first removed, then val is inserted, having the effect of moving it to the front.

Example:

env.PrependUnique(CCFLAGS='-g', FOO=['foo.yyy'])

See also env.Append, env.AppendUnique and env.Prepend.

Progress(callable, [interval]), Progress(string, [interval, file, overwrite]), Progress(list_of_strings, [interval, file, overwrite])

Allows SCons to show progress made during the build by displaying a string or calling a function while evaluating Nodes (e.g. files).

If the first specified argument is a Python callable (a function or an object that has a __call__ method), the function will be called once every interval times a Node is evaluated (default 1). The callable will be passed the evaluated Node as its only argument. (For future compatibility, it's a good idea to also add *args and **kwargs as arguments to your function or method signatures. This will prevent the code from breaking if SCons ever changes the interface to call the function with additional arguments in the future.)

An example of a simple custom progress function that prints a string containing the Node name every 10 Nodes:

def my_progress_function(node, *args, **kwargs):
    print('Evaluating node %s!' % node)
Progress(my_progress_function, interval=10)

A more complicated example of a custom progress display object that prints a string containing a count every 100 evaluated Nodes. Note the use of r (a carriage return) at the end so that the string will overwrite itself on a display:

import sys
class ProgressCounter(object):
    count = 0
    def __call__(self, node, *args, **kw):
        self.count += 100
        sys.stderr.write('Evaluated %s nodesr' % self.count)

Progress(ProgressCounter(), interval=100)

If the first argument to Progress is a string or list of strings, it is taken as text to be displayed every interval evaluated Nodes. If the first argument is a list of strings, then each string in the list will be displayed in rotating fashion every interval evaluated Nodes.

The default is to print the string on standard output. An alternate output stream may be specified with the file keyword argument, which the caller must pass already opened.

The following will print a series of dots on the error output, one dot for every 100 evaluated Nodes:

import sys
Progress('.', interval=100, file=sys.stderr)

If the string contains the verbatim substring $TARGET;, it will be replaced with the Node. Note that, for performance reasons, this is not a regular SCons variable substitution, so you can not use other variables or use curly braces. The following example will print the name of every evaluated Node, using a carriage return) (r) to cause each line to overwritten by the next line, and the overwrite keyword argument (default False) to make sure the previously-printed file name is overwritten with blank spaces:

import sys
Progress('$TARGETr', overwrite=True)

A list of strings can be used to implement a "spinner" on the user's screen as follows, changing every five evaluated Nodes:

Progress(['-r', 'r', '|r', '/r'], interval=5)

Pseudo(target, ...), env.Pseudo(target, ...)

Marks target as a pseudo target, not representing the production of any physical target file. If any pseudo target does exist, SCons will abort the build with an error. Multiple targets can be passed in a single call, and may be strings and/or Nodes. Returns a list of the affected target nodes.

Pseudo may be useful in conjuction with a builder call (such as Command) which does not create a physical target, and the behavior if the target accidentally existed would be incorrect. This is similar in concept to the GNU make .PHONY target. SCons also provides a powerful target alias capability (see Alias) which may provide more flexibility in many situations when defining target names that are not directly built.

PyPackageDir(modulename), env.PyPackageDir(modulename)

Finds the location of modulename, which can be a string or a sequence of strings, each representing the name of a Python module. Construction variables are expanded in modulename. Returns a Directory Node (see Dir), or a list of Directory Nodes if modulename is a sequence. None is returned for any module not found.

When a Tool module which is installed as a Python module is used, you need to specify a toolpath argument to Tool, Environment or Clone, as tools outside the standard project locations (site_scons/site_tools) will not be found otherwise. Using PyPackageDir allows this path to be discovered at runtime instead of hardcoding the path.

Example:

env = Environment(
    tools=["default", "ExampleTool"],
    toolpath=[PyPackageDir("example_tool")]
)

env.Replace(key=val, [...])

Replaces construction variables in the Environment with the specified keyword arguments.

Example:

env.Replace(CCFLAGS='-g', FOO='foo.xxx')

Repository(directory), env.Repository(directory)

Sets directory as a repository to be searched for files contributing to the build. Multiple calls to Repository are allowed, with repositories searched in the given order. Repositories specified via command-line option have higher priority.

In scons, a repository is partial or complete copy of the source tree, from the top-level directory down, containing source files that can be used to build targets in the current worktree. Repositories can also contain derived files. An example might be an official source tree maintained by an integrator. If a repository contains derived files, they should be the result of building with SCons, so a signature database (sconsign) is present in the repository, allowing better decisions on whether they are up-to-date or not.

Note that if an up-to-date derived file already exists in a repository, scons will not make a copy in the local directory tree. If you need a local copy to be made, use the Local method.

Requires(target, prerequisite), env.Requires(target, prerequisite)

Specifies an order-only relationship between target and prerequisite. The prerequisites will be (re)built, if necessary, before the target file(s), but the target file(s) do not actually depend on the prerequisites and will not be rebuilt simply because the prerequisite file(s) change. target and prerequisite may each be a string or Node, or a list of strings or Nodes. If there are multiple target values, the prerequisite(s) are added to each one. Returns a list of the affected target nodes.

Example:

env.Requires('foo', 'file-that-must-be-built-before-foo')

Return([vars..., stop=True])

Return to the calling SConscript, optionally returning the values of variables named in vars. Multiple strings containing variable names may be passed to Return. A string containing white space is split into individual variable names. Returns the value if one variable is specified, else returns a tuple of values. Returns an empty tuple if vars is omitted.

By default Return stops processing the current SConscript and returns immediately. The optional stop keyword argument may be set to a false value to continue processing the rest of the SConscript file after the Return call (this was the default behavior prior to SCons 0.98.) However, the values returned are still the values of the variables in the named vars at the point Return was called.

Examples:

# Returns no values (evaluates False)
Return()

# Returns the value of the 'foo' Python variable.
Return("foo")

# Returns the values of the Python variables 'foo' and 'bar'.
Return("foo", "bar")

# Returns the values of Python variables 'val1' and 'val2'.
Return('val1 val2')

Scanner(function, [name, argument, skeys, path_function, node_class, node_factory, scan_check, recursive]), env.Scanner(function, [name, argument, skeys, path_function, node_class, node_factory, scan_check, recursive])

Creates a Scanner object for the specified function. See manpage section "Scanner Objects" for a complete explanation of the arguments and behavior.

SConscript(scriptnames, [exports, variant_dir, duplicate, must_exist]), env.SConscript(scriptnames, [exports, variant_dir, duplicate, must_exist]), SConscript(dirs=subdirs, [name=scriptname, exports, variant_dir, duplicate, must_exist]), env.SConscript(dirs=subdirs, [name=scriptname, exports, variant_dir, duplicate, must_exist])

Executes subsidiary SConscript (build configuration) file(s). There are two ways to call the SConscript function.

The first calling style is to supply one or more SConscript file names as the first positional argument, which can be a string or a list of strings. If there is a second positional argument, it is treated as if the exports keyword argument had been given (see below). Examples:

SConscript('SConscript')  # run SConscript in the current directory
SConscript('src/SConscript')  # run SConscript in the src directory
SConscript(['src/SConscript', 'doc/SConscript'])
SConscript(Split('src/SConscript doc/SConscript'))
config = SConscript('MyConfig.py')

The second calling style is to omit the positional argument naming the script and instead specify directory names using the dirs keyword argument. The value can be a string or list of strings. In this case, scons will execute a subsidiary configuration file named SConscript (by default) in each of the specified directories. You may specify a name other than SConscript by supplying an optional name=scriptname keyword argument. The first three examples below have the same effect as the first three examples above:

SConscript(dirs='.')  # run SConscript in the current directory
SConscript(dirs='src')  # run SConscript in the src directory
SConscript(dirs=['src', 'doc'])
SConscript(dirs=['sub1', 'sub2'], name='MySConscript')

The optional exports keyword argument specifies variables to make available for use by the called SConscripts, which are evaluated in an isolated context and otherwise do not have access to local variables from the calling SConscript. The value may be a string or list of strings representing variable names, or a dictionary mapping local names to the names they can be imported by. For the first (scriptnames) calling style, a second positional argument will also be interpreted as exports; the second (directory) calling style accepts no positional arguments and must use the keyword form. These variables are locally exported only to the called SConscript file(s), and take precedence over any same-named variables in the global pool managed by the Export function. The subsidiary SConscript files must use the Import function to import the variables into their local scope. Examples:

foo = SConscript('sub/SConscript', exports='env')
SConscript('dir/SConscript', exports=['env', 'variable'])
SConscript(dirs='subdir', exports='env variable')
SConscript(dirs=['one', 'two', 'three'], exports='shared_info')

If the optional variant_dir argument is present, it causes an effect equivalent to the VariantDir function, but in effect only within the scope of the SConscript call. The variant_dir argument is interpreted relative to the directory of the calling SConscript file. The source directory is the directory in which the called SConscript file resides and the SConscript file is evaluated as if it were in the variant_dir directory. Thus:

SConscript('src/SConscript', variant_dir='build')

is equivalent to:

VariantDir('build', 'src')
SConscript('build/SConscript')

If the sources are in the same directory as the SConstruct,

SConscript('SConscript', variant_dir='build')

is equivalent to:

VariantDir('build', '.')
SConscript('build/SConscript')

The optional duplicate argument is interpreted as for VariantDir. If the variant_dir argument is omitted, the duplicate argument is ignored. See the description of VariantDir for additional details and restrictions.

If the optional must_exist is True (the default), an exception is raised if a requested SConscript file is not found. To allow missing scripts to be silently ignored (the default behavior prior to SCons version 3.1), pass must_exist=False in the SConscript call.

Changed in 4.6.0: must_exist now defaults to True.

Here are some composite examples:

# collect the configuration information and use it to build src and doc
shared_info = SConscript('MyConfig.py')
SConscript('src/SConscript', exports='shared_info')
SConscript('doc/SConscript', exports='shared_info')

# build debugging and production versions.  SConscript
# can use Dir('.').path to determine variant.
SConscript('SConscript', variant_dir='debug', duplicate=0)
SConscript('SConscript', variant_dir='prod', duplicate=0)

# build debugging and production versions.  SConscript
# is passed flags to use.
opts = { 'CPPDEFINES' : ['DEBUG'], 'CCFLAGS' : '-pgdb' }
SConscript('SConscript', variant_dir='debug', duplicate=0, exports=opts)
opts = { 'CPPDEFINES' : ['NODEBUG'], 'CCFLAGS' : '-O' }
SConscript('SConscript', variant_dir='prod', duplicate=0, exports=opts)

# build common documentation and compile for different architectures
SConscript('doc/SConscript', variant_dir='build/doc', duplicate=0)
SConscript('src/SConscript', variant_dir='build/x86', duplicate=0)
SConscript('src/SConscript', variant_dir='build/ppc', duplicate=0)

SConscript returns the values of any variables named by the executed SConscript file(s) in arguments to the Return function. If a single SConscript call causes multiple scripts to be executed, the return value is a tuple containing the returns of each of the scripts. If an executed script does not explicitly call Return, it returns None.

SConscriptChdir(value)

By default, scons changes its working directory to the directory in which each subsidiary SConscript file lives while reading and processing that script. This behavior may be disabled by specifying an argument which evaluates false, in which case scons will stay in the top-level directory while reading all SConscript files. (This may be necessary when building from repositories, when all the directories in which SConscript files may be found don't necessarily exist locally.) You may enable and disable this ability by calling SConscriptChdir multiple times.

Example:

SConscriptChdir(False)
SConscript('foo/SConscript')    # will not chdir to foo
SConscriptChdir(True)
SConscript('bar/SConscript')    # will chdir to bar

SConsignFile([name, dbm_module]), env.SConsignFile([name, dbm_module])

Specify where to store the SCons file signature database, and which database format to use. This may be useful to specify alternate database files and/or file locations for different types of builds.

The optional name argument is the base name of the database file(s). If not an absolute path name, these are placed relative to the directory containing the top-level SConstruct file. The default is .sconsign. The actual database file(s) stored on disk may have an appropriate suffix appended by the chosen dbm_module

The optional dbm_module argument specifies which Python database module to use for reading/writing the file. The module must be imported first; then the imported module name is passed as the argument. The default is a custom SCons.dblite module that uses pickled Python data structures, which works on all Python versions. See documentation of the Python dbm module for other available types.

If called with no arguments, the database will default to .sconsign.dblite in the top directory of the project, which is also the default if if SConsignFile is not called.

The setting is global, so the only difference between the global function and the environment method form is variable expansion on name. There should only be one active call to this function/method in a given build setup.

If name is set to None, scons will store file signatures in a separate .sconsign file in each directory, not in a single combined database file. This is a backwards-compatibility measure to support what was the default behavior prior to SCons 0.97 (i.e. before 2008). Use of this mode is discouraged and may be deprecated in a future SCons release.

Examples:

# Explicitly stores signatures in ".sconsign.dblite"
# in the top-level SConstruct directory (the default behavior).
SConsignFile()

# Stores signatures in the file "etc/scons-signatures"
# relative to the top-level SConstruct directory.
# SCons will add a database suffix to this name.
SConsignFile("etc/scons-signatures")

# Stores signatures in the specified absolute file name.
# SCons will add a database suffix to this name.
SConsignFile("/home/me/SCons/signatures")

# Stores signatures in a separate .sconsign file
# in each directory.
SConsignFile(None)

# Stores signatures in a GNU dbm format .sconsign file
import dbm.gnu
SConsignFile(dbm_module=dbm.gnu)

env.SetDefault(key=val, [...])

Sets construction variables to default values specified with the keyword arguments if (and only if) the variables are not already set. The following statements are equivalent:

env.SetDefault(FOO='foo')
if 'FOO' not in env:
    env['FOO'] = 'foo'

SetOption(name, value), env.SetOption(name, value)

Sets scons option variable name to value. These options are all also settable via command-line options but the variable name may differ from the command-line option name - see the table for correspondences. A value set via command-line option will take precedence over one set with SetOption, which allows setting a project default in the scripts and temporarily overriding it via command line. SetOption calls can also be placed in the site_init.py file.

See the documentation in the manpage for the corresponding command line option for information about each specific option. The value parameter is mandatory, for option values which are boolean in nature (that is, the command line option does not take an argument) use a value which evaluates to true (e.g. True, 1) or false (e.g. False, 0).

Options which affect the reading and processing of SConscript files are not settable using SetOption since those files must be read in order to find the SetOption call in the first place.

For project-specific options (sometimes called local options) added via an AddOption call, SetOption is available only after the AddOption call has completed successfully, and only if that call included the settable=True argument.

The settable variables with their associated command-line options are:

Settable name	Comman-line options	Notes
clean	,     ,
diskcheck
duplicate
experimental		since 4.2
hash_chunksize		Actually sets md5_chunksize.     since 4.2
hash_format		since 4.2
help	,
implicit_cache
implicit_deps_changed		Also sets implicit_cache.     (settable since 4.2)
implicit_deps_unchanged		Also sets implicit_cache.     (settable since 4.2)
max_drift
md5_chunksize
no_exec	,     ,     ,     ,
no_progress		See     [7]
num_jobs	,
random
silent	,     ,
stack_size
warn
- [a] If no_progress is set via SetOption in an SConscript file (but not if set in a site_init.py file) there will still be an initial status message about reading SConscript files since SCons has to start reading them before it can see the SetOption.

Example:

SetOption('max_drift', 0)

SideEffect(side_effect, target), env.SideEffect(side_effect, target)

Declares side_effect as a side effect of building target. Both side_effect and target can be a list, a file name, or a node. A side effect is a target file that is created or updated as a side effect of building other targets. For example, a Windows PDB file is created as a side effect of building the .obj files for a static library, and various log files are created updated as side effects of various TeX commands. If a target is a side effect of multiple build commands, scons will ensure that only one set of commands is executed at a time. Consequently, you only need to use this method for side-effect targets that are built as a result of multiple build commands.

Because multiple build commands may update the same side effect file, by default the side_effect target is not automatically removed when the target is removed by the -c option. (Note, however, that the side_effect might be removed as part of cleaning the directory in which it lives.) If you want to make sure the side_effect is cleaned whenever a specific target is cleaned, you must specify this explicitly with the Clean or env.Clean function.

This function returns the list of side effect Node objects that were successfully added. If the list of side effects contained any side effects that had already been added, they are not added and included in the returned list.

Split(arg), env.Split(arg)

If arg is a string, splits on whitespace and returns a list of strings without whitespace. This mode is the most common case, and can be used to split a list of filenames (for example) rather than having to type them as a list of individually quoted words. If arg is a list or tuple returns the list or tuple unchanged. If arg is any other type of object, returns a list containing just the object. These non-string cases do not actually do any spliting, but allow an argument variable to be passed to Split without having to first check its type.

Example:

files = Split("f1.c f2.c f3.c")
files = env.Split("f4.c f5.c f6.c")
files = Split("""
    f7.c
    f8.c
    f9.c
""")

env.subst(input, [raw, target, source, conv])

Performs construction variable interpolation (substitution) on input, which can be a string or a sequence. Substitutable elements take the form ${expression}, although if there is no ambiguity in recognizing the element, the braces can be omitted. A literal $ can be entered by using $$.

By default, leading or trailing white space will be removed from the result, and all sequences of white space will be compressed to a single space character. Additionally, any $( and $) character sequences will be stripped from the returned string, The optional raw argument may be set to 1 if you want to preserve white space and $(-$) sequences. The raw argument may be set to 2 if you want to additionally discard all characters between any $( and $) pairs (as is done for signature calculation).

If input is a sequence (list or tuple), the individual elements of the sequence will be expanded, and the results will be returned as a list.

The optional target and source keyword arguments must be set to lists of target and source nodes, respectively, if you want the $TARGET, $TARGETS, $SOURCE and $SOURCES to be available for expansion. This is usually necessary if you are calling env.subst from within a Python function used as an SCons action.

Returned string values or sequence elements are converted to their string representation by default. The optional conv argument may specify a conversion function that will be used in place of the default. For example, if you want Python objects (including SCons Nodes) to be returned as Python objects, you can use a Python lambda expression to pass in an unnamed function that simply returns its unconverted argument.

Example:

print(env.subst("The C compiler is: $CC"))

def compile(target, source, env):
    sourceDir = env.subst(
        "${SOURCE.srcdir}",
        target=target,
        source=source
    )

source_nodes = env.subst('$EXPAND_TO_NODELIST', conv=lambda x: x)

Tag(node, tags)

Annotates file or directory Nodes with information about how the Package Builder should package those files or directories. All Node-level tags are optional.

Examples:

# makes sure the built library will be installed with 644 file access mode
Tag(Library('lib.c'), UNIX_ATTR="0o644")

# marks file2.txt to be a documentation file
Tag('file2.txt', DOC)

Tool(name, [toolpath, key=value, ...]), env.Tool(name, [toolpath, key=value, ...])

Locates the tool specification module name and returns a callable tool object for that tool. When the environment method (env.Tool) form is used, the tool object is automatically called before the method returns to update env, and name is appended to the $TOOLS construction variable in that environment. When the global function Tool form is used, the tool object is constructed but not called, as it lacks the context of an environment to update, and the returned object needs to be used to arrange for the call.

The tool module is searched for in the tool search paths (see the Tools section in the manual page for details) and in any paths specified by the optional toolpath parameter, which must be a list of strings. If toolpath is omitted, the toolpath supplied when the environment was created, if any, is used.

Any remaining keyword arguments are saved in the tool object, and will be passed to the tool module's generate function when the tool object is actually called. The generate function can update the construction environment with construction variables and arrange any other initialization needed to use the mechanisms that tool describes, and can use these extra arguments to help guide its actions.

Changed in version 4.2: env.Tool now returns the tool object, previously it did not return (i.e. returned None).

Examples:

env.Tool('gcc')
env.Tool('opengl', toolpath=['build/tools'])

The returned tool object can be passed to an Environment or Clone call as part of the tools keyword argument, in which case the tool is applied to the environment being constructed, or it can be called directly, in which case a construction environment to update must be passed as the argument. Either approach will also update the $TOOLS construction variable.

Examples:

env = Environment(tools=[Tool('msvc')])

env = Environment()
msvctool = Tool('msvc')
msvctool(env)  # adds 'msvc' to the TOOLS variable
gltool = Tool('opengl', toolpath = ['tools'])
gltool(env)  # adds 'opengl' to the TOOLS variable

ValidateOptions([throw_exception=False])

Check that all the options specified on the command line are either SCons built-in options or defined via calls to AddOption. SCons will eventually fail on unknown options anyway, but calling this function allows the build to "fail fast" before executing expensive logic later in the build.

This function should only be called after the last AddOption call in your SConscript logic. Be aware that some tools call AddOption, if you are getting error messages for arguments that they add, you will need to ensure that those tools are loaded before calling ValidateOptions.

If there are any unknown command line options, ValidateOptions prints an error message and exits with an error exit status. If the optional throw_exception argument is True (default is False), a SConsBadOptionError is raised, giving an opportunity for the SConscript logic to catch that exception and handle invalid options appropriately. Note that this exception name needs to be imported (see the example below).

A common build problem is typos (or thinkos) - a user enters an option that is just a little off the expected value, or perhaps a different word with a similar meaning. It may be useful to abort the build before going too far down the wrong path. For example:

$ scons --compilers=mingw  # the correct flag is --compiler
      

Here SCons could go off and run a bunch of configure steps with the default value of --compiler, since the incorrect command line did not actually supply a value to it, costing developer time to track down why the configure logic made the "wrong" choices. This example shows catching this:

from SCons.Script.SConsOptions import SConsBadOptionError

AddOption(
    '--compiler',
    dest='compiler',
    action='store',
    default='gcc',
    type='string',
)

# ... other SConscript logic ...

try:
    ValidateOptions(throw_exception=True)
except SConsBadOptionError as e:
    print(f"ValidateOptions detects a fail: ", e.opt_str)
    Exit(3)
      

New in version 4.5.0

Value(value, [built_value], [name]), env.Value(value, [built_value], [name])

Returns a Node object representing the specified Python value. Value Nodes can be used as dependencies of targets. If the string representation of the Value Node changes between SCons runs, it is considered out-of-date and any targets depending on it will be rebuilt. Since Value Nodes have no filesystem representation, timestamps are not used; the timestamp deciders perform the same content-based up to date check.

The optional built_value argument can be specified when the Value Node is created to indicate the Node should already be considered "built."

The optional name parameter can be provided as an alternative name for the resulting Value node; this is advised if the value parameter cannot be converted to a string.

Value Nodes have a write method that can be used to "build" a Value Node by setting a new value. The corresponding read method returns the built value of the Node.

Changed in version 4.0: the name parameter was added.

Examples:

env = Environment()

def create(target, source, env):
    """Action function to create a file from a Value.

    Writes 'prefix=$SOURCE' into the file name given as $TARGET.
    """
    with open(str(target[0]), 'wb') as f:
        f.write(b'prefix=' + source[0].get_contents() + b'n')

# Fetch the prefix= argument, if any, from the command line.
# Use /usr/local as the default.
prefix = ARGUMENTS.get('prefix', '/usr/local')

# Attach builder named Config to the construction environment
# using the 'create' action function above.
env['BUILDERS']['Config'] = Builder(action=create)
env.Config(target='package-config', source=Value(prefix))

def build_value(target, source, env):
    """Action function to "build" a Value.

    Writes contents of $SOURCE into $TARGET, thus updating if it existed.
    """
    target[0].write(source[0].get_contents())

output = env.Value('before')
input = env.Value('after')

# Attach a builder named UpdateValue to the construction environment
# using the 'build_value' action function above.
env['BUILDERS']['UpdateValue'] = Builder(action=build_value)
env.UpdateValue(target=Value(output), source=Value(input))

VariantDir(variant_dir, src_dir, [duplicate]), env.VariantDir(variant_dir, src_dir, [duplicate])

Sets up a mapping to define a variant build directory in variant_dir. src_dir must not be underneath variant_dir. A VariantDir mapping is global, even if called using the env.VariantDir form. VariantDir can be called multiple times with the same src_dir to set up multiple variant builds with different options.

Note if variant_dir is not under the project top directory, target selection rules will not pick targets in the variant directory unless they are explicitly specified.

When files in variant_dir are referenced, SCons backfills as needed with files from src_dir to create a complete build directory. By default, SCons physically duplicates the source files, SConscript files, and directory structure as needed into the variant directory. Thus, a build performed in the variant directory is guaranteed to be identical to a build performed in the source directory even if intermediate source files are generated during the build, or if preprocessors or other scanners search for included files using paths relative to the source file, or if individual compilers or other invoked tools are hard-coded to put derived files in the same directory as source files. Only the files SCons calculates are needed for the build are duplicated into variant_dir. If possible on the platform, the duplication is performed by linking rather than copying. This behavior is affected by the --duplicate command-line option.

Duplicating the source files may be disabled by setting the duplicate argument to False. This will cause SCons to invoke Builders using the path names of source files in src_dir and the path names of derived files within variant_dir. This is more efficient than duplicating, and is safe for most builds; revert to duplicate=True if it causes problems.

VariantDir works most naturally when used with a subsidiary SConscript file. The subsidiary SConscript file must be called as if it were in variant_dir, regardless of the value of duplicate. When calling an SConscript file, you can use the exports keyword argument to pass parameters (individually or as an appropriately set up environment) so the SConscript can pick up the right settings for that variant build. The SConscript must Import these to use them. Example:

env1 = Environment(...settings for variant1...)
env2 = Environment(...settings for variant2...)

# run src/SConscript in two variant directories
VariantDir('build/variant1', 'src')
SConscript('build/variant1/SConscript', exports={"env": env1})
VariantDir('build/variant2', 'src')
SConscript('build/variant2/SConscript', exports={"env": env2})

See also the SConscript function for another way to specify a variant directory in conjunction with calling a subsidiary SConscript file.

More examples:

# use names in the build directory, not the source directory
VariantDir('build', 'src', duplicate=0)
Program('build/prog', 'build/source.c')

# this builds both the source and docs in a separate subtree
VariantDir('build', '.', duplicate=0)
SConscript(dirs=['build/src','build/doc'])

# same as previous example, but only uses SConscript
SConscript(dirs='src', variant_dir='build/src', duplicate=0)
SConscript(dirs='doc', variant_dir='build/doc', duplicate=0)

WhereIs(program, [path, pathext, reject]), env.WhereIs(program, [path, pathext, reject])

Searches for the specified executable program, returning the full path to the program or None.

When called as a construction environment method, searches the paths in the path keyword argument, or if None (the default) the paths listed in the construction environment (env['ENV']['PATH']). The external environment's path list (os.environ['PATH']) is used as a fallback if the key env['ENV']['PATH'] does not exist.

On Windows systems, searches for executable programs with any of the file extensions listed in the pathext keyword argument, or if None (the default) the pathname extensions listed in the construction environment (env['ENV']['PATHEXT']). The external environment's pathname extensions list (os.environ['PATHEXT']) is used as a fallback if the key env['ENV']['PATHEXT'] does not exist.

When called as a global function, uses the external environment's path os.environ['PATH'] and path extensions os.environ['PATHEXT'], respectively, if path and pathext are None.

Will not select any path name or names in the optional reject list.

SConscript Variables

In addition to the global functions and methods, scons supports a number of variables that can be used for run-time queries in SConscript files to affect how you want the build to be performed.

ARGLIST

A list of the variable=value build variable arguments specified on the command line. Each element in the list is a tuple consisting of the variable and its value. The separate variable and value elements of the tuple can be accessed by subscripting for elements [0] and [1] of the tuple, or, more readably, by using tuple unpacking. Examples:

print("first variable, value =", ARGLIST[0][0], ARGLIST[0][1])
print("second variable, value =", ARGLIST[1][0], ARGLIST[1][1])
var, value = ARGLIST[2]
print("third variable, value =", var, value)
for var, value in ARGLIST:
    # process variable and value

The values obtained from ARGLIST (or from ARGUMENTS) are always strings since they originate from outside the SCons process. As "untrusted data", they should be validated before usage, and may need conversion to an appropriate type.

ARGUMENTS

A dictionary of all the variable=value build variable arguments specified on the command line. The dictionary is in command-line order, so if a given variable has more than one value assigned to it on the command line, the last (right-most) value is the one saved in the ARGUMENTS dictionary.

Example:

if ARGUMENTS.get("debug", ""):
    env = Environment(CCFLAGS="-g")
else:
    env = Environment()

See also ARGLIST.

BUILD_TARGETS

A list of the targets which scons has been asked to build. The contents will be either those targets listed on the command line, or, if none, those targets set via calls to the Default function. It does not contain any dependent targets that scons selects for building as a result of making the sure the specified targets are up to date, if those targets did not appear on the command line. The list is empty if neither command line targets nor Default calls are present.

The elements of this list may be strings or nodes, so you should run the list through the Python str function to make sure any Node path names are converted to strings.

Because this list may be taken from the list of targets specified using the Default function, the contents of the list may change on each successive call to Default. See DEFAULT_TARGETS for additional information.

Example:

if 'foo' in BUILD_TARGETS:
    print("Don't forget to test the `foo' program!")
if 'special/program' in BUILD_TARGETS:
    SConscript('special')

COMMAND_LINE_TARGETS

A list of the targets explicitly specified on the command line. If there are command line targets, this list has the same contents as BUILD_TARGETS. If there are no targets specified on the command line, this list is empty. The elements of this list are strings. This can be used, for example, to take specific actions only when a certain target(s) are explicitly requested for building.

Example:

if 'foo' in COMMAND_LINE_TARGETS:
    print("Don't forget to test the `foo' program!")
if 'special/program' in COMMAND_LINE_TARGETS:
    SConscript('special')

DEFAULT_TARGETS

A list of the target nodes that have been specified using the Default function. If there are no command line targets, this list will have the same contents as BUILD_TARGETS. Since the elements of the list are nodes, you need to call the Python str function on them to get the path name for each Node.

Example:

print(str(DEFAULT_TARGETS[0]))
if 'foo' in [str(t) for t in DEFAULT_TARGETS]:
    print("Don't forget to test the `foo' program!")

The contents of the DEFAULT_TARGETS list changes on each successive call to the Default function:

print([str(t) for t in DEFAULT_TARGETS])   # originally []
Default('foo')
print([str(t) for t in DEFAULT_TARGETS])   # now a node ['foo']
Default('bar')
print([str(t) for t in DEFAULT_TARGETS])   # now a node ['foo', 'bar']
Default(None)
print([str(t) for t in DEFAULT_TARGETS])   # back to []

Consequently, be sure to use DEFAULT_TARGETS only after you've made all of your Default() calls, or else simply be careful of the order of these statements in your SConscript files so that you don't look for a specific default target before it's actually been added to the list.

These variables may be accessed from custom Python modules that you import into an SConscript file by adding the following to the Python module:

from SCons.Script import *

Construction Variables

Construction Variables are key-value pairs used to store information in a construction environment that is needed needed for builds using that environment. Construction variable naming must follow the same rules as Python identifier naming: the initial character must be an underscore or letter, followed by any number of underscores, letters, or digits. The convention is to use uppercase for all letters for easier visual identification.

Construction variables are used to hold many different types of information. For example, the $CPPDEFINES variable is how to tell a C/C++ compiler about preprocessor macros you need for your build. The tool discovery that SCons performs will cause the $CXX variable to hold the name of the C++ compiler, if one was detected on the system, but you can give it a different value to force a compiler command of a different name to be used. Some variables contain lists of filename suffixes that are recognized by a particular compiler chain. $BUILDERS contains a mapping of configured Builder names (e.g. Textfile) to the actual Builder instance to call when that Builder is used. Construction variables may include references to other construction variables: the same tool which set up the C/C++ compiler will also set up an "action string", describing how to invoke that compiler, in $CXXCOM, which contains other construction variables using $VARIABLE syntax. These references will be expanded and replaced on use (see Variable Substitution).

Construction variables are referenced as if they were keys and values in a Python dictionary:

env["CC"] = "cc"
flags = env.get("CPPDEFINES", [])

Construction variables can also be retrieved and set by using the Dictionary method of the construction environment to create an actual dictionary:

cvars = env.Dictionary()
cvars["CC"] = "cc"

in the previous example, since cvars is an external copy, the value of $CC in the construction environment itself is not changed by the assignment.

Construction variables can set by passing them as keyword arguments when creating a new construction environment:

env = Environment(CC="cc")

or when copying a construction environment using the Clone method:

env2 = env.Clone(CC="cl.exe")